gdb/testsuite/gdb.threads/signal-while-stepping-over-bp-other-thread.exp

   1 # Copyright (C) 2011-2024 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test that GDB doesn't inadvertently resume the stepped thread when a
  17 # signal arrives while stepping over the breakpoint that last caused a
  18 # stop, when the thread that hit that breakpoint is not the stepped
  19 # thread.
  20
  21 # Test relies on checking gdb debug output. Do not run if gdb debug is
  22 # enabled as any debug will be redirected to the log.
  23 require !gdb_debug_enabled
  24
  25 standard_testfile
  26 set executable ${testfile}
  27
  28 require {!target_info exists gdb,nosignals}
  29
  30 if {[gdb_compile_pthreads "${srcdir}/${subdir}/${srcfile}" "${binfile}" \
  31          executable [list debug "incdir=${objdir}"]] != "" } {
  32     return -1
  33 }
  34
  35 proc get_value {var test} {
  36     global expect_out
  37     global gdb_prompt
  38     global decimal
  39
  40     set value -1
  41     gdb_test_multiple "print $var" "$test" {
  42         -re ".*= ($decimal).*\r\n$gdb_prompt $" {
  43             set value $expect_out(1,string)
  44             pass "$test"
  45         }
  46     }
  47     return ${value}
  48 }
  49
  50 # Start with a fresh gdb.
  51
  52 clean_restart $executable
  53
  54 if ![runto_main] {
  55     return -1
  56 }
  57
  58 gdb_breakpoint [gdb_get_line_number "set wait-thread-2 breakpoint here"]
  59 gdb_continue_to_breakpoint "run to wait-thread-2 breakpoint"
  60 gdb_test "info threads" "" "info threads with thread 2"
  61
  62 gdb_breakpoint [gdb_get_line_number "set wait-thread-3 breakpoint here"]
  63 gdb_continue_to_breakpoint "run to breakpoint"
  64 gdb_test "info threads" "" "info threads with thread 3"
  65
  66 gdb_test "set scheduler-locking on"
  67
  68 gdb_breakpoint [gdb_get_line_number "set breakpoint child_two here"]
  69 gdb_breakpoint [gdb_get_line_number "set breakpoint child_one here"]
  70
  71 gdb_test "thread 3" "" "switch to thread 3 to run to its breakpoint"
  72 gdb_continue_to_breakpoint "run to breakpoint in thread 3"
  73
  74 gdb_test "thread 2" "" "switch to thread 2 to run to its breakpoint"
  75 gdb_continue_to_breakpoint "run to breakpoint in thread 2"
  76
  77 delete_breakpoints
  78
  79 gdb_test "b *\$pc" "" "set breakpoint to be stepped over"
  80 # Make sure the first loop breaks without hitting the breakpoint
  81 # again.
  82 gdb_test "p *myp = 0" " = 0" "force loop break in thread 2"
  83
  84 # We want "print" to make sure the target reports the signal to the
  85 # core.
  86 gdb_test "handle SIGUSR1 print nostop pass" "" ""
  87
  88 gdb_test "thread 1" "" "switch to thread 1 to queue signal in thread 2"
  89 gdb_test "next 2" "pthread_join .*" "queue signal in thread 2"
  90
  91 gdb_test "thread 3" "" "switch to thread 3 for stepping"
  92 set my_number [get_value "my_number" "get my_number"]
  93 set cnt_before [get_value "args\[$my_number\]" "get count before step"]
  94 gdb_test "set scheduler-locking off"
  95
  96 # Make sure we're exercising the paths we want to.
  97 gdb_test "set debug infrun 1"
  98
  99 set test "step"
 100 gdb_test_sequence $test $test -prompt "$gdb_prompt \\\[infrun\\\] fetch_inferior_event: exit\r\n$"  {
 101     "need to step-over"
 102     "resume_1: step=1,"
 103     "signal arrived while stepping over breakpoint"
 104     "stepped to a different line"
 105     "callme"
 106 }
 107
 108 set cnt_after [get_value "args\[$my_number\]" "get count after step"]
 109
 110 # Test that GDB doesn't inadvertently resume the stepped thread when a
 111 # signal arrives while stepping over a breakpoint in another thread.
 112
 113 gdb_assert { $cnt_before + 1 == $cnt_after } "stepped thread under control"