gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2024 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT
  22 AC_CONFIG_MACRO_DIRS([../config])
  23 AC_CONFIG_SRCDIR([server.cc])
  24 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_USE_SYSTEM_EXTENSIONS
  31 AC_SYS_LARGEFILE
  32 AM_PROG_INSTALL_STRIP
  33
  34 # Set build, build_cpu, build_vendor and build_os.
  35 AC_CANONICAL_BUILD
  36
  37 # Set host, host_cpu, host_vendor, and host_os.
  38 AC_CANONICAL_HOST
  39
  40 # Set target, target_cpu, target_vendor, and target_os.
  41 AC_CANONICAL_TARGET
  42
  43 AC_PROG_INSTALL
  44 AC_CHECK_TOOL(AR, ar)
  45 AC_PROG_RANLIB
  46
  47 AC_ARG_PROGRAM
  48
  49 # We require a C++17 compiler.  Check if one is available, and if
  50 # necessary, set CXX_DIALECT to some -std=xxx switch.
  51 AX_CXX_COMPILE_STDCXX(17, , mandatory)
  52
  53 AC_HEADER_STDC
  54
  55 GDB_AC_COMMON
  56 # This is set by GDB_AC_COMMON.
  57 AC_SUBST(WIN32APILIBS)
  58
  59 GDB_AC_SELFTEST
  60
  61 ACX_NONCANONICAL_TARGET
  62 ACX_NONCANONICAL_HOST
  63
  64 # Dependency checking.
  65 ZW_CREATE_DEPDIR
  66
  67 dnl Set up for gettext.
  68 ZW_GNU_GETTEXT_SISTER_DIR
  69
  70 # Create sub-directories for objects and dependencies.
  71 CONFIG_SRC_SUBDIR="arch gdbsupport nat target"
  72 AC_SUBST(CONFIG_SRC_SUBDIR)
  73
  74 AC_CONFIG_COMMANDS([gdbdepdir],[
  75   for subdir in ${CONFIG_SRC_SUBDIR}
  76   do
  77       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  78   done],
  79   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  80
  81 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  82
  83 AC_CHECK_HEADERS([ \
  84   arpa/inet.h \
  85   fcntl.h \
  86   linux/elf.h \
  87   netdb.h \
  88   netinet/in.h \
  89   netinet/tcp.h \
  90   signal.h \
  91   string.h \
  92   sys/file.h \
  93   sys/ioctl.h \
  94   sys/procfs.h \
  95   sys/reg.h \
  96   sys/socket.h \
  97   termios.h \
  98   ws2tcpip.h \
  99 ])
 100
 101 AC_FUNC_FORK
 102 AC_CHECK_FUNCS([ \
 103   pread \
 104   pread64 \
 105   pwrite \
 106 ])
 107
 108 # Check the return and argument types of ptrace.
 109 GDB_AC_PTRACE
 110
 111 AM_GDB_COMPILER_TYPE
 112 AM_GDB_WARNINGS
 113
 114 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 115 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 116 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 117 dnl augment LIBS.
 118 old_LIBS="$LIBS"
 119 LIBS="$LIBS -ldl"
 120 AC_CHECK_FUNCS(dladdr)
 121 LIBS="$old_LIBS"
 122
 123 libiberty_INIT
 124
 125 AC_CHECK_DECLS([perror, vasprintf, vsnprintf])
 126
 127 AC_CHECK_TYPES(socklen_t, [], [],
 128 [#include <sys/types.h>
 129 #if HAVE_SYS_SOCKET_H
 130 # include <sys/socket.h>
 131 #elif HAVE_WS2TCPIP_H
 132 # include <ws2tcpip.h>
 133 #endif
 134 ])
 135
 136 case "${target}" in
 137   *-android*)
 138     # Starting with NDK version 9, <elf.h> actually includes definitions
 139     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 140     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 141     # leading to conflicts with the defintions from <linux/elf.h>.
 142     # This makes it impossible for us to include both <elf.h> and
 143     # <linux/elf.h>, which means that, in practice, we do not have
 144     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 145     # Therefore, do not try to auto-detect availability, as it would
 146     # get it wrong on this platform.
 147     ;;
 148   *)
 149     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 150     #include <elf.h>
 151     )
 152 esac
 153
 154 ACX_PKGVERSION([GDB])
 155 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 156 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 157 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 158
 159 # Check for various supplementary target information (beyond the
 160 # triplet) which might affect the choices in configure.srv.
 161 case "${target}" in
 162 changequote(,)dnl
 163   i[34567]86-*-linux*)
 164 changequote([,])dnl
 165     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 166                    [save_CPPFLAGS="$CPPFLAGS"
 167                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 168                     AC_EGREP_CPP([got it], [
 169 #if __x86_64__
 170 got it
 171 #endif
 172                  ], [gdb_cv_i386_is_x86_64=yes],
 173                     [gdb_cv_i386_is_x86_64=no])
 174                     CPPFLAGS="$save_CPPFLAGS"])
 175     ;;
 176
 177   x86_64-*-linux*)
 178     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 179                    [save_CPPFLAGS="$CPPFLAGS"
 180                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 181                     AC_EGREP_CPP([got it], [
 182 #if __x86_64__ && __ILP32__
 183 got it
 184 #endif
 185                  ], [gdb_cv_x86_is_x32=yes],
 186                     [gdb_cv_x86_is_x32=no])
 187                     CPPFLAGS="$save_CPPFLAGS"])
 188     ;;
 189
 190   m68k-*-*)
 191     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 192                    [save_CPPFLAGS="$CPPFLAGS"
 193                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 194                     AC_EGREP_CPP([got it], [
 195 #ifdef __mcoldfire__
 196 got it
 197 #endif
 198                  ], [gdb_cv_m68k_is_coldfire=yes],
 199                     [gdb_cv_m68k_is_coldfire=no])
 200                     CPPFLAGS="$save_CPPFLAGS"])
 201     ;;
 202 esac
 203
 204 . ${srcdir}/configure.srv
 205
 206 if test "${srv_mingwce}" = "yes"; then
 207   LIBS="$LIBS -lws2"
 208 elif test "${srv_mingw}" = "yes"; then
 209   # WIN32APILIBS is set by GDB_AC_COMMON.
 210   LIBS="$LIBS $WIN32APILIBS"
 211 fi
 212
 213 if test "${srv_linux_usrregs}" = "yes"; then
 214   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 215             [Define if the target supports PTRACE_PEEKUSR for register ]
 216             [access.])
 217 fi
 218
 219 if test "${srv_linux_regsets}" = "yes"; then
 220   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 221             [Define if the target supports register sets.])
 222
 223   AC_MSG_CHECKING(for PTRACE_GETREGS)
 224   AC_CACHE_VAL(
 225     [gdbsrv_cv_have_ptrace_getregs],
 226     [AC_COMPILE_IFELSE(
 227        [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
 228        [gdbsrv_cv_have_ptrace_getregs=yes],
 229        [gdbsrv_cv_have_ptrace_getregs=no]
 230      )]
 231   )
 232   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 233   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 234     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 235               [Define if the target supports PTRACE_GETREGS for register ]
 236               [access.])
 237   fi
 238
 239   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 240   AC_CACHE_VAL(
 241     [gdbsrv_cv_have_ptrace_getfpxregs],
 242     [AC_COMPILE_IFELSE(
 243        [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
 244        [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 245        [gdbsrv_cv_have_ptrace_getfpxregs=no]
 246      )]
 247   )
 248   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 249   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 250     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 251               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 252               [register access.])
 253   fi
 254 fi
 255
 256 if test "${srv_linux_btrace}" = "yes"; then
 257   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 258             [Define if the target supports branch tracing.])
 259 fi
 260
 261 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 262 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 263   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 264 fi
 265
 266 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 267 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 268   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 269 fi
 270
 271 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 272 dnl needs it (and gdbreplay doesn't).
 273 old_LIBS="$LIBS"
 274 AC_CHECK_LIB(dl, dlopen)
 275 LIBS="$old_LIBS"
 276
 277 srv_thread_depfiles=
 278 srv_libs=
 279
 280 if test "$srv_linux_thread_db" = "yes"; then
 281   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 282     srv_libs="-ldl"
 283     AC_MSG_CHECKING(for the dynamic export flag)
 284     old_LDFLAGS="$LDFLAGS"
 285     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 286     # supported there.
 287     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 288     LDFLAGS="$LDFLAGS $RDYNAMIC"
 289     AC_LINK_IFELSE(
 290       [AC_LANG_PROGRAM([],[])],
 291       [found="-Wl,--dynamic-list"
 292        RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 293       [RDYNAMIC="-rdynamic"
 294        LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 295        AC_LINK_IFELSE(
 296          [AC_LANG_PROGRAM([], [])],
 297          [found="-rdynamic"],
 298          [found="no"
 299           RDYNAMIC=""]
 300        )]
 301     )
 302     AC_SUBST(RDYNAMIC)
 303     LDFLAGS="$old_LDFLAGS"
 304     AC_MSG_RESULT($found)
 305   else
 306     srv_libs="-lthread_db"
 307   fi
 308
 309   srv_thread_depfiles="thread-db.o proc-service.o"
 310   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 311   AC_CACHE_CHECK(
 312     [for TD_VERSION],
 313     [gdbsrv_cv_have_td_version],
 314     [AC_COMPILE_IFELSE(
 315        [AC_LANG_PROGRAM([#include <thread_db.h>], [TD_VERSION;])],
 316        [gdbsrv_cv_have_td_version=yes],
 317        [gdbsrv_cv_have_td_version=no]
 318      )]
 319   )
 320   if test "$gdbsrv_cv_have_td_version" = yes; then
 321     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 322   fi
 323 fi
 324
 325 AC_ARG_WITH(libthread-db,
 326 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 327 [srv_libthread_db_path="${withval}"
 328   srv_libs="$srv_libthread_db_path"
 329 ])
 330
 331 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 332   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 333 fi
 334
 335 if test "$srv_xmlfiles" != ""; then
 336   srv_xmlbuiltin="xml-builtin.o"
 337   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 338
 339   tmp_xmlfiles=$srv_xmlfiles
 340   srv_xmlfiles=""
 341   for f in $tmp_xmlfiles; do
 342     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 343   done
 344 fi
 345
 346 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_thread_depfiles"
 347 GDBSERVER_LIBS="$srv_libs"
 348
 349 dnl Check whether the target supports __sync_*_compare_and_swap.
 350 AC_CACHE_CHECK(
 351   [whether the target supports __sync_*_compare_and_swap],
 352   [gdbsrv_cv_have_sync_builtins],
 353   [AC_LINK_IFELSE(
 354      [AC_LANG_PROGRAM(
 355         [],
 356         [int foo, bar;
 357          bar = __sync_val_compare_and_swap(&foo, 0, 1);]
 358       )],
 359      [gdbsrv_cv_have_sync_builtins=yes],
 360      [gdbsrv_cv_have_sync_builtins=no]
 361    )]
 362 )
 363 if test "$gdbsrv_cv_have_sync_builtins" = yes; then
 364   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 365     [Define to 1 if the target supports __sync_*_compare_and_swap])
 366 fi
 367
 368 dnl Check for -fvisibility=hidden support in the compiler.
 369 saved_cflags="$CFLAGS"
 370 CFLAGS="$CFLAGS -fvisibility=hidden"
 371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 372                         [gdbsrv_cv_have_visibility_hidden=yes],
 373                         [gdbsrv_cv_have_visibility_hidden=no])
 374 CFLAGS="$saved_cflags"
 375
 376 IPA_DEPFILES=""
 377 extra_libraries=""
 378
 379 # check whether to enable the inprocess agent
 380 if test "$ipa_obj" != "" \
 381    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 382    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 383    have_ipa=true
 384 else
 385    have_ipa=false
 386 fi
 387
 388 AC_ARG_ENABLE(inprocess-agent,
 389 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 390 [case "$enableval" in
 391   yes) want_ipa=true ;;
 392   no) want_ipa=false ;;
 393   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 394 esac],
 395 [want_ipa=$have_ipa])
 396
 397 if $want_ipa ; then
 398    if $have_ipa ; then
 399      IPA_DEPFILES="$ipa_obj"
 400      extra_libraries="$extra_libraries libinproctrace.so"
 401    else
 402      AC_MSG_ERROR([inprocess agent not supported for this target])
 403    fi
 404 fi
 405
 406 AC_SUBST(GDBSERVER_DEPFILES)
 407 AC_SUBST(GDBSERVER_LIBS)
 408 AC_SUBST(srv_xmlbuiltin)
 409 AC_SUBST(srv_xmlfiles)
 410 AC_SUBST(IPA_DEPFILES)
 411 AC_SUBST(extra_libraries)
 412
 413 GNULIB=../gnulib/import
 414
 415 GNULIB_STDINT_H=
 416 if test x"$STDINT_H" != x; then
 417   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 418 fi
 419 AC_SUBST(GNULIB_STDINT_H)
 420
 421 # Check for libiconv.  It is a requirement for Linux hosts, and others hosts
 422 # don't use it at all.  Define MAYBE_LIBICONV only if the host is Linux.
 423 AM_ICONV
 424 MAYBE_LIBICONV=
 425 case "$host" in
 426   *linux*)
 427     if test "$am_cv_func_iconv" != yes; then
 428       AC_MSG_ERROR([could not find libiconv (required for host $host)])
 429     fi
 430
 431     MAYBE_LIBICONV="$LIBICONV"
 432     ;;
 433 esac
 434
 435 AC_SUBST(MAYBE_LIBICONV)
 436
 437 AC_CONFIG_FILES([Makefile])
 438
 439 AC_OUTPUT