gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2024 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], [BFD_VERSION])
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32
  33 AM_INIT_AUTOMAKE
  34 AM_SILENT_RULES([yes])
  35
  36 AC_PROG_CC
  37 AC_USE_SYSTEM_EXTENSIONS
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41 ACX_PROG_CMP_IGNORE_INITIAL
  42
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations besides the primary],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51
  52 ac_checking=
  53 . ${srcdir}/../bfd/development.sh
  54 test "$development" = true && ac_checking=yes
  55 AC_ARG_ENABLE(checking,
  56 [  --enable-checking       enable run-time checks],
  57 [case "${enableval}" in
  58   no|none)  ac_checking= ;;
  59   *)        ac_checking=yes ;;
  60 esac])dnl
  61 if test x$ac_checking != x ; then
  62   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  63 fi
  64
  65 # PR gas/19109
  66 # Decide the default method for compressing debug sections.
  67 ac_default_compressed_debug_sections=unset
  68 # Provide a configure time option to override our default.
  69 AC_ARG_ENABLE(compressed_debug_sections,
  70               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  71               [compress debug sections by default]),
  72 [case ,"${enableval}", in
  73   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  74   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  75   *)   ac_default_compressed_debug_sections=unset ;;
  76 esac])dnl
  77
  78 # Select default compression algorithm.
  79 ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_GABI_ZLIB
  80 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
  81               AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
  82               [Default compression algorithm for --enable-compressed-debug-sections.]),
  83 [case "${enableval}" in
  84    zstd) ac_default_compressed_debug_sections_algorithm=COMPRESS_DEBUG_ZSTD ;;
  85 esac])dnl
  86
  87 # PR gas/19520
  88 # Decide if x86 assembler should generate relax relocations.
  89 ac_default_x86_relax_relocations=unset
  90 # Provide a configure time option to override our default.
  91 AC_ARG_ENABLE(x86_relax_relocations,
  92               AS_HELP_STRING([--enable-x86-relax-relocations],
  93               [generate x86 relax relocations by default]),
  94 [case "${enableval}" in
  95   no)  ac_default_x86_relax_relocations=0 ;;
  96 esac])dnl
  97
  98 # PR gas/32022
  99 # Decide if x86 assembler should check TLS relocation.
 100 ac_default_x86_tls_check=unset
 101 # Provide a configure time option to override our default.
 102 AC_ARG_ENABLE(x86_tls_check,
 103               AS_HELP_STRING([--enable-x86-tls-check],
 104               [check x86 TLS relocation by default]),
 105 [case "${enableval}" in
 106   no)  ac_default_x86_tls_check=0 ;;
 107 esac])dnl
 108
 109 # Decide if ELF assembler should generate common symbols with the
 110 # STT_COMMON type.
 111 ac_default_elf_stt_common=unset
 112 # Provide a configure time option to override our default.
 113 AC_ARG_ENABLE(elf_stt_common,
 114               AS_HELP_STRING([--enable-elf-stt-common],
 115               [generate ELF common symbols with STT_COMMON type by default]),
 116 [case "${enableval}" in
 117   yes)  ac_default_elf_stt_common=1 ;;
 118 esac])dnl
 119
 120
 121 # Decide if the ELF assembler should default to generating
 122 # GNU Build notes if none are provided by the input.
 123 ac_default_generate_build_notes=0
 124 # Provide a configuration option to override the default.
 125 AC_ARG_ENABLE(generate_build_notes,
 126               AS_HELP_STRING([--enable-generate-build-notes],
 127               [generate GNU Build notes if none are provided by the input]),
 128 [case "${enableval}" in
 129   yes)  ac_default_generate_build_notes=1 ;;
 130   no)   ac_default_generate_build_notes=0 ;;
 131 esac])dnl
 132
 133 # Decide if the MIPS assembler should default to enable MIPS fix Loongson3
 134 # LLSC errata.
 135 ac_default_mips_fix_loongson3_llsc=unset
 136 # Provide a configuration option to override the default.
 137 AC_ARG_ENABLE(mips-fix-loongson3-llsc,
 138              AS_HELP_STRING([--enable-mips-fix-loongson3-llsc],
 139              [enable MIPS fix Loongson3 LLSC errata]),
 140 [case "${enableval}" in
 141   yes)  ac_default_mips_fix_loongson3_llsc=1 ;;
 142   no)   ac_default_mips_fix_loongson3_llsc=0 ;;
 143 esac])dnl
 144
 145 # Decide if the x86 ELF assembler should default to generating GNU x86
 146 # used ISA and feature properties.
 147 ac_default_generate_x86_used_note=unset
 148 # Provide a configuration option to override the default.
 149 AC_ARG_ENABLE(x86-used-note,
 150               AS_HELP_STRING([--enable-x86-used-note],
 151               [generate GNU x86 used ISA and feature properties]),
 152 [case "${enableval}" in
 153   yes)  ac_default_generate_x86_used_note=1 ;;
 154   no)   ac_default_generate_x86_used_note=0 ;;
 155 esac])dnl
 156
 157 # Decide if the RISC-V ELF assembler should default to generating attribute.
 158 ac_default_generate_riscv_attr=unset
 159 # Provide a configuration option to override the default.
 160 AC_ARG_ENABLE(default-riscv-attribute,
 161               AS_HELP_STRING([--enable-default-riscv-attribute],
 162               [generate RISC-V arch attribute by default]),
 163 [case "${enableval}" in
 164   yes)  ac_default_generate_riscv_attr=1 ;;
 165   no)   ac_default_generate_riscv_attr=0 ;;
 166 esac])dnl
 167
 168 using_cgen=no
 169
 170 AM_BINUTILS_WARNINGS
 171
 172 # Generate a header file
 173 AC_CONFIG_HEADERS(config.h:config.in)
 174
 175 dnl Option --with-cpu=TYPE allows configure type control of the default
 176 dnl cpu type within the assembler.  Currently only the ARC target
 177 dnl supports this feature, but others may be added in the future.
 178 AC_ARG_WITH(cpu,
 179             AS_HELP_STRING([--with-cpu=CPU],
 180             [default cpu variant is CPU (currently only supported on ARC)]),
 181             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 182                                 "${with_cpu}",
 183                                 [Target specific CPU.])],
 184             [])
 185
 186 # PR 14072
 187 AH_VERBATIM([00_CONFIG_H_CHECK],
 188 [/* Check that config.h is #included before system headers
 189    (this works only for glibc, but that should be enough).  */
 190 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 191 #  error config.h must be #included before system headers
 192 #endif
 193 #define __CONFIG_H__ 1])
 194
 195 # If we are on a DOS filesystem, we must use gdb.ini rather than
 196 # .gdbinit.
 197 case "${host}" in
 198   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 199     GDBINIT="gdb.ini"
 200     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 201     ;;
 202   *)
 203     GDBINIT=".gdbinit"
 204     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 205     ;;
 206 esac
 207 AC_SUBST(GDBINIT)
 208
 209 #We need this for the host.
 210 AC_C_BIGENDIAN
 211
 212 te_file=generic
 213
 214 # Makefile target for installing gas in $(tooldir)/bin.
 215 install_tooldir=install-exec-tooldir
 216
 217 canon_targets=""
 218 all_targets=no
 219 if test -n "$enable_targets" ; then
 220   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 221     if test $t = "all"; then
 222       all_targets=yes
 223       continue
 224     fi
 225     result=`$ac_config_sub $t 2>/dev/null`
 226     if test -n "$result" ; then
 227       canon_targets="$canon_targets $result"
 228 #    else
 229 #      # Permit "all", etc.  We don't support it yet though.
 230 #      canon_targets="$canon_targets $t"
 231     fi
 232   done
 233   GAS_UNIQ(canon_targets)
 234 fi
 235
 236 emulations=""
 237
 238 for this_target in $target $canon_targets ; do
 239
 240     targ=${this_target}
 241     . ${srcdir}/configure.tgt
 242
 243     case ${target_cpu} in
 244       crisv32)
 245         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 246                            [Default CRIS architecture.])
 247         ;;
 248     esac
 249
 250     if test ${this_target} = $target ; then
 251       target_cpu_type=${cpu_type}
 252     elif test ${target_cpu_type} != ${cpu_type} ; then
 253       continue
 254     fi
 255
 256     generic_target=${cpu_type}-${target_vendor}-${target_os}
 257     case ${generic_target} in
 258       i386-*-msdosdjgpp* \
 259       | i386-*-go32*)
 260         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 261         ;;
 262
 263       i386-*-linux-* | x86_64-*-linux-*)
 264         if test ${this_target} = $target \
 265            && test ${ac_default_generate_x86_used_note} = unset; then
 266           ac_default_generate_x86_used_note=1
 267         fi
 268         ;;
 269
 270       i386-*-solaris2 \
 271       | x86_64-*-solaris2 \
 272       | i386-*-solaris2.[[0-9]] \
 273       | i386-*-solaris2.1[[01]] \
 274       | x86_64-*-solaris2.1[[01]])
 275         if test ${this_target} = $target \
 276            && test ${ac_default_x86_relax_relocations} = unset; then
 277           ac_default_x86_relax_relocations=0
 278         fi
 279         ;;
 280
 281       microblaze*)
 282         ;;
 283
 284 changequote(,)dnl
 285       ppc-*-aix5.[01]*)
 286         ;;
 287       ppc-*-aix[5-9].*)
 288 changequote([,])dnl
 289         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 290                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 291         ;;
 292       ppc-*-solaris*)
 293         if test ${this_target} = $target; then
 294           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 295                     [Define if default target is PowerPC Solaris.])
 296         fi
 297         if test x${endian} = xbig; then
 298           AC_MSG_ERROR(Solaris must be configured little endian)
 299         fi
 300         ;;
 301     esac
 302
 303     if test ${this_target} = $target ; then
 304       endian_def=
 305       if test x${endian} = xbig; then
 306         endian_def=1
 307       elif test x${endian} = xlittle; then
 308         endian_def=0
 309       fi
 310       if test x${endian_def} != x; then
 311         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 312                            [Define as 1 if big endian.])
 313       fi
 314     fi
 315
 316 # Other random stuff.
 317
 318     case ${cpu_type} in
 319       mips)
 320         # Set mips_cpu to the name of the default CPU.
 321         case ${target_cpu} in
 322           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 323             mips_cpu=from-abi
 324             ;;
 325           mipsisa32 | mipsisa32el)
 326             mips_cpu=mips32
 327             ;;
 328           mipsisa32r2 | mipsisa32r2el)
 329             mips_cpu=mips32r2
 330             ;;
 331           mipsisa32r3 | mipsisa32r3el)
 332             mips_cpu=mips32r3
 333             ;;
 334           mipsisa32r5 | mipsisa32r5el)
 335             mips_cpu=mips32r5
 336             ;;
 337           mipsisa32r6 | mipsisa32r6el)
 338             mips_cpu=mips32r6
 339             ;;
 340           mipsisa64 | mipsisa64el)
 341             mips_cpu=mips64
 342             ;;
 343           mipsisa64r2 | mipsisa64r2el)
 344             mips_cpu=mips64r2
 345             ;;
 346           mipsisa64r3 | mipsisa64r3el)
 347             mips_cpu=mips64r3
 348             ;;
 349           mipsisa64r5 | mipsisa64r5el)
 350             mips_cpu=mips64r5
 351             ;;
 352           mipsisa64r6 | mipsisa64r6el)
 353             mips_cpu=mips64r6
 354             ;;
 355           mipstx39 | mipstx39el)
 356             mips_cpu=r3900
 357             ;;
 358           mips64vr | mips64vrel)
 359             mips_cpu=vr4100
 360             ;;
 361           mipsisa32r2* | mipsisa64r2*)
 362 changequote(,)dnl
 363             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 364 changequote([,])dnl
 365             ;;
 366           mipsisa32r6* | mipsisa64r6*)
 367 changequote(,)dnl
 368             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 369 changequote([,])dnl
 370             ;;
 371           mips64* | mipsisa64* | mipsisa32*)
 372 changequote(,)dnl
 373             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 374 changequote([,])dnl
 375             ;;
 376           mips*)
 377 changequote(,)dnl
 378             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 379 changequote([,])dnl
 380             ;;
 381           *)
 382             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 383             ;;
 384         esac
 385         # See whether it's appropriate to set EF_MIPS_ABI_O32 for o32
 386         # binaries.  It's a GNU extension that some OSes don't understand.
 387         case ${target} in
 388           *-*-irix*)
 389             use_ef_mips_abi_o32=0
 390             ;;
 391           *)
 392             use_ef_mips_abi_o32=1
 393             ;;
 394         esac
 395         # If Vendor is IMG, then MIPSr6 is used
 396         case ${target} in
 397           mips*-img-*)
 398             mips_cpu=mips32r6
 399             ;;
 400         esac
 401         # Decide whether to generate 32-bit or 64-bit code by default.
 402         # Used to resolve -march=from-abi when an embedded ABI is selected.
 403         case ${target} in
 404           mips64*-*-* | mipsisa64*-*-*)
 405             mips_default_64bit=1
 406             ;;
 407           *)
 408             mips_default_64bit=0
 409             ;;
 410         esac
 411         # Decide which ABI to target by default.
 412         case ${target} in
 413           mips64*-openbsd* | mips64*-linux-gnuabi64)
 414             mips_default_abi=N64_ABI
 415             ;;
 416           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 417           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 418             mips_default_abi=N32_ABI
 419             ;;
 420           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 421             mips_default_abi=O32_ABI
 422             ;;
 423           *)
 424             mips_default_abi=NO_ABI
 425             ;;
 426         esac
 427         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 428                            [Default CPU for MIPS targets. ])
 429         AC_DEFINE_UNQUOTED(USE_EF_MIPS_ABI_O32, $use_ef_mips_abi_o32,
 430                            [Allow use of EF_MIPS_ABI_O32 on MIPS targets. ])
 431         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 432                            [Generate 64-bit code by default on MIPS targets. ])
 433         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 434                            [Choose a default ABI for MIPS targets. ])
 435         ;;
 436     esac
 437
 438     # Do we need the opcodes library?
 439     case ${cpu_type} in
 440       vax | tic30 | i386 | arm)
 441         ;;
 442
 443       *)
 444         need_opcodes=yes
 445
 446         case "${enable_shared}" in
 447         yes) shared_opcodes=true ;;
 448         *opcodes*) shared_opcodes=true ;;
 449         *) shared_opcodes=false ;;
 450         esac
 451         ;;
 452     esac
 453
 454     # Any other special object files needed ?
 455     case ${cpu_type} in
 456
 457       bfin)
 458         for f in config/bfin-parse.o config/bfin-lex-wrapper.o; do
 459           case " $extra_objects " in
 460             *" $f "*) ;;
 461             *) extra_objects="$extra_objects $f" ;;
 462           esac
 463         done
 464         ;;
 465
 466       bpf)
 467         if test $this_target = $target ; then
 468           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 469         fi
 470         ;;
 471       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 472         using_cgen=yes
 473         ;;
 474
 475       loongarch)
 476         for f in config/loongarch-parse.o config/loongarch-lex-wrapper.o; do
 477           case " $extra_objects " in
 478             *" $f "*) ;;
 479             *) extra_objects="$extra_objects $f" ;;
 480           esac
 481         done
 482         # --target=loongarch[32|64]-*-*.  */
 483         if test $this_target = $target ; then
 484           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 485         fi
 486         ;;
 487
 488       m32c)
 489         using_cgen=yes
 490         ;;
 491       frv)
 492         using_cgen=yes
 493         ;;
 494       kvx)
 495         for f in config/kvx-parse.o; do
 496           case " $extra_objects " in
 497             *" $f "*) ;;
 498             *) extra_objects="$extra_objects $f" ;;
 499           esac
 500         done
 501         ;;
 502       m68k)
 503         f=config/m68k-parse.o
 504         case " $extra_objects " in
 505           *" $f "*) ;;
 506           *) extra_objects="$extra_objects $f" ;;
 507         esac
 508         ;;
 509
 510       mep)
 511         using_cgen=yes
 512         ;;
 513
 514       mips)
 515         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 516           case " $extra_objects " in
 517             *" $f "*) ;;
 518             *) extra_objects="$extra_objects $f" ;;
 519           esac
 520         done
 521         ;;
 522
 523       mt)
 524         using_cgen=yes
 525         ;;
 526
 527       nds32)
 528         # setup NDS32_LINUX_TOOLCHAIN definition
 529         if test "linux" = $em; then
 530           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 531             [Define value for nds32_linux_toolchain])
 532         else
 533           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 534             [Define default value for nds32_linux_toolchain])
 535         fi
 536
 537         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 538         # based on arch_name.
 539         AC_MSG_CHECKING(for default configuration of --with-arch)
 540         if test "x${with_arch}" != x; then
 541           case ${with_arch} in
 542             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 543               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 544                                  [Define value for nds32_arch_name])
 545               ;;
 546             *)
 547               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 548               ;;
 549           esac
 550         fi
 551         AC_MSG_RESULT($with_arch)
 552
 553         # Decide features one by one.
 554         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 555         if test "x${enable_dx_regs}" = xyes; then
 556           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 557                     [Define value for nds32_dx_regs])
 558         else
 559           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 560                     [Define default value for nds32_dx_regs])
 561         fi
 562         AC_MSG_RESULT($enable_dx_regs)
 563
 564         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 565         if test "x${enable_perf_ext}" = xno; then
 566           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 567                     [Define value for nds32_perf_ext])
 568         else
 569           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 570                     [Define default value for nds32_perf_ext])
 571         fi
 572         AC_MSG_RESULT($enable_perf_ext)
 573
 574         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 575         if test "x${enable_perf_ext2}" = xno; then
 576           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 577                     [Define value for nds32_perf_ext2])
 578         else
 579           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 580                     [Define default value for nds32_perf_ext2])
 581         fi
 582         AC_MSG_RESULT($enable_perf_ext2)
 583
 584         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 585         if test "x${enable_string_ext}" = xno; then
 586           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 587                     [Define value for nds32_string_ext])
 588         else
 589           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 590                     [Define default value for nds32_string_ext])
 591         fi
 592         AC_MSG_RESULT($enable_string_ext)
 593
 594         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 595         if test "x${enable_audio_ext}" = xno; then
 596           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 597                     [Define value for nds32_audio_ext])
 598         else
 599           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 600                     [Define default value for nds32_audio_ext])
 601         fi
 602         AC_MSG_RESULT($enable_audio_ext)
 603
 604         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 605         if test "x${enable_dsp_ext}" = xno; then
 606           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 607                     [Define value for nds32_dsp_ext])
 608         else
 609           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 610                     [Define default value for nds32_dsp_ext])
 611         fi
 612         AC_MSG_RESULT($enable_dsp_ext)
 613
 614         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 615         if test "x${enable_zol_ext}" = xno; then
 616           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 617                     [Define value for nds32_zol_ext])
 618         else
 619           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 620                     [Define default value for nds32_zol_ext])
 621         fi
 622         AC_MSG_RESULT($enable_zol_ext)
 623         ;;
 624
 625       aarch64 | i386 | s390 | sparc)
 626         if test $this_target = $target ; then
 627           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 628         fi
 629         ;;
 630
 631       riscv)
 632         # --target=riscv[32|64]-*-*.  */
 633         if test $this_target = $target ; then
 634           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 635         fi
 636
 637         # --with-arch=<value>.  The syntax of <value> is same as Gas option -march.
 638         AC_MSG_CHECKING(for default configuration of --with-arch)
 639         if test "x${with_arch}" != x; then
 640         AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ARCH_WITH_EXT, "$with_arch",
 641                            [Define default value for RISC-V -march.])
 642         fi
 643         AC_MSG_RESULT($with_arch)
 644
 645         # --with-isa-spec=[2.2|20190608|20191213].
 646         AC_MSG_CHECKING(for default configuration of --with-isa-spec)
 647         if test "x${with_isa_spec}" != x; then
 648           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ISA_SPEC, "$with_isa_spec",
 649                              [Define default value for RISC-V -misa-spec.])
 650         fi
 651         AC_MSG_RESULT($with_isa_spec)
 652
 653         # --with-priv-spec=[1.9.1|1.10|1.11|1.12].
 654         AC_MSG_CHECKING(for default configuration of --with-priv-spec)
 655         if test "x${with_priv_spec}" != x; then
 656           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_PRIV_SPEC, "$with_priv_spec",
 657                              [Define default value for RISC-V -mpriv-spec])
 658         fi
 659         AC_MSG_RESULT($with_priv_spec)
 660         ;;
 661
 662       rl78)
 663         f=config/rl78-parse.o
 664         case " $extra_objects " in
 665           *" $f "*) ;;
 666           *) extra_objects="$extra_objects $f" ;;
 667         esac
 668         ;;
 669
 670       rx)
 671         f=config/rx-parse.o
 672         case " $extra_objects " in
 673           *" $f "*) ;;
 674           *) extra_objects="$extra_objects $f" ;;
 675         esac
 676         ;;
 677
 678       xstormy16)
 679         using_cgen=yes
 680         ;;
 681
 682       xtensa)
 683         f=config/xtensa-relax.o
 684         case " $extra_objects " in
 685           *" $f "*) ;;
 686           *) extra_objects="$extra_objects $f" ;;
 687         esac
 688         ;;
 689
 690       *)
 691         ;;
 692     esac
 693
 694     if test $using_cgen = yes ; then
 695         f=cgen.o
 696         case " $extra_objects " in
 697           *" $f "*) ;;
 698           *) extra_objects="$extra_objects $f" ;;
 699         esac
 700     fi
 701
 702 # See if we really can support this configuration with the emulation code.
 703
 704     if test $this_target = $target ; then
 705       obj_format=$fmt
 706       te_file=$em
 707     fi
 708
 709     case ${te_file} in
 710       vms)
 711         f=config/te-vms.o
 712         case " $extra_objects " in
 713           *" $f "*) ;;
 714           *) extra_objects="$extra_objects $f" ;;
 715         esac ;;
 716     esac
 717
 718 # From target name and format, produce a list of supported emulations.
 719
 720     case ${generic_target}-${fmt} in
 721       mips-*-*-*)       case "$endian" in
 722                         big)    emulation="mipsbelf mipslelf mipself" ;;
 723                         *)      emulation="mipslelf mipsbelf mipself" ;;
 724                         esac ;;
 725
 726       # Always all formats.  The first stated emulation becomes the default.
 727       cris-*-*aout*)    emulation="crisaout criself" ;;
 728       cris-*-*)         emulation="criself crisaout" ;;
 729     esac
 730
 731     emulations="$emulations $emulation"
 732
 733 done
 734
 735 if test ${ac_default_x86_relax_relocations} = unset; then
 736   ac_default_x86_relax_relocations=1
 737 fi
 738 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 739   $ac_default_x86_relax_relocations,
 740   [Define to 1 if you want to generate x86 relax relocations by default.])
 741
 742 if test ${ac_default_x86_tls_check} = unset; then
 743   ac_default_x86_tls_check=1
 744 fi
 745 AC_DEFINE_UNQUOTED(DEFAULT_X86_TLS_CHECK,
 746   $ac_default_x86_tls_check,
 747   [Define to 1 if you want to check x86 TLS relocation by default.])
 748
 749 if test ${ac_default_elf_stt_common} = unset; then
 750   ac_default_elf_stt_common=0
 751 fi
 752 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 753   $ac_default_elf_stt_common,
 754   [Define to 1 if you want to generate ELF common symbols with the
 755    STT_COMMON type by default.])
 756
 757 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 758   $ac_default_generate_build_notes,
 759   [Define to 1 if you want to generate GNU Build attribute notes
 760    by default, if none are contained in the input.])
 761
 762 if test ${ac_default_generate_x86_used_note} = unset; then
 763   ac_default_generate_x86_used_note=0
 764 fi
 765 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 766   $ac_default_generate_x86_used_note,
 767   [Define to 1 if you want to generate GNU x86 used ISA and feature
 768    properties by default.])
 769
 770 if test ${ac_default_generate_riscv_attr} = unset; then
 771   ac_default_generate_riscv_attr=1
 772 fi
 773
 774 AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ATTR,
 775   $ac_default_generate_riscv_attr,
 776   [Define to 1 if you want to generate RISC-V arch attribute by default.])
 777
 778 if test ${ac_default_mips_fix_loongson3_llsc} = unset; then
 779   ac_default_mips_fix_loongson3_llsc=0
 780 fi
 781 AC_DEFINE_UNQUOTED(DEFAULT_MIPS_FIX_LOONGSON3_LLSC,
 782   $ac_default_mips_fix_loongson3_llsc,
 783   [Define to 1 if you want to fix Loongson3 LLSC Errata by default.])
 784
 785 if test x$ac_default_compressed_debug_sections = xyes ; then
 786   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 787 fi
 788
 789 AC_DEFINE_UNQUOTED(DEFAULT_COMPRESSED_DEBUG_ALGORITHM, $ac_default_compressed_debug_sections_algorithm,
 790                    [Default compression algorithm for --enable-compressed-debug-sections.])
 791
 792 # PE code has way too many macros tweaking behaviour
 793 case ${te_file} in
 794   pe*) emulations="" ;;
 795 esac
 796
 797 # Assign floating point type.  Most processors with FP support
 798 # IEEE FP.  On those that don't support FP at all, usually IEEE
 799 # is emulated.
 800 case ${target_cpu} in
 801   vax | pdp11 ) atof=vax ;;
 802   *)            atof=ieee ;;
 803 esac
 804
 805 case "${obj_format}" in
 806   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 807 esac
 808
 809 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 810 cgen_cpu_prefix=""
 811 if test $using_cgen = yes ; then
 812   case ${target_cpu} in
 813     or1knd)
 814        cgen_cpu_prefix=or1k ;;
 815     *) cgen_cpu_prefix=${target_cpu} ;;
 816   esac
 817   AC_SUBST(cgen_cpu_prefix)
 818   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 819 fi
 820
 821 dnl
 822 dnl Make sure the desired support files exist.
 823 dnl
 824
 825 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 826   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 827 fi
 828
 829 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 830   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 831 fi
 832
 833 # Some COFF configurations want these random other flags set.
 834 case ${obj_format} in
 835   coff)
 836     case ${target_cpu_type} in
 837       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 838       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 839     esac
 840     ;;
 841 esac
 842
 843 # Getting this done right is going to be a bitch.  Each configuration specified
 844 # with --enable-targets=... should be checked for environment, format, cpu
 845 # setting.
 846 #
 847 # For each configuration, the necessary object file support code must be linked
 848 # in.  This might be only one, it might be up to four.  The necessary emulation
 849 # code needs to be provided, too.
 850 #
 851 # And then there's "--enable-targets=all"....
 852 #
 853 # For now, just always do it for MIPS ELF configurations.  Sigh.
 854
 855 formats="${obj_format}"
 856 emfiles=""
 857 EMULATIONS=""
 858 GAS_UNIQ(emulations)
 859 for em in . $emulations ; do
 860   case $em in
 861     .)  continue ;;
 862     mipsbelf | mipslelf | mipself)
 863         fmt=elf   file=mipself ;;
 864     *coff)
 865         fmt=coff  file=$em ;;
 866     *aout)
 867         fmt=aout file=$em ;;
 868     *elf)
 869         fmt=elf file=$em ;;
 870   esac
 871   formats="$formats $fmt"
 872   emfiles="$emfiles config/e-$file.o"
 873   EMULATIONS="$EMULATIONS &$em,"
 874 done
 875 GAS_UNIQ(formats)
 876 GAS_UNIQ(emfiles)
 877 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 878   for fmt in $formats ; do
 879     case $fmt in
 880       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 881       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 882       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 883       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 884       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 885       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 886     esac
 887     extra_objects="$extra_objects config/obj-$fmt.o"
 888   done
 889   obj_format=multi
 890 fi
 891 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 892   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 893   # e-mipself has more than one emulation per file, e-i386* has just one at the
 894   # moment.  If only one emulation is specified, then don't define
 895   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 896   case "${obj_format}${emfiles}" in
 897     multi* | *mipself*)
 898       extra_objects="$extra_objects $emfiles"
 899       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 900   esac
 901 fi
 902 AC_SUBST(extra_objects)
 903 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 904 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 905                    [Default emulation.])
 906
 907 reject_dev_configs=yes
 908
 909 case ${reject_dev_configs}-${dev} in
 910   yes-yes) # Oops.
 911     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 912     ;;
 913 esac
 914
 915 AC_SUBST(target_cpu_type)
 916 AC_SUBST(obj_format)
 917 AC_SUBST(te_file)
 918 AC_SUBST(install_tooldir)
 919 AC_SUBST(atof)
 920 dnl AC_SUBST(emulation)
 921
 922 # do we need the opcodes library?
 923 case "${need_opcodes}" in
 924 yes)
 925   OPCODES_LIB=../opcodes/libopcodes.la
 926   ;;
 927 esac
 928
 929 AC_SUBST(OPCODES_LIB)
 930
 931 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 932 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 933 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 934 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 935 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 936
 937 AC_PROG_YACC
 938 AM_PROG_LEX
 939
 940 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 941 ZW_GNU_GETTEXT_SISTER_DIR
 942 AM_PO_SUBDIRS
 943
 944 AM_MAINTAINER_MODE
 945 AM_CONDITIONAL(GENINSRC_NEVER, false)
 946 AC_EXEEXT
 947
 948 AC_CHECK_HEADERS(memory.h sys/stat.h sys/types.h unistd.h)
 949
 950 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 951 # people who are not cross-compiling but are compiling cross-assemblers.
 952 AC_MSG_CHECKING(whether compiling a cross-assembler)
 953 if test "${host}" = "${target}"; then
 954   cross_gas=no
 955 else
 956   cross_gas=yes
 957   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 958 fi
 959 AC_MSG_RESULT($cross_gas)
 960
 961 AC_CHECK_FUNCS(strsignal)
 962
 963 AM_LC_MESSAGES
 964
 965 # do we need the math library?
 966 case "${need_libm}" in
 967 yes)
 968   LT_LIB_M
 969   AC_SUBST(LIBM)
 970   ;;
 971 esac
 972
 973 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 974 # enough, but on some of those systems, the assert macro relies on requoting
 975 # working properly!
 976 GAS_WORKING_ASSERT
 977
 978 # On some systems, the system header files may not declare malloc, realloc,
 979 # and free.  There are places where gas needs these functions to have been
 980 # declared -- such as when taking their addresses.
 981 gas_test_headers="
 982 #ifdef HAVE_MEMORY_H
 983 #include <memory.h>
 984 #endif
 985 #include <string.h>
 986 #include <stdlib.h>
 987 #ifdef HAVE_UNISTD_H
 988 #include <unistd.h>
 989 #endif
 990 "
 991
 992 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 993 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 994 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 995 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 996 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 997 if test $gas_cv_decl_getopt_unistd_h = yes; then
 998   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 999             [Is the prototype for getopt in <unistd.h> in the expected format?])
1000 fi
1001
1002 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1003 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
1004
1005 AC_CHECK_DECLS([mempcpy, stpcpy])
1006
1007 BFD_BINARY_FOPEN
1008
1009 # Link in zlib/zstd if we can.  This allows us to write compressed debug sections.
1010 AM_ZLIB
1011 AC_ZSTD
1012
1013 # Support for VMS timestamps via cross compile
1014
1015 if test "$ac_cv_header_time_h" = yes; then
1016   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
1017 fi
1018
1019 if test "$ac_cv_header_sys_stat_h" = yes; then
1020     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
1021     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
1022 fi
1023
1024
1025 dnl Required for html, pdf, install-pdf and install-html targets.
1026 AC_SUBST(datarootdir)
1027 AC_SUBST(docdir)
1028 AC_SUBST(htmldir)
1029 AC_SUBST(pdfdir)
1030
1031 dnl This must come last.
1032
1033 dnl We used to make symlinks to files in the source directory, but now
1034 dnl we just use the right name for .c files, and create .h files in
1035 dnl the build directory which include the right .h file.  Make sure
1036 dnl the old symlinks don't exist, so that a reconfigure in an existing
1037 dnl directory behaves reasonably.
1038
1039 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
1040 AC_CONFIG_COMMANDS([default],
1041 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1042  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1043  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1044  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1045  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1046  if test "x$cgen_cpu_prefix" != x ; then
1047    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1048  fi],
1049 [target_cpu_type=${target_cpu_type}
1050  cgen_cpu_prefix=${cgen_cpu_prefix}
1051  obj_format=${obj_format}
1052  te_file=${te_file}])
1053
1054 AC_OUTPUT
1055
1056 GNU_MAKE_JOBSERVER