gdb/testsuite/gdb.dwarf2/implref-struct.exp

   1 # Copyright 2016-2019 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test a C++ reference marked with DW_OP_GNU_implicit_pointer.
  17 # The referenced value is a global struct whose location is a DW_OP_addr.
  18
  19 if [skip_cplus_tests] {
  20     continue
  21 }
  22
  23 load_lib dwarf.exp
  24
  25 # This test can only be run on targets which support DWARF-2 and use gas.
  26 if ![dwarf2_support] {
  27     return 0
  28 }
  29
  30 # We'll place the output of Dwarf::assemble in implref-struct.S.
  31 standard_testfile .c .S
  32
  33 # ${testfile} is now "implref-struct".  srcfile2 is "implref-struct.S".
  34 set executable ${testfile}
  35 set asm_file [standard_output_file ${srcfile2}]
  36
  37 # We need to know the size of integer and address types in order
  38 # to write some of the debugging info we'd like to generate.
  39 #
  40 # For that, we ask GDB by debugging our implref-struct program.
  41 # Any program would do, but since we already have implref-struct
  42 # specifically for this testcase, might as well use that.
  43 if [prepare_for_testing "failed to prepare" ${testfile} ${srcfile} {debug c++}] {
  44     return -1
  45 }
  46
  47 # Create the DWARF.  We need a regular variable for the struct and a reference
  48 # to it that'll be marked with DW_OP_GNU_implicit_pointer. The variable must be
  49 # global so that its name is an exported symbol that can we can reference from
  50 # the DWARF using gdb_target_symbol.
  51 Dwarf::assemble ${asm_file} {
  52     global srcdir subdir srcfile
  53
  54     cu {} {
  55         DW_TAG_compile_unit {
  56             {DW_AT_language @DW_LANG_C_plus_plus}
  57         } {
  58             declare_labels int_label struct_label variable_label ref_label
  59             set int_size [get_sizeof "int" -1]
  60
  61             # gdb always assumes references are implemented as pointers.
  62             set addr_size [get_sizeof "void *" -1]
  63             set S_size [get_sizeof "S" -1]
  64
  65             # The compiler shouldn't introduce structure padding here.
  66             set b_offset 4
  67             set c_offset 8
  68
  69             int_label: DW_TAG_base_type {
  70                 {DW_AT_byte_size ${int_size} DW_FORM_udata}
  71                 {DW_AT_encoding @DW_ATE_signed}
  72                 {DW_AT_name "int"}
  73             }
  74
  75             struct_label: DW_TAG_structure_type {
  76                 {DW_AT_name "S"}
  77                 {DW_AT_byte_size ${S_size} DW_FORM_udata}
  78             } {
  79                 DW_TAG_member {
  80                     {DW_AT_name "a"}
  81                     {DW_AT_type :${int_label}}
  82                     {DW_AT_data_member_location 0 DW_FORM_udata}
  83                 }
  84
  85                 DW_TAG_member {
  86                     {DW_AT_name "b"}
  87                     {DW_AT_type :${int_label}}
  88                     {DW_AT_data_member_location ${b_offset} DW_FORM_udata}
  89                 }
  90
  91                 DW_TAG_member {
  92                     {DW_AT_name "c"}
  93                     {DW_AT_type :${int_label}}
  94                     {DW_AT_data_member_location ${c_offset} DW_FORM_udata}
  95                 }
  96             }
  97
  98             ref_label: DW_TAG_reference_type {
  99                 {DW_AT_byte_size ${addr_size} DW_FORM_udata}
 100                 {DW_AT_type :${struct_label}}
 101             }
 102
 103             variable_label: DW_TAG_variable {
 104                 {DW_AT_name "s1"}
 105                 {DW_AT_type :${struct_label}}
 106                 {DW_AT_external 1 DW_FORM_flag}
 107                 {DW_AT_location {DW_OP_addr [gdb_target_symbol "s1"]} SPECIAL_expr}
 108             }
 109
 110             DW_TAG_variable {
 111                 {DW_AT_name "s2"}
 112                 {DW_AT_type :${struct_label}}
 113                 {DW_AT_external 1 DW_FORM_flag}
 114                 {DW_AT_location {DW_OP_addr [gdb_target_symbol "s2"]} SPECIAL_expr}
 115             }
 116
 117             DW_TAG_subprogram {
 118                 {MACRO_AT_func { "main" "${srcdir}/${subdir}/${srcfile}" }}
 119                 {DW_AT_type :${int_label}}
 120                 {DW_AT_external 1 DW_FORM_flag}
 121             } {
 122                 DW_TAG_variable {
 123                     {DW_AT_name "ref"}
 124                     {DW_AT_type :${ref_label}}
 125                     {DW_AT_location {DW_OP_GNU_implicit_pointer ${variable_label} 0} SPECIAL_expr}
 126                 }
 127             }
 128         }
 129     }
 130 }
 131
 132 if [prepare_for_testing "failed to prepare" ${executable} [list ${asm_file} ${srcfile}] {}] {
 133     return -1
 134 }
 135
 136 # DW_OP_GNU_implicit_pointer implementation requires a valid frame.
 137 if ![runto_main] {
 138     return -1
 139 }
 140
 141 # Returns the struct members, e.g. '{a = 0, b = 1, c = 2}'.
 142 proc get_members {var} {
 143     set members [get_valueof "" ${var} ""]
 144
 145     # Trim leading/trailing whitespace, '{' and '}' since they confuse TCL to no end.
 146     set members [string trim ${members}]
 147     set members [string trim ${members} "{}"]
 148
 149     return ${members}
 150 }
 151
 152 # Values of the struct members.
 153 set s1_members [get_members "s1"]
 154 set s2_members [get_members "s2"]
 155
 156 # Address of the referenced value.
 157 set address [get_hexadecimal_valueof "&s1" ""]
 158
 159 # Test printing with both 'set print object off' and 'on', just to make sure
 160 # the output doesn't change.
 161 foreach_with_prefix print-object {"off" "on"} {
 162     gdb_test_no_output "set print object ${print-object}"
 163
 164     # Doing 'print ref' should show us e.g.
 165     # '(S &) @0xdeadbeef: {a = 0, b = 1, c = 2}'.
 166     gdb_test "print ref" " = \\(S &\\) @${address}: \\{${s1_members}\\}"
 167
 168     # Doing 'print &ref' should show us e.g. '(S *) 0xdeadbeef <s1>'.
 169     gdb_test "print &ref" " = \\(S \\*\\) ${address} <s1>"
 170
 171     # gdb assumes C++ references are implemented as pointers, and
 172     # print &(&ref) shows us the underlying pointer's address.
 173     # Since in this case there's no physical pointer, gdb should tell us so.
 174     gdb_test "print &(&ref)" "Attempt to take address of value not located in memory."
 175 }
 176
 177 # Test assignment through the synthetic reference.
 178 gdb_test_no_output "set (ref = s2)"
 179
 180 foreach_with_prefix print-object {"off" "on"} {
 181     gdb_test_no_output "set print object ${print-object}"
 182
 183     gdb_test "print ref" " = \\(S &\\) @${address}: \\{${s2_members}\\}" "print ref after assignment"
 184     gdb_test "print s1" " = \\{${s2_members}\\}" "print s1 after assignment"
 185 }