gdb/testsuite/gdb.arch/ftrace-insn-reloc.exp

   1 # Copyright 2015-2022 Free Software Foundation, Inc.
   2 # This program is free software; you can redistribute it and/or modify
   3 # it under the terms of the GNU General Public License as published by
   4 # the Free Software Foundation; either version 3 of the License, or
   5 # (at your option) any later version.
   6 #
   7 # This program is distributed in the hope that it will be useful,
   8 # but WITHOUT ANY WARRANTY; without even the implied warranty of
   9 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10 # GNU General Public License for more details.
  11 #
  12 # You should have received a copy of the GNU General Public License
  13 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14
  15 load_lib "trace-support.exp"
  16
  17 standard_testfile insn-reloc.c
  18 set executable $testfile
  19 set expfile $testfile.exp
  20
  21 # Some targets have leading underscores on assembly symbols.
  22 set additional_flags [gdb_target_symbol_prefix_flags]
  23
  24 if [prepare_for_testing "failed to prepare" $executable $srcfile \
  25         [list debug $additional_flags]] {
  26     return -1
  27 }
  28
  29 if ![runto_main] {
  30     return -1
  31 }
  32
  33 if ![gdb_target_supports_trace] {
  34     unsupported "target does not support trace"
  35     return -1
  36 }
  37
  38 set libipa [get_in_proc_agent]
  39 set remote_libipa [gdb_load_shlib $libipa]
  40
  41 # Can't use prepare_for_testing, because that splits compiling into
  42 # building objects and then linking, and we'd fail with "linker input
  43 # file unused because linking not done" when building the object.
  44
  45 if { [gdb_compile "$srcdir/$subdir/$srcfile" $binfile \
  46           executable [list debug $additional_flags shlib=$libipa] ] != "" } {
  47     untested "failed to compile"
  48     return -1
  49 }
  50 clean_restart ${executable}
  51
  52 if ![runto_main] {
  53     return 0
  54 }
  55
  56 gdb_reinitialize_dir $srcdir/$subdir
  57
  58 if { [gdb_test "info sharedlibrary" ".*${remote_libipa}.*" "IPA loaded"] != 0 } {
  59     untested "could not find IPA lib loaded"
  60     return 1
  61 }
  62
  63 # Read function name from testcases[N].
  64
  65 proc read_testcase { n } {
  66     global gdb_prompt
  67
  68     set result -1
  69     gdb_test_multiple "print testcases\[${n}\]" "read name of test case ${n}" {
  70         -re "\[$\].*= .*<(.*)>.*$gdb_prompt $" {
  71             set result $expect_out(1,string)
  72         }
  73         -re "$gdb_prompt $" { }
  74     }
  75
  76     return $result
  77 }
  78
  79 set n_testcases [gdb_readexpr "n_testcases"]
  80
  81 if { ${n_testcases} == 0 } {
  82     untested "no instruction relocation to test"
  83     return 1
  84 }
  85
  86 # Set a fast tracepoint on each set_point${i} symbol.  There is one for
  87 # each testcase.
  88 for { set i 0 } { ${i} < ${n_testcases} } { incr i } {
  89     set testcase [read_testcase $i]
  90
  91     gdb_test "ftrace *set_point$i" "Fast tracepoint .*" \
  92         "fast tracepoint on ${testcase}"
  93 }
  94
  95 gdb_test "break pass" ".*" ""
  96 gdb_test "break fail" ".*" ""
  97
  98 gdb_test_no_output "tstart" "start trace experiment"
  99
 100 # Make sure we have hit the pass breakpoint for each testcase.
 101 for { set i 0 } { ${i} < ${n_testcases} } { incr i } {
 102     set testcase [read_testcase $i]
 103
 104     gdb_test "continue" \
 105         ".*Breakpoint \[0-9\]+, pass \(\).*" \
 106         "relocated instruction at ${testcase}"
 107 }
 108
 109 gdb_test "tstatus" ".*Collected ${n_testcases} trace frames.*" "check on trace status"
 110
 111 gdb_test "tstop" "" ""