gdb/testsuite/gdb.server/stop-reply-no-thread-multi.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2 #
   3 # Copyright 2021-2022 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Test how GDB handles the case where a target either doesn't use 'T'
  19 # packets at all or doesn't include a thread-id in a 'T' packet, AND,
  20 # where the test program contains multiple threads.
  21 #
  22 # In general if multiple threads are executing and the target doesn't
  23 # include a thread-id in its stop response then GDB will not be able
  24 # to correctly figure out which thread the stop applies to.
  25 #
  26 # However, this test covers a very specific case, there are multiple
  27 # threads but only a single thread is actually executing.  So, when
  28 # the stop comes from the target, without a thread-id, GDB should be
  29 # able to correctly figure out which thread has stopped.
  30
  31 load_lib gdbserver-support.exp
  32
  33 if { [skip_gdbserver_tests] } {
  34     verbose "skipping gdbserver tests"
  35     return -1
  36 }
  37
  38 standard_testfile
  39 if { [build_executable "failed to prepare" $testfile $srcfile {debug pthreads}] == -1 } {
  40     return -1
  41 }
  42
  43 # Run the tests with different features of GDBserver disabled.
  44 # TARGET_NON_STOP is passed to "maint set target-non-stop".
  45 proc run_test { target_non_stop disable_feature } {
  46     global binfile gdb_prompt decimal hex
  47     global GDBFLAGS
  48
  49     save_vars { GDBFLAGS } {
  50         append GDBFLAGS " -ex \"maint set target-non-stop $target_non_stop\""
  51
  52         # If GDB and GDBserver are both running locally, set the sysroot to avoid
  53         # reading files via the remote protocol.
  54         if { ![is_remote host] && ![is_remote target] } {
  55             set GDBFLAGS "$GDBFLAGS -ex \"set sysroot\""
  56         }
  57
  58         clean_restart ${binfile}
  59     }
  60
  61     # Make sure we're disconnected, in case we're testing with an
  62     # extended-remote board, therefore already connected.
  63     gdb_test "disconnect" ".*"
  64
  65     set packet_arg ""
  66     if { $disable_feature != "" } {
  67         set packet_arg "--disable-packet=${disable_feature}"
  68     }
  69     set res [gdbserver_start $packet_arg $binfile]
  70     set gdbserver_protocol [lindex $res 0]
  71     set gdbserver_gdbport [lindex $res 1]
  72
  73     # Disable XML-based thread listing, and multi-process extensions.
  74     gdb_test_no_output "set remote threads-packet off"
  75     gdb_test_no_output "set remote multiprocess-feature-packet off"
  76
  77     set res [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
  78     if ![gdb_assert {$res == 0} "connect"] {
  79         return
  80     }
  81
  82     # There should be only one thread listed at this point.
  83     gdb_test_multiple "info threads" "" {
  84         -re "2 Thread.*$gdb_prompt $" {
  85             fail $gdb_test_name
  86         }
  87         -re "has terminated.*$gdb_prompt $" {
  88             fail $gdb_test_name
  89         }
  90         -re "\\\* 1\[\t \]*Thread\[^\r\n\]*\r\n$gdb_prompt $" {
  91             pass $gdb_test_name
  92         }
  93     }
  94
  95     gdb_breakpoint "unlock_worker"
  96     gdb_continue_to_breakpoint "run to unlock_worker"
  97
  98     # There should be two threads at this point with thread 1 selected.
  99     gdb_test "info threads" \
 100         "\\\* 1\[\t \]*Thread\[^\r\n\]*\r\n  2\[\t \]*Thread\[^\r\n\]*" \
 101         "second thread should now exist"
 102
 103     # Switch threads.
 104     gdb_test "thread 2" ".*" "switch to second thread"
 105
 106     # Now turn on scheduler-locking so that when we step thread 2 only
 107     # that one thread will be set running.
 108     gdb_test_no_output "set scheduler-locking on"
 109
 110     # Single step thread 2.  Only the one thread will step.  When the
 111     # thread stops, if the stop packet doesn't include a thread-id
 112     # then GDB should still understand which thread stopped.
 113     gdb_test_multiple "stepi" "" {
 114         -re -wrap "Thread 1 received signal SIGTRAP.*" {
 115             fail $gdb_test_name
 116         }
 117         -re -wrap "$hex.*$decimal.*while \\(worker_blocked\\).*" {
 118             pass $gdb_test_name
 119         }
 120     }
 121
 122     # Check that thread 2 is still selected.
 123     gdb_test "info threads" \
 124         "  1\[\t \]*Thread\[^\r\n\]*\r\n\\\* 2\[\t \]*Thread\[^\r\n\]*" \
 125         "second thread should still be selected after stepi"
 126
 127     # Turn scheduler locking off again so that when we continue all
 128     # threads will be set running.
 129     gdb_test_no_output "set scheduler-locking off"
 130
 131     # Continue until exit.  The server sends a 'W' with no PID.
 132     # Bad GDB gave an error like below when target is nonstop:
 133     #  (gdb) c
 134     #  Continuing.
 135     #  No process or thread specified in stop reply: W00
 136     gdb_continue_to_end "" continue 1
 137 }
 138
 139 # Disable different features within gdbserver:
 140 #
 141 # Tthread: Start GDBserver, with ";thread:NNN" in T stop replies disabled,
 142 #          emulating old gdbservers when debugging single-threaded programs.
 143 #
 144 # T: Start GDBserver with the entire 'T' stop reply packet disabled,
 145 #    GDBserver will instead send the 'S' stop reply.
 146 #
 147 # Also test both all-stop and non-stop variants of the remote
 148 # protocol.
 149 foreach_with_prefix target-non-stop {"off" "on"} {
 150     foreach_with_prefix to_disable { "" Tthread T } {
 151         run_test ${target-non-stop} $to_disable
 152     }
 153 }