gdb/testsuite/gdb.threads/signal-command-multiple-signals-pending.exp

   1 # Copyright (C) 2014-2022 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  15
  16 # Test that "signal FOO" behaves correctly when we have multiple
  17 # threads that have stopped for a signal.
  18
  19 standard_testfile
  20
  21 if [target_info exists gdb,nosignals] {
  22     verbose "Skipping ${testfile}.exp because of nosignals."
  23     return -1
  24 }
  25
  26 if {[gdb_compile_pthreads "${srcdir}/${subdir}/${srcfile}" "${binfile}" \
  27          executable { debug }] != "" } {
  28     return -1
  29 }
  30
  31 # Run the test proper.  SCHEDLOCK indicates which variant (around
  32 # scheduler-locking) of the test to perform.
  33
  34 proc test { schedlock } {
  35     global srcfile binfile
  36
  37     with_test_prefix "schedlock $schedlock" {
  38         clean_restart ${binfile}
  39
  40         if ![runto_main] then {
  41             return 0
  42         }
  43
  44         gdb_test "handle SIGUSR1 stop print pass"
  45         gdb_test "handle SIGUSR2 stop print pass"
  46
  47         gdb_test "break all_threads_started" "Breakpoint .* at .*$srcfile.*"
  48
  49         # Create threads one at a time, to insure stable thread
  50         # numbers between runs and targets.
  51         gdb_test "break thread_function" "Breakpoint .* at .*$srcfile.*"
  52         gdb_test "continue" "thread_function.*" "thread 2 created"
  53         gdb_test "continue" "thread_function.*" "thread 3 created"
  54
  55         gdb_test "continue" "all_threads_started.*" \
  56             "continue to all_threads_started"
  57
  58         # Using schedlock, let the main thread queue a signal for each
  59         # non-main thread.
  60         gdb_test_no_output "set scheduler-locking on"
  61
  62         gdb_test "break all_threads_signalled" "Breakpoint .* at .*$srcfile.*"
  63         gdb_test "continue" "all_threads_signalled.*" \
  64             "continue to all_threads signalled"
  65
  66         gdb_test "info threads" "\\\* 1\[ \t\]+Thread.*" "thread 1 selected"
  67
  68         # With schedlock still enabled, let each thread report its
  69         # signal.
  70
  71         gdb_test "thread 3" "Switching to thread 3.*"
  72         gdb_test "continue" "Thread 3 .*received signal SIGUSR2.*" "stop with SIGUSR2"
  73         gdb_test "thread 2" "Switching to thread 2.*"
  74         gdb_test "continue" "Thread 2 .*received signal SIGUSR1.*" "stop with SIGUSR1"
  75
  76         gdb_test "break handler_sigusr1" "Breakpoint .* at .*$srcfile.*"
  77         gdb_test "break handler_sigusr2" "Breakpoint .* at .*$srcfile.*"
  78
  79         set handler_re "Breakpoint .*, handler_sigusr. \\(sig=.*\\) at .*"
  80
  81         # Now test the "signal" command with either scheduler locking
  82         # enabled or disabled.
  83
  84         if { $schedlock == "off" } {
  85             # With scheduler locking off, switch to the main thread
  86             # and issue "signal 0".  "signal 0" should then warn that
  87             # two threads have signals that will be delivered.  When
  88             # we let the command proceed, a signal should be
  89             # delivered, and thus the corresponding breakpoint in the
  90             # signal handler should trigger.
  91
  92             gdb_test_no_output "set scheduler-locking off"
  93             gdb_test "thread 1" "Switching to thread 1.*"
  94
  95             set queried 0
  96             set test "signal command queries"
  97             gdb_test_multiple "signal 0" $test {
  98                 -re "stopped with.*stopped with.*stopped with.*Continue anyway.*y or n. $" {
  99                     fail "$test (too many threads noted)"
 100                     set queried 1
 101                 }
 102                 -re "stopped with signal SIGUSR.*\r\nContinuing .*still deliver .*Continue anyway.*y or n. $" {
 103                     pass $test
 104                     set queried 1
 105                 }
 106                 -re "Continue anyway.*y or n. $" {
 107                     fail "$test (no threads noted)"
 108                     set queried 1
 109                 }
 110             }
 111
 112             # Continuing should stop in one of the signal handlers.
 113             # Which thread runs first is not determinate.
 114             if {$queried} {
 115                 gdb_test "y" "$handler_re" "one signal delivered"
 116             }
 117
 118             # Continuing a second time should stop in the other
 119             # handler.
 120             with_test_prefix "second signal" {
 121                 gdb_test "continue" "$handler_re" "signal delivered"
 122             }
 123         } else {
 124             # With scheduler locking on, stay with thread 2 selected,
 125             # and try to deliver its signal explicitly.  The "signal"
 126             # command should then warn that one other thread has a
 127             # signal that will be delivered.  When we let the command
 128             # proceed, the current thread's signal should be
 129             # delivered, and thus the corresponding breakpoint in the
 130             # signal handler should trigger.
 131             gdb_test "signal SIGUSR1" \
 132                 "Breakpoint .*, handler_sigusr1 \\(sig=.*\\) at .*" \
 133                 "signal command does not query, signal delivered"
 134
 135             with_test_prefix "second signal" {
 136                 # The other thread had stopped for a signal too, and
 137                 # it wasn't resumed yet.  Disabling schedlock and
 138                 # trying "signal 0" from the main thread should warn
 139                 # again.
 140                 gdb_test_no_output "set scheduler-locking off"
 141
 142                 set queried 0
 143                 set test "signal command queries"
 144                 gdb_test_multiple "signal 0" $test {
 145                     -re "stopped with.*stopped with.*Continue anyway.*y or n. $" {
 146                         fail "$test (too many threads noted)"
 147                         set queried 1
 148                     }
 149                     -re "stopped with signal SIGUSR.*\r\nContinuing .*still deliver .*Continue anyway.*y or n. $" {
 150                         pass $test
 151                         set queried 1
 152                     }
 153                     -re "Continue anyway.*y or n. $" {
 154                         fail "$test (no threads noted)"
 155                         set queried 1
 156                     }
 157                 }
 158
 159                 if {$queried} {
 160                     gdb_test "y" "Breakpoint .*, handler_sigusr2 \\(sig=.*\\) at .*" "signal delivered"
 161                 }
 162             }
 163         }
 164
 165         # Both threads got their signal.  Continuing again should
 166         # neither intercept nor deliver any other signal.
 167         gdb_test "b end" "Breakpoint .* at .*$srcfile.*"
 168         gdb_test "continue" "end .*" "no more signals"
 169     }
 170 }
 171
 172 foreach schedlock {"off" "on"} {
 173     test $schedlock
 174 }