opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  21 dnl to call AC_CHECK_PROG.
  22 AC_CHECK_TOOL(AR, ar)
  23 AC_CHECK_TOOL(RANLIB, ranlib, :)
  24
  25 dnl Default to a non shared library.  This may be overridden by the
  26 dnl configure option --enable-shared.
  27 AM_DISABLE_SHARED
  28
  29 AM_PROG_LIBTOOL
  30
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  45 esac])dnl
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48
  49 AC_ARG_ENABLE(werror,
  50   [  --enable-werror    treat compile warnings as errors],
  51   [case "${enableval}" in
  52      yes | y) ERROR_ON_WARNING="yes" ;;
  53      no | n)  ERROR_ON_WARNING="no" ;;
  54      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  55    esac])
  56
  57 # Enable -Werror by default, suppressing it only for --disable-werror
  58 # or --disable-build-warnings.
  59 if test "${ERROR_ON_WARNING}" != no
  60 then
  61   build_warnings="$build_warnings -Werror"
  62 fi
  63
  64 AC_ARG_ENABLE(build-warnings,
  65 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  66 [case "${enableval}" in
  67   yes)  ;;
  68   no)   build_warnings="-w";;
  69   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  70         build_warnings="${build_warnings} ${t}";;
  71   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  72         build_warnings="${t} ${build_warnings}";;
  73   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  74 esac
  75 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  76   echo "Setting warning flags = $build_warnings" 6>&1
  77 fi])dnl
  78 WARN_CFLAGS=""
  79 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  80     WARN_CFLAGS="${build_warnings}"
  81 fi
  82 AC_SUBST(WARN_CFLAGS)
  83
  84 AM_CONFIG_HEADER(config.h:config.in)
  85
  86 if test -z "$target" ; then
  87     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  88 fi
  89
  90 AM_MAINTAINER_MODE
  91 AM_INSTALL_LIBBFD
  92 AC_EXEEXT
  93
  94 # host-specific stuff:
  95
  96 AC_PROG_CC
  97
  98 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl"
  99 CY_GNU_GETTEXT
 100
 101 . ${srcdir}/../bfd/configure.host
 102
 103 BFD_CC_FOR_BUILD
 104
 105 AC_SUBST(HDEFINES)
 106 AC_PROG_INSTALL
 107
 108 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
 109
 110 AC_CHECK_DECLS(basename, , , [#include "sysdep.h"])
 111
 112 cgen_maint=no
 113 cgendir='$(srcdir)/../cgen'
 114
 115 AC_ARG_ENABLE(cgen-maint,
 116 [  --enable-cgen-maint[=dir]    build cgen generated files],
 117 [case "${enableval}" in
 118   yes)  cgen_maint=yes ;;
 119   no)   cgen_maint=no ;;
 120   *)
 121         # argument is cgen install directory (not implemented yet).
 122         # Having a `share' directory might be more appropriate for the .scm,
 123         # .cpu, etc. files.
 124         cgen_maint=yes
 125         cgendir=${cgen_maint}/lib/cgen
 126         ;;
 127 esac])dnl
 128 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 129 AC_SUBST(cgendir)
 130
 131 using_cgen=no
 132
 133 # Horrible hacks to build DLLs on Windows.
 134 WIN32LDFLAGS=
 135 WIN32LIBADD=
 136 case "${host}" in
 137 *-*-cygwin*)
 138   if test "$enable_shared" = "yes"; then
 139     WIN32LDFLAGS="-no-undefined"
 140     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 141   fi
 142   ;;
 143 esac
 144 AC_SUBST(WIN32LDFLAGS)
 145 AC_SUBST(WIN32LIBADD)
 146
 147 # target-specific stuff:
 148
 149 # Canonicalize the secondary target names.
 150 if test -n "$enable_targets" ; then
 151     for targ in `echo $enable_targets | sed 's/,/ /g'`
 152     do
 153         result=`$ac_config_sub $targ 2>/dev/null`
 154         if test -n "$result" ; then
 155             canon_targets="$canon_targets $result"
 156         else
 157             # Allow targets that config.sub doesn't recognize, like "all".
 158             canon_targets="$canon_targets $targ"
 159         fi
 160     done
 161 fi
 162
 163 all_targets=false
 164 selarchs=
 165 for targ in $target $canon_targets
 166 do
 167     if test "x$targ" = "xall" ; then
 168         all_targets=true
 169     else
 170         . $srcdir/../bfd/config.bfd
 171         selarchs="$selarchs $targ_archs"
 172     fi
 173 done
 174
 175 # Utility var, documents generic cgen support files.
 176
 177 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 178
 179 # We don't do any links based on the target system, just makefile config.
 180
 181 if test x${all_targets} = xfalse ; then
 182
 183     # Target architecture .o files.
 184     ta=
 185
 186     for arch in $selarchs
 187     do
 188         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 189         archdefs="$archdefs -DARCH_$ad"
 190         case "$arch" in
 191         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 192         bfd_alliant_arch)       ;;
 193         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 194         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 195         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 196         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 197         bfd_convex_arch)        ;;
 198         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo" ;;
 199         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 200         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 201         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 202         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 203         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 204         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 205         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 206         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 207         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 208         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 209         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 210         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 211         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 212         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 213         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 214         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 215         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 216         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 217         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 218         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 219         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 220         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 221         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 222         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 223         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 224         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 225         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 226         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 227         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 228         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 229         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 230         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 231         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 232         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 233         bfd_pyramid_arch)       ;;
 234         bfd_romp_arch)          ;;
 235         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 236         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 237         bfd_sh_arch)
 238           # We can't decide what we want just from the CPU family.
 239           # We want SH5 support unless a specific version of sh is
 240           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 241           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 242           for t in $target $canon_targets; do
 243             case $t in
 244               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 245               sh-*-linux* | shl-*-linux*)
 246                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 247                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 248                                 break;;
 249             esac;
 250           done
 251                                 ta="$ta sh-dis.lo" ;;
 252         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 253         bfd_tahoe_arch)         ;;
 254         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 255         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 256         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 257         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 258         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 259         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 260         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 261         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 262         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 263         bfd_we32k_arch)         ;;
 264         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 265         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 266         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 267         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 268
 269         "")                     ;;
 270         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 271         esac
 272     done
 273
 274     if test $using_cgen = yes ; then
 275         ta="$ta $cgen_files"
 276     fi
 277
 278     # Weed out duplicate .o files.
 279     f=""
 280     for i in $ta ; do
 281         case " $f " in
 282         *" $i "*) ;;
 283         *) f="$f $i" ;;
 284         esac
 285     done
 286     ta="$f"
 287
 288     # And duplicate -D flags.
 289     f=""
 290     for i in $archdefs ; do
 291         case " $f " in
 292         *" $i "*) ;;
 293         *) f="$f $i" ;;
 294         esac
 295     done
 296     archdefs="$f"
 297
 298     BFD_MACHINES="$ta"
 299
 300 else    # all_targets is true
 301     archdefs=-DARCH_all
 302     BFD_MACHINES='$(ALL_MACHINES)'
 303 fi
 304
 305 AC_SUBST(archdefs)
 306 AC_SUBST(BFD_MACHINES)
 307
 308 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 309 AC_CONFIG_COMMANDS([default],[[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile]],[[]])
 310 AC_OUTPUT