bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.17)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AC_ARG_ENABLE(secureplt,
  55 [  --enable-secureplt      Default to creating read-only plt entries],
  56 [case "${enableval}" in
  57   yes)  use_secureplt=true  ;;
  58   no)   use_secureplt=false ;;
  59   *)    AC_MSG_ERROR(bad value ${enableval} for secureplt option) ;;
  60 esac],[use_secureplt=false])dnl
  61 if test $use_secureplt = true; then
  62   AC_DEFINE(USE_SECUREPLT, 1,
  63     [Define if we should default to creating read-only plt entries])
  64 fi
  65
  66 # Package version.  For an official FSF release, it is empty.
  67 AC_ARG_WITH(pkgversion,
  68   AS_HELP_STRING([--with-pkgversion=PKG],
  69                  [Add PKG to the version string]),
  70   [case "$withval" in
  71     yes) AC_MSG_ERROR([package version not specified]) ;;
  72     no)  PKGVERSION= ;;
  73     *)   PKGVERSION="($withval) " ;;
  74    esac],
  75   PKGVERSION=
  76 )
  77 AC_SUBST(PKGVERSION)
  78
  79 AM_BINUTILS_WARNINGS
  80
  81 AM_CONFIG_HEADER(config.h:config.in)
  82
  83 if test -z "$target" ; then
  84     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  85 fi
  86
  87 AM_MAINTAINER_MODE
  88 AM_INSTALL_LIBBFD
  89 AC_EXEEXT
  90
  91 host64=false
  92 target64=false
  93 bfd_default_target_size=32
  94
  95 # host stuff:
  96
  97 AC_PROG_CC
  98 AC_GNU_SOURCE
  99
 100 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw vi"
 101 CY_GNU_GETTEXT
 102
 103 # Permit host specific settings.
 104 . ${srcdir}/configure.host
 105
 106 AC_SUBST(HDEFINES)
 107 AC_PROG_INSTALL
 108
 109 BFD_HOST_64BIT_LONG=0
 110 BFD_HOST_LONG_LONG=0
 111 BFD_HOST_64_BIT_DEFINED=0
 112 BFD_HOST_64_BIT=
 113 BFD_HOST_U_64_BIT=
 114
 115 AC_MSG_CHECKING([for long long])
 116 AC_CACHE_VAL(bfd_cv_has_long_long,
 117 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 118 AC_MSG_RESULT($bfd_cv_has_long_long)
 119 if test $bfd_cv_has_long_long = yes; then
 120   BFD_HOST_LONG_LONG=1
 121   AC_CHECK_SIZEOF(long long)
 122 fi
 123
 124 AC_CHECK_SIZEOF(long)
 125 if test "x${ac_cv_sizeof_long}" = "x8"; then
 126   host64=true
 127   BFD_HOST_64BIT_LONG=1
 128   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 129   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 130 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 131   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 132   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 133 fi
 134
 135 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 136   BFD_HOST_64_BIT_DEFINED=1
 137   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 138   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 139 fi
 140
 141 AC_SUBST(BFD_HOST_64BIT_LONG)
 142 AC_SUBST(BFD_HOST_LONG_LONG)
 143 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 144 AC_SUBST(BFD_HOST_64_BIT)
 145 AC_SUBST(BFD_HOST_U_64_BIT)
 146
 147 BFD_CC_FOR_BUILD
 148
 149 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 150 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 151 AC_HEADER_TIME
 152 AC_HEADER_DIRENT
 153 ACX_HEADER_STRING
 154 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 155 AC_CHECK_FUNCS(strtoull)
 156
 157 AC_CHECK_DECLS(basename)
 158 AC_CHECK_DECLS(ftello)
 159 AC_CHECK_DECLS(ftello64)
 160 AC_CHECK_DECLS(fseeko)
 161 AC_CHECK_DECLS(fseeko64)
 162
 163 BFD_BINARY_FOPEN
 164
 165 AC_CHECK_DECLS(ffs)
 166 AC_CHECK_DECLS(free)
 167 AC_CHECK_DECLS(getenv)
 168 AC_CHECK_DECLS(malloc)
 169 AC_CHECK_DECLS(realloc)
 170 AC_CHECK_DECLS(stpcpy)
 171 AC_CHECK_DECLS(strstr)
 172 AC_CHECK_DECLS(snprintf)
 173 AC_CHECK_DECLS(vsnprintf)
 174
 175 # If we are configured native, pick a core file support file.
 176 COREFILE=
 177 COREFLAG=
 178 TRAD_HEADER=
 179 if test "${target}" = "${host}"; then
 180   case "${host}" in
 181   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 182         COREFILE=''
 183         ;;
 184   alpha*-*-linux-*)
 185         COREFILE=trad-core.lo
 186         TRAD_HEADER='"hosts/alphalinux.h"'
 187         ;;
 188   alpha*-*-netbsd* | alpha*-*-openbsd*)
 189         COREFILE=netbsd-core.lo
 190         ;;
 191   alpha*-*-*)           COREFILE=osf-core.lo ;;
 192   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 193                         COREFILE='' ;;
 194   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 195   arm-*-riscix)         COREFILE=trad-core.lo ;;
 196   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 197   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 198   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 199   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 200                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 201   hppa*-*-netbsd* | hppa*-*-openbsd*)
 202         COREFILE=netbsd-core.lo
 203         ;;
 204
 205   i370-*-*)
 206         COREFILE=trad-core.lo
 207         TRAD_HEADER='"hosts/i370linux.h"'
 208         ;;
 209
 210 changequote(,)dnl
 211   i[3-7]86-sequent-bsd*)
 212 changequote([,])dnl
 213         COREFILE=trad-core.lo
 214         TRAD_HEADER='"hosts/symmetry.h"'
 215         ;;
 216 changequote(,)dnl
 217   i[3-7]86-sequent-sysv4*) ;;
 218   i[3-7]86-sequent-sysv*)
 219 changequote([,])dnl
 220         COREFILE=trad-core.lo
 221         TRAD_HEADER='"hosts/symmetry.h"'
 222         ;;
 223 changequote(,)dnl
 224   i[3-7]86-*-bsdi)
 225 changequote([,])dnl
 226         COREFILE=
 227         ;;
 228 changequote(,)dnl
 229   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 230 changequote([,])dnl
 231         COREFILE=trad-core.lo
 232         TRAD_HEADER='"hosts/i386bsd.h"'
 233         ;;
 234 changequote(,)dnl
 235   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 236 changequote([,])dnl
 237         COREFILE=''
 238         TRAD_HEADER='"hosts/i386bsd.h"'
 239         ;;
 240 changequote(,)dnl
 241   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 242 changequote([,])dnl
 243         COREFILE=netbsd-core.lo
 244         ;;
 245 changequote(,)dnl
 246   i[3-7]86-esix-sysv3*)
 247 changequote([,])dnl
 248         COREFILE=trad-core.lo
 249         TRAD_HEADER='"hosts/esix.h"'
 250         ;;
 251 changequote(,)dnl
 252   i[3-7]86-*-sco3.2v5*)
 253 changequote([,])dnl
 254         COREFILE=sco5-core.lo
 255         ;;
 256 changequote(,)dnl
 257   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 258 changequote([,])dnl
 259         COREFILE=trad-core.lo
 260         TRAD_HEADER='"hosts/i386sco.h"'
 261         ;;
 262 changequote(,)dnl
 263   i[3-7]86-*-mach3*)
 264 changequote([,])dnl
 265         COREFILE=trad-core.lo
 266         TRAD_HEADER='"hosts/i386mach3.h"'
 267         ;;
 268 changequote(,)dnl
 269   i[3-7]86-*-linux-*)
 270 changequote([,])dnl
 271         COREFILE=trad-core.lo
 272         TRAD_HEADER='"hosts/i386linux.h"'
 273         ;;
 274 changequote(,)dnl
 275   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 276   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 277 changequote([,])dnl
 278   i860-*-mach3* | i860-*-osf1*)
 279         COREFILE=trad-core.lo
 280         TRAD_HEADER='"hosts/i860mach3.h"'
 281         ;;
 282   mips-*-netbsd* | mips*-*-openbsd*)
 283         COREFILE=netbsd-core.lo
 284         ;;
 285   mips-dec-*)
 286         COREFILE=trad-core.lo
 287         TRAD_HEADER='"hosts/decstation.h"'
 288         ;;
 289   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 290   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 291   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 292   mips-*-sysv4*)        ;;
 293   mips-*-sysv* | mips-*-riscos*)
 294         COREFILE=trad-core.lo
 295         TRAD_HEADER='"hosts/riscos.h"'
 296         ;;
 297   mips-sony-bsd*)
 298         COREFILE=trad-core.lo
 299         TRAD_HEADER='"hosts/news-mips.h"'
 300         ;;
 301   m68*-bull*-sysv*)
 302         COREFILE=trad-core.lo
 303         TRAD_HEADER='"hosts/dpx2.h"'
 304         ;;
 305   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 306   m68*-hp-bsd*)
 307         COREFILE=trad-core.lo
 308         TRAD_HEADER='"hosts/hp300bsd.h"'
 309         ;;
 310   m68*-*-linux-*)
 311         COREFILE=trad-core.lo
 312         TRAD_HEADER='"hosts/m68klinux.h"'
 313         ;;
 314   m68*-motorola-sysv*)
 315         COREFILE=trad-core.lo
 316         TRAD_HEADER='"hosts/delta68.h"'
 317         ;;
 318   m68*-sony-*)
 319         COREFILE=trad-core.lo
 320         TRAD_HEADER='"hosts/news.h"'
 321         ;;
 322   m68*-*-netbsd* | m68*-*-openbsd*)
 323         COREFILE=netbsd-core.lo
 324         ;;
 325   m68*-apple-aux*)
 326         COREFILE=trad-core.lo
 327         TRAD_HEADER='"hosts/m68kaux.h"'
 328         ;;
 329   m88*-*-sysv4*)
 330         ;;
 331   m88*-motorola-sysv*)
 332         COREFILE=ptrace-core.lo
 333         ;;
 334   m88*-*-mach3*)
 335         COREFILE=trad-core.lo
 336         TRAD_HEADER='"hosts/m88kmach3.h"'
 337         ;;
 338   m88*-*-openbsd*)
 339         COREFILE=netbsd-core.lo
 340         ;;
 341   ns32k-pc532-mach)
 342         COREFILE=trad-core.lo
 343         TRAD_HEADER='"hosts/pc532mach.h"'
 344         ;;
 345   ns32k-*-netbsd* | ns32k-*-openbsd*)
 346         COREFILE=netbsd-core.lo
 347         ;;
 348   rs6000-*-lynx*)
 349         COREFILE=lynx-core.lo
 350         ;;
 351   rs6000-*-aix5.* | powerpc-*-aix5.*)
 352         COREFILE=rs6000-core.lo
 353         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 354         ;;
 355 changequote(,)dnl
 356   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 357 changequote([,])dnl
 358         COREFILE=rs6000-core.lo
 359         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 360         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 361         # have c_impl as a member of struct core_dumpx
 362         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 363         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 364             [Define if struct core_dumpx has member c_impl])
 365           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 366         ;;
 367   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 368   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 369   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 370   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 371   powerpc-*-beos*)      ;;
 372   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 373                         COREFILE='' ;;
 374   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 375   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 376   s390*-*-*)            COREFILE=trad-core.lo ;;
 377   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 378   sparc-*-netbsd* | sparc*-*-openbsd*)
 379         COREFILE=netbsd-core.lo
 380         ;;
 381   tahoe-*-*)
 382         COREFILE=trad-core.lo
 383         TRAD_HEADER='"hosts/tahoe.h"'
 384         ;;
 385   vax-*-netbsd* | vax-*-openbsd*)
 386         COREFILE=netbsd-core.lo
 387         ;;
 388   vax-*-ultrix2*)
 389         COREFILE=trad-core.lo
 390         TRAD_HEADER='"hosts/vaxult2.h"'
 391         ;;
 392   vax-*-ultrix*)
 393         COREFILE=trad-core.lo
 394         TRAD_HEADER='"hosts/vaxult2.h"'
 395         ;;
 396   vax-*-linux-*)
 397         COREFILE=trad-core.lo
 398         TRAD_HEADER='"hosts/vaxlinux.h"'
 399         ;;
 400   vax-*-*)
 401         COREFILE=trad-core.lo
 402         TRAD_HEADER='"hosts/vaxbsd.h"'
 403         ;;
 404   x86_64-*-netbsd* | x86_64-*-openbsd*)
 405         COREFILE=netbsd-core.lo
 406         ;;
 407   esac
 408
 409   case "$COREFILE" in
 410   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 411   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 412   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 413   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 414   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 415   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 416   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 417   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 418   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 419   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 420   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 421   esac
 422
 423   # ELF corefile support has several flavors, but all of
 424   # them use something called <sys/procfs.h>
 425   AC_CHECK_HEADERS(sys/procfs.h)
 426   if test "$ac_cv_header_sys_procfs_h" = yes; then
 427     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 428     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 429     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 430     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 431     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 432     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 433     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 434     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 435     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 436     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 437     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 438     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 439     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 440     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 441     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 442     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 443   fi
 444 fi
 445 AC_SUBST(COREFILE)
 446 AC_SUBST(COREFLAG)
 447 if test -n "$TRAD_HEADER"; then
 448   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 449     [Name of host specific header file to include in trad-core.c.])
 450 fi
 451
 452 # Horrible hacks to build DLLs on Windows.
 453 WIN32LDFLAGS=
 454 WIN32LIBADD=
 455 case "${host}" in
 456 *-*-cygwin*)
 457   if test "$enable_shared" = "yes"; then
 458     WIN32LDFLAGS="-no-undefined"
 459     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 460   fi
 461   ;;
 462 *-*-linux*)
 463   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 464   # libiberty.a.
 465   case "${host}" in
 466   mips*-*-linux*)
 467     # Linux/MIPS uses PIC by default.
 468     if test "$enable_shared" = "yes"; then
 469       WIN32LIBADD="-L../libiberty -liberty"
 470     fi
 471     ;;
 472   *)
 473 changequote(,)dnl
 474     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 475 changequote([,])dnl
 476     if test -n "$x"; then
 477       WIN32LIBADD="-L../libiberty/pic -liberty"
 478     fi
 479   ;;
 480   esac
 481   ;;
 482 esac
 483 AC_SUBST(WIN32LDFLAGS)
 484 AC_SUBST(WIN32LIBADD)
 485
 486 # target stuff:
 487
 488 # Canonicalize the secondary target names.
 489 if test -n "$enable_targets" ; then
 490     for targ in `echo $enable_targets | sed 's/,/ /g'`
 491     do
 492         result=`$ac_config_sub $targ 2>/dev/null`
 493         if test -n "$result" ; then
 494             canon_targets="$canon_targets $result"
 495         else
 496             # Allow targets that config.sub doesn't recognize, like "all".
 497             canon_targets="$canon_targets $targ"
 498         fi
 499     done
 500 fi
 501
 502 all_targets=false
 503 defvec=
 504 selvecs=
 505 assocvecs=
 506 selarchs=
 507 TDEFINES=
 508 for targ in $target $canon_targets
 509 do
 510     if test "x$targ" = "xall"; then
 511         all_targets=true
 512         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 513     else
 514         . $srcdir/config.bfd
 515         if test "x$targ" = "x$target"; then
 516             defvec=$targ_defvec
 517         fi
 518         selvecs="$selvecs $targ_defvec $targ_selvecs"
 519         selarchs="$selarchs $targ_archs"
 520         TDEFINES="$TDEFINES $targ_cflags"
 521     fi
 522 done
 523 AC_SUBST(TDEFINES)
 524
 525 # This processing still needs to be done if we're to decide properly whether
 526 # 64-bit support needs to be compiled in.  Currently, it will be included if
 527 # the default or any other explicitly requested target requires it; it
 528 # will not be included on a 32-bit host if no 64-bit target is requested, and
 529 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 530 # used.
 531
 532 # uniq the default and selected vectors in all the configured targets.
 533 f=""
 534 for i in $selvecs ; do
 535     case " $f " in
 536     *" $i "*) ;;
 537     *) f="$f $i" ;;
 538     esac
 539 done
 540 selvecs="$f"
 541
 542
 543 # uniq the associated vectors in all the configured targets.
 544 f=""
 545 for i in $assocvecs ; do
 546     case " $f " in
 547     *" $i "*) ;;
 548     *) f="$f $i" ;;
 549     esac
 550 done
 551 assocvecs="$f"
 552
 553
 554 # uniq the architectures in all the configured targets.
 555 f=""
 556 for i in $selarchs ; do
 557     case " $f " in
 558     *" $i "*) ;;
 559     *) f="$f $i" ;;
 560     esac
 561 done
 562 selarchs="$f"
 563
 564 # Target backend .o files.
 565 tb=
 566
 567 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 568
 569 for vec in $selvecs
 570 do
 571     target_size=32
 572     case "$vec" in
 573     # This list is alphabetized to make it easy to compare
 574     # with the two vector lists in targets.c.  For the same reason,
 575     # use one entry per line, even though this leads to long lines.
 576     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 577     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 578     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 579     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 580     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 581     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 582     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 583     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 584     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 585     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 586     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 587     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 588     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 589     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 590     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 591     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 592     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 593     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 594     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 595     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 596     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 597     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 598     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 599     bfd_elf32_bfin_vec)         tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 600     bfd_elf32_bfinfdpic_vec)    tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 601     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 602     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 603     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 604     bfd_elf32_bigarm_symbian_vec)
 605                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 606     bfd_elf32_bigarm_vxworks_vec)
 607                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 608     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 609     bfd_elf32_bigmips_vxworks_vec)
 610                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 611     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 612     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 613     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 614     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 615     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 616     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 617     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 618     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 619     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 620     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 621     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 622     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 623     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 624     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 625     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 626     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 627     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 628     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 629     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 630     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 631     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 632     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 633     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 634     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 635     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 636     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 637     bfd_elf32_littlearm_symbian_vec)
 638                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 639     bfd_elf32_littlearm_vxworks_vec)
 640                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 641     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 642     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 643     bfd_elf32_littlemips_vxworks_vec)
 644                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 645     bfd_elf32_m32c_vec)         tb="$tb elf32-m32c.lo elf32.lo $elf" ;;
 646     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 647     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 648     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 649     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 650     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 651     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 652     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 653     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 654     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 655     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 656     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 657     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 658     bfd_elf32_mt_vec)           tb="$tb elf32-mt.lo elf32.lo $elf" ;;
 659     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 660     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 661     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 662     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 663     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 664     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 665     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 666     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 667     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 668     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 669     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 670     bfd_elf32_powerpc_vxworks_vec) tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 671     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 672     # FIXME: We include cofflink.lo not because it's needed for
 673     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 674     # which needs it but does not list it.  Should be fixed in right place.
 675     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 676     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 677     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 678     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 679     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 680     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 681     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 682     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 683     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 684     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 685     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 686     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 687     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 688     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 689     bfd_elf32_sparc_vxworks_vec) tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 690     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 691     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 692     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 693     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 694     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 695     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 696     bfd_elf32_xc16x_vec)                tb="$tb elf32-xc16x.lo elf32.lo $elf" ;;
 697     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 698     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 699     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 700     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 701     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 702     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 703     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 704     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 705     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 706     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 707     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 708     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 709     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 710     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 711     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 712     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 713     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 714     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 715     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 716     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 717     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 718     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 719     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 720     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf64.lo $elf"; target_size=64 ;;
 721     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 722     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 723     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 724     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 725     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 726     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 727     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 728     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 729     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 730     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 731     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 732     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 733     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 734     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 735     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 736     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 737     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 738     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 739     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 740     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 741     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 742     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 743     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 744     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 745     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 746     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 747     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 748     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 749     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 750     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 751     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 752     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 753     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 754     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 755     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 756     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 757     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 758     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 759     ieee_vec)                   tb="$tb ieee.lo" ;;
 760     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 761     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 762     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 763     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 764     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 765     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 766     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 767     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 768     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 769     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 770     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 771     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 772     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 773     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 774     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 775     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 776     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 777     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 778     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 779     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 780     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 781     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 782     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 783     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 784     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 785     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 786     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 787     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 788     pef_vec)                    tb="$tb pef.lo" ;;
 789     pef_xlib_vec)               tb="$tb pef.lo" ;;
 790     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 791     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 792     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 793     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 794     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 795     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 796     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 797     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 798     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 799     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 800     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 801     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 802     som_vec)                    tb="$tb som.lo" ;;
 803     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 804     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 805     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 806     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 807     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 808     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 809     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 810     sym_vec)                    tb="$tb xsym.lo" ;;
 811     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 812     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 813     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 814     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 815     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 816     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 817     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 818     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 819     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 820     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 821     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 822     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 823     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 824     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 825     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 826     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 827     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 828     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 829     versados_vec)               tb="$tb versados.lo" ;;
 830     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 831     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 832     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 833     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 834     z80coff_vec)                tb="$tb coff-z80.lo reloc16.lo" ;;
 835     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo cofflink.lo" ;;
 836
 837     # These appear out of order in targets.c
 838     srec_vec)                   tb="$tb srec.lo" ;;
 839     symbolsrec_vec)             tb="$tb srec.lo" ;;
 840     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 841     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 842     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 843
 844     "")                 ;;
 845     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 846     esac
 847
 848     if test ${target_size} = 64; then
 849         target64=true
 850     fi
 851     if test x"${vec}" = x"${defvec}"; then
 852         bfd_default_target_size=${target_size}
 853     fi
 854 done
 855
 856 # Target architecture .o files.
 857 # A couple of CPUs use shorter file names to avoid problems on DOS
 858 # filesystems.
 859 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 860
 861 # Weed out duplicate .o files.
 862 f=""
 863 for i in $tb ; do
 864     case " $f " in
 865     *" $i "*) ;;
 866     *) f="$f $i" ;;
 867     esac
 868 done
 869 tb="$f"
 870
 871 f=""
 872 for i in $ta ; do
 873     case " $f " in
 874     *" $i "*) ;;
 875     *) f="$f $i" ;;
 876     esac
 877 done
 878 ta="$f"
 879
 880 bfd_backends="$tb"
 881 bfd_machines="$ta"
 882
 883 if test x${all_targets} = xtrue ; then
 884   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 885   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 886   selvecs=
 887   havevecs=
 888   selarchs=
 889   test -n "$assocvecs" &&
 890     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 891 else    # all_targets is true
 892   # Only set these if they will be nonempty, for the clever echo.
 893   havevecs=
 894   assocvecs=
 895   test -n "$selvecs" &&
 896     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 897   test -n "$selvecs" &&
 898     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 899   test -n "$selarchs" &&
 900     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 901 fi      # all_targets is true
 902
 903 case ${host64}-${target64}-${want64} in
 904   *true*)
 905     wordsize=64
 906     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 907     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 908     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 909       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 910       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 911     fi
 912     if test -n "$GCC" ; then
 913        bad_64bit_gcc=no;
 914        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 915        # Add more tests for gcc versions with non-working 64-bit support here.
 916        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 917                     bad_64bit_gcc=yes;
 918                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 919                     AC_MSG_RESULT(no))
 920        if test $bad_64bit_gcc = yes ; then
 921          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 922        fi
 923     fi
 924     ;;
 925   false-false-false)
 926     wordsize=32
 927     bfd_libs='$(BFD32_LIBS)'
 928     all_backends='$(BFD32_BACKENDS)'
 929     ;;
 930 esac
 931
 932 AC_SUBST(wordsize)
 933 AC_SUBST(bfd_libs)
 934 AC_SUBST(all_backends)
 935 AC_SUBST(bfd_backends)
 936 AC_SUBST(bfd_machines)
 937 AC_SUBST(bfd_default_target_size)
 938
 939 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 940 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 941 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 942 # Hopefully a reasonable assumption since fseeko et.al. should be
 943 # upward compatible.
 944 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64 fopen64)
 945 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 946     AC_CHECK_SIZEOF(off_t)
 947 fi
 948 AC_MSG_CHECKING([file_ptr type])
 949 bfd_file_ptr="long"
 950 bfd_ufile_ptr="unsigned long"
 951 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 952         -o x"${ac_cv_sizeof_off_t}" = x8; then
 953     bfd_file_ptr=BFD_HOST_64_BIT
 954     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 955 fi
 956 AC_MSG_RESULT($bfd_file_ptr)
 957 AC_SUBST(bfd_file_ptr)
 958 AC_SUBST(bfd_ufile_ptr)
 959
 960
 961 tdefaults=""
 962 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 963 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 964 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 965 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 966 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 967 AC_SUBST(tdefaults)
 968
 969 dnl AC_CHECK_HEADERS(sys/mman.h)
 970 AC_FUNC_MMAP
 971 AC_CHECK_FUNCS(madvise mprotect)
 972 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 973   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 974 esac
 975
 976 rm -f doc/config.status
 977 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 978 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 979
 980 dnl Required by html and install-html
 981 AC_SUBST(datarootdir)
 982 AC_SUBST(docdir)
 983 AC_SUBST(htmldir)
 984
 985 AC_OUTPUT
 986