libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 GCC_NO_EXECUTABLES
 113 AC_PROG_CC
 114 AC_PROG_CPP_WERROR
 115
 116 if test x$GCC = xyes; then
 117   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
 118 fi
 119 AC_SUBST(ac_libiberty_warn_cflags)
 120
 121 AC_PROG_CC_C_O
 122 # autoconf is lame and doesn't give us any substitution variable for this.
 123 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 124   NO_MINUS_C_MINUS_O=yes
 125 else
 126   OUTPUT_OPTION='-o $@'
 127 fi
 128 AC_SUBST(NO_MINUS_C_MINUS_O)
 129 AC_SUBST(OUTPUT_OPTION)
 130
 131 AC_C_CONST
 132 AC_C_INLINE
 133 AC_C_BIGENDIAN_CROSS
 134
 135 dnl When we start using libtool:
 136 dnl Default to a non shared library.  This may be overridden by the
 137 dnl configure option --enable-shared.
 138 dnl AM_DISABLE_SHARED
 139
 140 dnl When we start using libtool:
 141 dnl AM_PROG_LIBTOOL
 142
 143 dnl When we start using automake:
 144 dnl AM_CONFIG_HEADER(config.h:config.in)
 145 AC_CONFIG_HEADER(config.h:config.in)
 146
 147 dnl When we start using automake:
 148 dnl AM_MAINTAINER_MODE
 149 dnl AC_EXEEXT
 150
 151 dnl When we start using automake:
 152 dnl AM_PROG_INSTALL
 153 AC_PROG_INSTALL
 154
 155 . ${srcdir}/config.table
 156 host_makefile_frag=${frag}
 157 AC_SUBST_FILE(host_makefile_frag)
 158
 159 # It's OK to check for header files.  Although the compiler may not be
 160 # able to link anything, it had better be able to at least compile
 161 # something.
 162 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h)
 163 AC_HEADER_SYS_WAIT
 164 AC_HEADER_TIME
 165
 166 libiberty_AC_DECLARE_ERRNO
 167
 168 # Determine the size of an int for struct fibnode.
 169 AC_CHECK_SIZEOF([int])
 170
 171 AC_CHECK_TYPE(uintptr_t, unsigned long)
 172
 173 # Look for a 64-bit type.
 174 AC_MSG_CHECKING([for a 64-bit type])
 175 AC_CACHE_VAL(liberty_cv_uint64,
 176 [AC_TRY_COMPILE(
 177 [#ifdef HAVE_STDINT_H
 178 #include <stdint.h>
 179 #endif],
 180 [extern uint64_t foo;],
 181 liberty_cv_uint64=uint64_t,
 182 [AC_TRY_COMPILE(
 183 [#ifdef HAVE_LIMITS_H
 184 #include <limits.h>
 185 #endif
 186 #ifndef CHAR_BIT
 187 #define CHAR_BIT 8
 188 #endif],
 189 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 190 liberty_cv_uint64="unsigned long",
 191 [AC_TRY_COMPILE(
 192 [#ifdef HAVE_LIMITS_H
 193 #include <limits.h>
 194 #endif
 195 #ifndef CHAR_BIT
 196 #define CHAR_BIT 8
 197 #endif],
 198 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 199 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 200 AC_MSG_RESULT($liberty_cv_uint64)
 201 if test "$liberty_cv_uint64" != none; then
 202   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 203                      [Define to an unsigned 64-bit type available in the compiler.])
 204 fi
 205
 206 # Given the above check, we always have uintptr_t or a fallback
 207 # definition.  So define HAVE_UINTPTR_T in case any imported code
 208 # relies on it.
 209 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 210
 211 AC_TYPE_PID_T
 212
 213 # This is the list of functions which libiberty will provide if they
 214 # are not available on the host.
 215
 216 funcs="asprintf"
 217 funcs="$funcs atexit"
 218 funcs="$funcs basename"
 219 funcs="$funcs bcmp"
 220 funcs="$funcs bcopy"
 221 funcs="$funcs bsearch"
 222 funcs="$funcs bzero"
 223 funcs="$funcs calloc"
 224 funcs="$funcs clock"
 225 funcs="$funcs ffs"
 226 funcs="$funcs getcwd"
 227 funcs="$funcs getpagesize"
 228 funcs="$funcs index"
 229 funcs="$funcs insque"
 230 funcs="$funcs memchr"
 231 funcs="$funcs memcmp"
 232 funcs="$funcs memcpy"
 233 funcs="$funcs memmove"
 234 funcs="$funcs mempcpy"
 235 funcs="$funcs memset"
 236 funcs="$funcs mkstemps"
 237 funcs="$funcs putenv"
 238 funcs="$funcs random"
 239 funcs="$funcs rename"
 240 funcs="$funcs rindex"
 241 funcs="$funcs setenv"
 242 funcs="$funcs snprintf"
 243 funcs="$funcs sigsetmask"
 244 funcs="$funcs stpcpy"
 245 funcs="$funcs stpncpy"
 246 funcs="$funcs strcasecmp"
 247 funcs="$funcs strchr"
 248 funcs="$funcs strdup"
 249 funcs="$funcs strncasecmp"
 250 funcs="$funcs strrchr"
 251 funcs="$funcs strstr"
 252 funcs="$funcs strtod"
 253 funcs="$funcs strtol"
 254 funcs="$funcs strtoul"
 255 funcs="$funcs tmpnam"
 256 funcs="$funcs vasprintf"
 257 funcs="$funcs vfprintf"
 258 funcs="$funcs vprintf"
 259 funcs="$funcs vsnprintf"
 260 funcs="$funcs vsprintf"
 261 funcs="$funcs waitpid"
 262
 263 # Also in the old function.def file: alloca, vfork, getopt.
 264
 265 vars="sys_errlist sys_nerr sys_siglist"
 266
 267 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 268 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 269 checkfuncs="$checkfuncs getsysinfo table sysctl"
 270
 271 # These are neither executed nor required, but they help keep
 272 # autoheader happy without adding a bunch of text to acconfig.h.
 273 if test "x" = "y"; then
 274   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 275   getcwd getpagesize index insque mkstemps memchr memcmp memcpy \
 276   memmove mempcpy memset putenv random rename rindex sigsetmask \
 277   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr \
 278   strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \
 279   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 280   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 281   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl \
 282   realpath canonicalize_file_name)
 283   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 284   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 285   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 286 fi
 287
 288 # For each of these functions, if the host does not provide the
 289 # function we want to put FN.o in LIBOBJS, and if the host does
 290 # provide the function, we want to define HAVE_FN in config.h.
 291
 292 setobjs=
 293 CHECK=
 294 target_header_dir=
 295 if test -n "${with_target_subdir}"; then
 296
 297   # We are being configured as a target library.  AC_REPLACE_FUNCS
 298   # may not work correctly, because the compiler may not be able to
 299   # link executables.  Note that we may still be being configured
 300   # native.
 301
 302   # If we are being configured for newlib, we know which functions
 303   # newlib provide and which ones we will be expected to provide.
 304
 305   if test "x${with_newlib}" = "xyes"; then
 306     AC_LIBOBJ([asprintf])
 307     AC_LIBOBJ([basename])
 308     AC_LIBOBJ([insque])
 309     AC_LIBOBJ([random])
 310     AC_LIBOBJ([strdup])
 311     AC_LIBOBJ([vasprintf])
 312
 313     for f in $funcs; do
 314       case "$f" in
 315         asprintf | basename | insque | random | strdup | vasprintf)
 316           ;;
 317         *)
 318           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 319           AC_DEFINE_UNQUOTED($n)
 320           ;;
 321       esac
 322     done
 323
 324     # newlib doesnt provide any of the variables in $vars, so we
 325     # dont have to check them here.
 326
 327     # Of the functions in $checkfuncs, newlib only has strerror.
 328     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 329
 330     setobjs=yes
 331
 332   fi
 333
 334   # We may wish to install the target headers somewhere.
 335   AC_ARG_ENABLE(install-libiberty,
 336   [  --enable-install-libiberty       Install headers for end users],
 337   enable_install_libiberty=$enableval,
 338   enable_install_libiberty=no)dnl
 339
 340   # Option parsed, now set things appropriately.
 341   case x"$enable_install_libiberty" in
 342     xyes|x)
 343       target_header_dir=libiberty
 344       ;;
 345     xno)
 346       target_header_dir=
 347       ;;
 348     *)
 349       # This could be sanity-checked in various ways...
 350       target_header_dir="${enable_install_libiberty}"
 351       ;;
 352   esac
 353
 354
 355 else
 356
 357    # Not a target library, so we set things up to run the test suite.
 358    CHECK=check-cplus-dem
 359
 360 fi
 361
 362 AC_SUBST(CHECK)
 363 AC_SUBST(target_header_dir)
 364
 365 case "${host}" in
 366   *-*-cygwin* | *-*-mingw*)
 367     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 368     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 369     ;;
 370 esac
 371
 372 if test -z "${setobjs}"; then
 373   case "${host}" in
 374
 375   *-*-vxworks*)
 376     # Handle VxWorks configuration specially, since on VxWorks the
 377     # libraries are actually on the target board, not in the file
 378     # system.
 379     AC_LIBOBJ([basename])
 380     AC_LIBOBJ([getpagesize])
 381     AC_LIBOBJ([insque])
 382     AC_LIBOBJ([random])
 383     AC_LIBOBJ([strcasecmp])
 384     AC_LIBOBJ([strncasecmp])
 385     AC_LIBOBJ([strdup])
 386     AC_LIBOBJ([vfork])
 387     AC_LIBOBJ([waitpid])
 388     AC_LIBOBJ([vasprintf])
 389     for f in $funcs; do
 390       case "$f" in
 391         basename | getpagesize | insque | random | strcasecmp)
 392           ;;
 393         strncasecmp | strdup | vfork | waitpid | vasprintf)
 394           ;;
 395         *)
 396           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 397           AC_DEFINE_UNQUOTED($n)
 398           ;;
 399       esac
 400     done
 401
 402     # VxWorks doesn't provide any of the variables in $vars, so we
 403     # don't have to check them here.
 404
 405     # Of the functions in $checkfuncs, VxWorks only has strerror.
 406     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 407
 408     setobjs=yes
 409     ;;
 410
 411   esac
 412 fi
 413
 414 if test -z "${setobjs}"; then
 415
 416   case "${host}" in
 417
 418   *-*-cygwin*)
 419     # The Cygwin library actually uses a couple of files from
 420     # libiberty when it is built.  If we are building a native
 421     # Cygwin, and we run the tests, we will appear to have these
 422     # files.  However, when we go on to build winsup, we will wind up
 423     # with a library which does not have the files, since they should
 424     # have come from libiberty.
 425
 426     # We handle this by removing the functions the winsup library
 427     # provides from our shell variables, so that they appear to be
 428     # missing.
 429
 430     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 431
 432     if test -n "${with_target_subdir}"
 433     then
 434       funcs="`echo $funcs | sed -e 's/random//'`"
 435       AC_LIBOBJ([random])
 436       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 437       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 438     fi
 439     ;;
 440
 441   *-*-mingw32*)
 442     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 443     # macros, so the test below won't find them.
 444     libiberty_cv_var_sys_nerr=yes
 445     libiberty_cv_var_sys_errlist=yes
 446     ;;
 447
 448   *-*-uwin*)
 449     # Under some versions of uwin, vfork is notoriously buggy and the test
 450     # can hang configure; on other versions, vfork exists just as a stub.
 451     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 452     ac_cv_func_vfork_works=no
 453     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 454     # macros (actually, these are imported from a DLL, but the end effect
 455     # is the same), so the test below won't find them.
 456     libiberty_cv_var_sys_nerr=yes
 457     libiberty_cv_var_sys_errlist=yes
 458     ;;
 459
 460   *-*-*vms*)
 461     # Under VMS, vfork works very different than on Unix. The standard test
 462     # won't work, and it isn't easily adaptable. It makes more sense to
 463     # just force it.
 464     ac_cv_func_vfork_works=yes
 465     ;;
 466
 467   esac
 468
 469   # We haven't set the list of objects yet.  Use the standard autoconf
 470   # tests.  This will only work if the compiler works.
 471   AC_ISC_POSIX
 472   AC_REPLACE_FUNCS($funcs)
 473   libiberty_AC_FUNC_C_ALLOCA
 474   AC_FUNC_FORK
 475   if test $ac_cv_func_vfork_works = no; then
 476     AC_LIBOBJ([vfork])
 477   fi
 478   # We only need _doprnt if we might use it to implement v*printf.
 479   if test $ac_cv_func_vprintf != yes \
 480      || test $ac_cv_func_vfprintf != yes \
 481      || test $ac_cv_func_vsprintf != yes; then
 482     AC_REPLACE_FUNCS(_doprnt)
 483   else
 484     AC_CHECK_FUNCS(_doprnt)
 485   fi
 486
 487   for v in $vars; do
 488     AC_MSG_CHECKING([for $v])
 489     AC_CACHE_VAL(libiberty_cv_var_$v,
 490       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 491                       [eval "libiberty_cv_var_$v=yes"],
 492                       [eval "libiberty_cv_var_$v=no"])])
 493     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 494       AC_MSG_RESULT(yes)
 495       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 496       AC_DEFINE_UNQUOTED($n)
 497     else
 498       AC_MSG_RESULT(no)
 499     fi
 500   done
 501
 502   # special check for _system_configuration because AIX <4.3.2 do not
 503   # contain the `physmem' member.
 504   AC_MSG_CHECKING([for external symbol _system_configuration])
 505   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 506                         [[double x = _system_configuration.physmem;]])],
 507     [AC_MSG_RESULT([yes])
 508     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 509               [Define if you have the _system_configuration variable.])],
 510     [AC_MSG_RESULT([no])])
 511
 512   AC_CHECK_FUNCS($checkfuncs)
 513   libiberty_NEED_DECLARATION(canonicalize_file_name)
 514 fi
 515
 516 # Figure out which version of pexecute to use.
 517 case "${host}" in
 518      *-*-mingw* | *-*-winnt*)   pexecute=./pex-win32.o  ;;
 519      *-*-msdosdjgpp*)           pexecute=./pex-djgpp.o  ;;
 520      *-*-msdos*)                pexecute=./pex-msdos.o  ;;
 521      *-*-os2-emx*)              pexecute=./pex-os2.o    ;;
 522      *)                         pexecute=./pex-unix.o   ;;
 523 esac
 524 AC_SUBST(pexecute)
 525
 526 libiberty_AC_FUNC_STRNCMP
 527
 528 # Install a library built with a cross compiler in $(tooldir) rather
 529 # than $(libdir).
 530 if test -z "${with_cross_host}"; then
 531   INSTALL_DEST=libdir
 532 else
 533   INSTALL_DEST=tooldir
 534 fi
 535 AC_SUBST(INSTALL_DEST)
 536
 537 m4_pattern_allow(LIBOBJS)
 538 L=""
 539 for l in x $LIBOBJS; do
 540   case $l in
 541     x) ;;
 542     *) L="$L ./$l" ;;
 543   esac
 544 done
 545 LIBOBJS="$L"
 546
 547 # We need multilib support, but only if configuring for the target.
 548 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 549 AC_CONFIG_COMMANDS([default],
 550   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 551 if test -n "$CONFIG_FILES"; then
 552   if test -n "${with_target_subdir}"; then
 553     # FIXME: We shouldn't need to set ac_file
 554     ac_file=Makefile
 555     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 556     . ${libiberty_topdir}/config-ml.in
 557   fi
 558 fi]],
 559 [[srcdir=${srcdir}
 560 host=${host}
 561 target=${target}
 562 with_target_subdir=${with_target_subdir}
 563 with_multisubdir=${with_multisubdir}
 564 ac_configure_args="--enable-multilib ${ac_configure_args}"
 565 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 566 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 567 libiberty_topdir=${libiberty_topdir}
 568 ]])
 569 AC_OUTPUT