gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3456]86)        cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       *)                cpu_type=${cpu} ;;
 157     esac
 158
 159     if test ${this_target} = $target ; then
 160       target_cpu_type=${cpu_type}
 161     elif test ${target_cpu_type} != ${cpu_type} ; then
 162       continue
 163     fi
 164
 165     generic_target=${cpu_type}-$vendor-$os
 166     dev=no
 167     bfd_gas=no
 168     em=generic
 169
 170     # assign object format
 171     case ${generic_target} in
 172       a29k-*-coff)                      fmt=coff ;;
 173       a29k-amd-udi)                     fmt=coff ;;
 174       a29k-amd-ebmon)                   fmt=coff ;;
 175       a29k-nyu-sym1)                    fmt=coff ;;
 176       a29k-*-rtems*)                    fmt=coff ;;
 177       a29k-*-vxworks*)                  fmt=coff ;;
 178
 179       alpha*-*-*vms*)                   fmt=evax ;;
 180       alpha*-*-netware*)                fmt=ecoff ;;
 181       alpha*-*-osf*)                    fmt=ecoff ;;
 182       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 183       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 184       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 185       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 186
 187       arc-*-elf*)                       fmt=elf ;;
 188
 189       arm-*-aout)                       fmt=aout ;;
 190       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 191       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 192       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 193       arm*-*-conix*)                    fmt=elf ;;
 194       arm-*-linux*aout*)                fmt=aout em=linux ;;
 195       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 196       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 197       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 198       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 199       arm-**-nto*)                      fmt=elf ;;
 200       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 201       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 202       arm-*-wince)                      fmt=coff em=wince-pe ;;
 203       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 204       arm-*-riscix*)                    fmt=aout em=riscix ;;
 205       arm-*-vxworks)                    fmt=coff ;;
 206
 207       avr-*-*)                          fmt=elf ;;
 208
 209       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 210
 211       d10v-*-*)                         fmt=elf ;;
 212       d30v-*-*)                         fmt=elf ;;
 213       dlx-*-*)                          fmt=elf ;;
 214
 215       fr30-*-*)                         fmt=elf ;;
 216       frv-*-*)                          fmt=elf ;;
 217
 218       hppa-*-linux*)    case ${cpu} in
 219                             hppa*64*)   fmt=elf em=hppalinux64;;
 220                             hppa*)      fmt=elf em=linux;;
 221                         esac ;;
 222       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 223       hppa-*-lites*)                    fmt=elf em=hppa ;;
 224       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 225       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 226       hppa-*-osf*)                      fmt=som em=hppa ;;
 227       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 228       hppa-*-hpux11*)   case ${cpu} in
 229                             hppa*64*)   fmt=elf em=hppa64 ;;
 230                             hppa*)      fmt=som em=hppa ;;
 231                         esac ;;
 232       hppa-*-hpux*)                     fmt=som em=hppa ;;
 233       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 234       hppa-*-bsd*)                      fmt=som em=hppa ;;
 235       hppa-*-hiux*)                     fmt=som em=hppa ;;
 236
 237       h8300-*-rtems*)                   fmt=coff ;;
 238       h8300-*-coff)                     fmt=coff ;;
 239       h8300-*-elf)                      fmt=elf ;;
 240       h8500-*-rtems*)                   fmt=coff ;;
 241       h8500-*-coff)                     fmt=coff ;;
 242
 243       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 244       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 245       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 246       i386-*-beospe*)                   fmt=coff em=pe ;;
 247       i386-*-beos*)                     fmt=elf ;;
 248       i386-*-coff)                      fmt=coff ;;
 249       i386-*-elf)                       fmt=elf ;;
 250       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 251       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 252       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 253       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 254       i386-*-*n*bsd*)   case ${cpu} in
 255                             x86_64)     fmt=elf em=nbsd ;;
 256                             *)          fmt=aout em=nbsd ;;
 257                         esac ;;
 258       i386-*-linux*aout*)               fmt=aout em=linux ;;
 259       i386-*-linux*oldld)               fmt=aout em=linux ;;
 260       i386-*-linux*coff*)               fmt=coff em=linux ;;
 261       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 262       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 263       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 264 changequote(,)dnl
 265       i386-*-sysv[45]*)                 fmt=elf ;;
 266       i386-*-solaris*)                  fmt=elf ;;
 267       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 268       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 269       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 270 changequote([,])dnl
 271       i386-*-sysv*)                     fmt=coff ;;
 272       i386-*-sco3.2v5*coff)             fmt=coff ;;
 273       i386-*-isc*)                      fmt=coff ;;
 274       i386-*-sco3.2v5*)                 fmt=elf
 275           if test ${this_target} = $target; then
 276             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 277           fi ;;
 278       i386-*-sco3.2*)                   fmt=coff ;;
 279       i386-*-vsta)                      fmt=aout ;;
 280       i386-*-msdosdjgpp* \
 281       | i386-*-go32* \
 282       | i386-go32-rtems*)               fmt=coff em=go32
 283             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 284       i386-*-rtemself*)                 fmt=elf ;;
 285       i386-*-rtemscoff*)                fmt=coff ;;
 286       i386-*-rtems*)                    fmt=elf ;;
 287       i386-*-gnu*)                      fmt=elf ;;
 288       i386-*-mach*)                     fmt=aout em=mach ;;
 289       i386-*-msdos*)                    fmt=aout ;;
 290       i386-*-moss*)                     fmt=elf ;;
 291       i386-*-pe)                        fmt=coff em=pe ;;
 292       i386-*-cygwin*)                   fmt=coff em=pe ;;
 293       i386-*-interix*)                  fmt=coff em=interix ;;
 294       i386-*-mingw32*)                  fmt=coff em=pe ;;
 295       i386-*-nto-qnx*)                  fmt=elf ;;
 296       i386-*-*nt*)                      fmt=coff em=pe ;;
 297       i386-*-vxworks*)                  fmt=aout ;;
 298       i386-*-chaos)                     fmt=elf ;;
 299
 300       i860-*-*)                         fmt=elf endian=little
 301                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 302       i960-*-bout)                      fmt=bout ;;
 303       i960-*-coff)                      fmt=coff em=ic960 ;;
 304       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 305       i960-*-nindy*)                    fmt=bout ;;
 306       i960-*-vxworks5.0)                fmt=bout ;;
 307       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 308       i960-*-vxworks*)                  fmt=bout ;;
 309       i960-*-elf*)                      fmt=elf ;;
 310
 311       ia64-*-elf*)                      fmt=elf ;;
 312       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 313       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 314       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 315       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 316
 317       ip2k-*-*)                         fmt=elf ;;
 318
 319       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 320
 321       m32r-*-*)                         fmt=elf ;;
 322
 323       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 324       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 325
 326       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 327       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 328       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 329       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 330       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 331       m68k-apollo-*)                    fmt=coff em=apollo ;;
 332       m68k-*-elf*)                      fmt=elf ;;
 333       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 334       m68k-*-sysv*)                     fmt=coff ;;
 335       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 336       m68k-*-rtems*)                    fmt=elf ;;
 337       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 338       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 339       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 340       m68k-*-gnu*)                      fmt=elf ;;
 341       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 342       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 343       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 344       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 345       m68k-apple-aux*)                  fmt=coff em=aux ;;
 346       m68k-*-psos*)                     fmt=elf em=psos;;
 347
 348       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 349       m88k-*-coff*)                     fmt=coff ;;
 350
 351       mcore-*-elf)                      fmt=elf ;;
 352       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 353
 354       # don't change em like *-*-bsd does
 355       mips-dec-openbsd*)                fmt=elf endian=little ;;
 356       mips-dec-bsd*)                    fmt=aout endian=little ;;
 357       mips-sony-bsd*)                   fmt=ecoff ;;
 358       mips-*-bsd*)
 359             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 360       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 361       mips-*-osf*)                      fmt=ecoff endian=little ;;
 362       mips-*-ecoff*)                    fmt=ecoff ;;
 363       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 364       mips-*-irix6*)                    fmt=elf ;;
 365       mips-*-irix5*)                    fmt=elf ;;
 366       mips-*-irix*)                     fmt=ecoff ;;
 367       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 368       mips-*-riscos*)                   fmt=ecoff ;;
 369       mips*-*-linux*)                   fmt=elf em=tmips ;;
 370       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 371       mips-*-sysv*)                     fmt=ecoff ;;
 372       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 373       mips-*-*n*bsd*)                   fmt=elf ;;
 374       mips-*-vxworks*)                  fmt=elf ;;
 375
 376       mmix-*-*)                         fmt=elf ;;
 377       mn10200-*-*)                      fmt=elf ;;
 378       mn10300-*-*)                      fmt=elf ;;
 379       msp430-*-*)                       fmt=elf ;;
 380       openrisc-*-*)                     fmt=elf ;;
 381       or32-*-rtems*)                    fmt=coff ;;
 382       or32-*-coff)                      fmt=coff ;;
 383       or32-*-elf)                       fmt=elf ;;
 384       pj*)                              fmt=elf ;;
 385
 386       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 387       ppc-*-winnt*)                     fmt=coff em=pe ;;
 388       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 389       ppc-*-aix*)                       fmt=coff ;;
 390       ppc-*-beos*)                      fmt=coff ;;
 391       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 392       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 393       ppc-*-linux-gnu*)                 fmt=elf
 394             case "$endian" in
 395                 big)  ;;
 396                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 397             esac ;;
 398       ppc-*-solaris*)                   fmt=elf
 399             if test ${this_target} = $target; then
 400                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 401                           [Define if default target is PowerPC Solaris.])
 402             fi
 403             if test x${endian} = xbig; then
 404                 AC_MSG_ERROR(Solaris must be configured little endian)
 405             fi ;;
 406       ppc-*-rtems*)                     fmt=elf ;;
 407       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 408       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 409       ppc-**-nto*)                      fmt=elf ;;
 410       ppc-*-vxworks*)                   fmt=elf ;;
 411       ppc-*-windiss*)                   fmt=elf ;;
 412
 413       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 414       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 415
 416       sh*-*-linux*)                     fmt=elf em=linux
 417             case ${cpu} in
 418                 sh*eb)  endian=big ;;
 419                 *)      endian=little ;;
 420             esac ;;
 421       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 422       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 423       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 424       sh-*-elf*)                        fmt=elf ;;
 425       sh-*-coff*)                       fmt=coff ;;
 426       sh-*-nto*)                        fmt=elf ;;
 427       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 428       sh-*-rtemself*)                   fmt=elf ;;
 429       sh-*-rtems*)                      fmt=coff ;;
 430       sh64-*-elf*)                      fmt=elf ;;
 431
 432       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 433       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 434       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 435       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 436
 437       sparc-*-rtemsaout*)               fmt=aout ;;
 438       sparc-*-rtemself*)                fmt=elf ;;
 439       sparc-*-rtems*)                   fmt=elf ;;
 440       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 441       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 442       sparc-*-coff)                     fmt=coff ;;
 443       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 444       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 445       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 446       sparc-fujitsu-none)               fmt=aout ;;
 447       sparc-*-elf)                      fmt=elf ;;
 448       sparc-*-sysv4*)                   fmt=elf ;;
 449       sparc-*-solaris*)                 fmt=elf ;;
 450       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 451       sparc-*-*n*bsd*)  case ${cpu} in
 452                             sparc64)    fmt=elf em=nbsd ;;
 453                             *)          fmt=aout em=nbsd ;;
 454                         esac ;;
 455       strongarm-*-coff)                 fmt=coff ;;
 456       strongarm-*-elf)                  fmt=elf ;;
 457       xscale-*-coff)                    fmt=coff ;;
 458       xscale-*-elf)                     fmt=elf ;;
 459
 460       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 461       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 462       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 463       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 464       tic80-*-*)                        fmt=coff ;;
 465
 466       v850-*-*)                         fmt=elf ;;
 467       v850e-*-*)                        fmt=elf ;;
 468       v850ea-*-*)                       fmt=elf ;;
 469
 470       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 471       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 472       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 473       vax-*-vms)                        fmt=vms ;;
 474
 475       w65-*-*)                          fmt=coff ;;
 476
 477       xstormy16-*-*)                    fmt=elf ;;
 478
 479       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 480
 481       *-*-aout | *-*-scout)             fmt=aout ;;
 482       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 483       *-*-nindy*)                       fmt=bout ;;
 484       *-*-bsd*)                         fmt=aout em=sun3 ;;
 485       *-*-generic)                      fmt=generic ;;
 486       *-*-xray | *-*-hms)               fmt=coff ;;
 487       *-*-sim)                          fmt=coff ;;
 488       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 489       *-*-vxworks)                      fmt=aout ;;
 490       *-*-netware)                      fmt=elf ;;
 491     esac
 492
 493     if test ${this_target} = $target ; then
 494       endian_def=
 495       if test x${endian} = xbig; then
 496         endian_def=1
 497       elif test x${endian} = xlittle; then
 498         endian_def=0
 499       fi
 500       if test x${endian_def} != x; then
 501         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 502                            [Define as 1 if big endian.])
 503       fi
 504     fi
 505
 506     case ${cpu_type}-${fmt} in
 507         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 508                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 509                 | *-elf | *-ecoff | *-som)
 510             bfd_gas=yes ;;
 511     esac
 512
 513 # Other random stuff.
 514
 515     case ${cpu_type} in
 516       mips)
 517         # Set mips_cpu to the name of the default CPU.
 518         case ${target_cpu} in
 519           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 520             mips_cpu=from-abi
 521             ;;
 522           mipsisa32 | mipsisa32el)
 523             mips_cpu=mips32
 524             ;;
 525           mipsisa32r2 | mipsisa32r2el)
 526             mips_cpu=mips32r2
 527             ;;
 528           mipsisa64 | mipsisa64el)
 529             mips_cpu=mips64
 530             ;;
 531           mipstx39 | mipstx39el)
 532             mips_cpu=r3900
 533             ;;
 534           mips64vr | mips64vrel)
 535             mips_cpu=vr4100
 536             ;;
 537           mipsisa32r2*)
 538 changequote(,)dnl
 539             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 540 changequote([,])dnl
 541             ;;
 542           mips64* | mipsisa64* | mipsisa32*)
 543 changequote(,)dnl
 544             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 545 changequote([,])dnl
 546             ;;
 547           *)
 548             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 549             ;;
 550         esac
 551         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 552         # binaries.  It's a GNU extension that some OSes don't understand.
 553         # The value only matters on ELF targets.
 554         case ${target} in
 555           *-*-irix*)
 556             use_e_mips_abi_o32=0
 557             ;;
 558           *)
 559             use_e_mips_abi_o32=1
 560             ;;
 561         esac
 562         # Decide whether to generate 32-bit or 64-bit code by default.
 563         # Used to resolve -march=from-abi when an embedded ABI is selected.
 564         case ${target} in
 565           mips64*-*-* | mipsisa64*-*-*)
 566             mips_default_64bit=1
 567             ;;
 568           *)
 569             mips_default_64bit=0
 570             ;;
 571         esac
 572         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 573                            [Default CPU for MIPS targets. ])
 574         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 575                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 576         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 577                            [Generate 64-bit code by default on MIPS targets. ])
 578         ;;
 579     esac
 580
 581     # Do we need the opcodes library?
 582     case ${cpu_type} in
 583       vax | i386 | tic30)
 584         ;;
 585
 586       *)
 587         need_opcodes=yes
 588
 589         case "${enable_shared}" in
 590         yes) shared_opcodes=true ;;
 591         *opcodes*) shared_opcodes=true ;;
 592         *) shared_opcodes=false ;;
 593         esac
 594         if test "${shared_opcodes}" = "true"; then
 595           # A shared libopcodes must be linked against libbfd.
 596           need_bfd=yes
 597         fi
 598         ;;
 599     esac
 600
 601     # Any other special object files needed ?
 602     case ${cpu_type} in
 603       fr30 | ip2k | iq2000 | m32r | openrisc)
 604         using_cgen=yes
 605         ;;
 606
 607       frv)
 608         using_cgen=yes
 609         ;;
 610       m68k)
 611         case ${extra_objects} in
 612         *m68k-parse.o*) ;;
 613         *) extra_objects="$extra_objects m68k-parse.o" ;;
 614         esac
 615         ;;
 616
 617       mips)
 618         echo ${extra_objects} | grep -s "itbl-parse.o"
 619         if test $? -ne 0 ; then
 620           extra_objects="$extra_objects itbl-parse.o"
 621         fi
 622
 623         echo ${extra_objects} | grep -s "itbl-lex.o"
 624         if test $? -ne 0 ; then
 625           extra_objects="$extra_objects itbl-lex.o"
 626         fi
 627
 628         echo ${extra_objects} | grep -s "itbl-ops.o"
 629         if test $? -ne 0 ; then
 630           extra_objects="$extra_objects itbl-ops.o"
 631         fi
 632         ;;
 633
 634       i386 | s390 | sparc)
 635         if test $this_target = $target ; then
 636           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 637         fi
 638         ;;
 639
 640       xstormy16)
 641         using_cgen=yes
 642         ;;
 643
 644       *)
 645         ;;
 646     esac
 647
 648     if test $using_cgen = yes ; then
 649         case "x${extra_objects}" in
 650         *cgen.o*) ;;
 651         *) extra_objects="$extra_objects cgen.o" ;;
 652         esac
 653     fi
 654
 655 # See if we really can support this configuration with the emulation code.
 656
 657     if test $this_target = $target ; then
 658       primary_bfd_gas=$bfd_gas
 659       obj_format=$fmt
 660       te_file=$em
 661
 662       if test $bfd_gas = no ; then
 663         # Can't support other configurations this way.
 664         break
 665       fi
 666     elif test $bfd_gas = no ; then
 667       # Can't support this configuration.
 668       break
 669     fi
 670
 671 # From target name and format, produce a list of supported emulations.
 672
 673     case ${generic_target}-${fmt} in
 674       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 675       mips*-*-linux*-*) case "$endian" in
 676                         big)    emulation="mipsbelf mipslelf mipself" ;;
 677                         *)      emulation="mipslelf mipsbelf mipself" ;;
 678                         esac ;;
 679       mips-*-lnews*-ecoff) ;;
 680       mips-*-*-ecoff)   case "$endian" in
 681                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 682                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 683                         esac ;;
 684       mips-*-*-elf)     case "$endian" in
 685                         big)    emulation="mipsbelf mipslelf mipself" ;;
 686                         *)      emulation="mipslelf mipsbelf mipself" ;;
 687                         esac ;;
 688       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 689       # i386-pc-pe-coff != i386-pc-coff.
 690       i386-*-pe-coff)   ;;
 691       # Uncommenting the next line will turn on support for i386 AOUT
 692       # for the default linux configuration
 693       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 694       #
 695       i386-*-aout)      emulation="i386aout" ;;
 696       i386-*-coff)      emulation="i386coff" ;;
 697       i386-*-elf)       emulation="i386elf" ;;
 698
 699       # Always all formats.  The first stated emulation becomes the default.
 700       cris-*-*aout*)    emulation="crisaout criself" ;;
 701       cris-*-*)         emulation="criself crisaout" ;;
 702     esac
 703
 704     emulations="$emulations $emulation"
 705
 706 done
 707
 708 # Turn on all targets if possible
 709 if test ${all_targets} = "yes"; then
 710   case ${target_cpu_type} in
 711   i386)
 712     case ${obj_format} in
 713     aout)
 714       emulations="$emulations i386coff i386elf"
 715       ;;
 716     coff)
 717       emulations="$emulations i386aout i386elf"
 718     ;;
 719     elf)
 720       emulations="$emulations i386aout i386coff"
 721       ;;
 722     esac
 723   ;;
 724   esac
 725 fi
 726
 727 # Assign floating point type.  Most processors with FP support
 728 # IEEE FP.  On those that don't support FP at all, usually IEEE
 729 # is emulated.
 730 case ${target_cpu} in
 731   vax | tahoe ) atof=${target_cpu} ;;
 732   pdp11)        atof=vax ;;
 733   *)            atof=ieee ;;
 734 esac
 735
 736 case "${obj_format}" in
 737   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 738 esac
 739
 740 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 741 cgen_cpu_prefix=""
 742 if test $using_cgen = yes ; then
 743   case ${target_cpu} in
 744     *) cgen_cpu_prefix=${target_cpu} ;;
 745   esac
 746   AC_SUBST(cgen_cpu_prefix)
 747   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 748 fi
 749
 750 dnl
 751 dnl Make sure the desired support files exist.
 752 dnl
 753
 754 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 755   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 756 fi
 757
 758 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 759   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 760 fi
 761
 762 case ${user_bfd_gas}-${primary_bfd_gas} in
 763   yes-yes | no-no)
 764     # We didn't override user's choice.
 765     ;;
 766   no-yes)
 767     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 768     ;;
 769   no-preferred)
 770     primary_bfd_gas=no
 771     ;;
 772   *-preferred)
 773     primary_bfd_gas=yes
 774     ;;
 775   yes-*)
 776     primary_bfd_gas=yes
 777     ;;
 778   -*)
 779     # User specified nothing.
 780     ;;
 781 esac
 782
 783 # Some COFF configurations want these random other flags set.
 784 case ${obj_format} in
 785   coff)
 786     case ${target_cpu_type} in
 787       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 788       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 789       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 790     esac
 791     ;;
 792 esac
 793
 794 # Getting this done right is going to be a bitch.  Each configuration specified
 795 # with --enable-targets=... should be checked for environment, format, cpu, and
 796 # bfd_gas setting.
 797 #
 798 # For each configuration, the necessary object file support code must be linked
 799 # in.  This might be only one, it might be up to four.  The necessary emulation
 800 # code needs to be provided, too.
 801 #
 802 # And then there's "--enable-targets=all"....
 803 #
 804 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 805
 806 formats="${obj_format}"
 807 emfiles=""
 808 EMULATIONS=""
 809 GAS_UNIQ(emulations)
 810 for em in . $emulations ; do
 811   case $em in
 812     .)  continue ;;
 813     mipsbelf | mipslelf | mipself)
 814         fmt=elf   file=mipself ;;
 815     mipsbecoff | mipslecoff | mipsecoff)
 816         fmt=ecoff file=mipsecoff ;;
 817     *coff)
 818         fmt=coff  file=$em ;;
 819     *aout)
 820         fmt=aout file=$em ;;
 821     *elf)
 822         fmt=elf file=$em ;;
 823   esac
 824   formats="$formats $fmt"
 825   emfiles="$emfiles e-$file.o"
 826   EMULATIONS="$EMULATIONS &$em,"
 827 done
 828 GAS_UNIQ(formats)
 829 GAS_UNIQ(emfiles)
 830 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 831   for fmt in $formats ; do
 832     case $fmt in
 833       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 834       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 835       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 836       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 837       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 838       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 839       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 840       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 841       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 842       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 843     esac
 844     extra_objects="$extra_objects obj-$fmt.o"
 845   done
 846   obj_format=multi
 847 fi
 848 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 849   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 850   # e-mips* has more than one emulation per file, e-i386* has just one at the
 851   # moment.  If only one emulation is specified, then don't define
 852   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 853   case "${obj_format}${emfiles}" in
 854     multi* | *mips*)
 855       extra_objects="$extra_objects $emfiles"
 856       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 857   esac
 858 fi
 859 AC_SUBST(extra_objects)
 860 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 861 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 862                    [Default emulation.])
 863
 864 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 865   yes-*-coff)   need_bfd=yes ;;
 866   no-*-coff)    need_bfd=yes
 867                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 868 esac
 869
 870 reject_dev_configs=yes
 871
 872 case ${reject_dev_configs}-${dev} in
 873   yes-yes) # Oops.
 874     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 875     ;;
 876 esac
 877
 878 AC_SUBST(target_cpu_type)
 879 AC_SUBST(obj_format)
 880 AC_SUBST(te_file)
 881 AC_SUBST(install_tooldir)
 882 AC_SUBST(atof)
 883 dnl AC_SUBST(emulation)
 884
 885 case "${primary_bfd_gas}" in
 886   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 887         need_bfd=yes ;;
 888 esac
 889
 890 # do we need the opcodes library?
 891 case "${need_opcodes}" in
 892 yes)
 893   OPCODES_LIB=../opcodes/libopcodes.la
 894   ;;
 895 esac
 896
 897 case "${need_bfd}" in
 898 yes)
 899   BFDLIB=../bfd/libbfd.la
 900   BFDVER_H=../bfd/bfdver.h
 901   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 902   ;;
 903 esac
 904
 905 AC_SUBST(BFDLIB)
 906 AC_SUBST(OPCODES_LIB)
 907
 908 AC_SUBST(BFDVER_H)
 909 AC_SUBST(ALL_OBJ_DEPS)
 910
 911 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 912 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 913 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 914 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 915 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 916
 917 AC_PROG_CC
 918
 919 AC_PROG_YACC
 920 AM_PROG_LEX
 921
 922 ALL_LINGUAS="fr tr es"
 923 CY_GNU_GETTEXT
 924
 925 AM_MAINTAINER_MODE
 926 AC_EXEEXT
 927
 928 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 929
 930 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 931 # people who are not cross-compiling but are compiling cross-assemblers.
 932 AC_MSG_CHECKING(whether compiling a cross-assembler)
 933 if test "${host}" = "${target}"; then
 934   cross_gas=no
 935 else
 936   cross_gas=yes
 937   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 938 fi
 939 AC_MSG_RESULT($cross_gas)
 940
 941 dnl ansidecl.h will deal with const
 942 dnl AC_CONST
 943 AC_FUNC_ALLOCA
 944 AC_C_INLINE
 945
 946 # VMS doesn't have unlink.
 947 AC_CHECK_FUNCS(unlink remove, break)
 948
 949 # Some systems don't have sbrk().
 950 AC_CHECK_FUNCS(sbrk)
 951
 952 # do we need the math library?
 953 case "${need_libm}" in
 954 yes)
 955   AC_CHECK_LIBM
 956   AC_SUBST(LIBM)
 957   ;;
 958 esac
 959
 960 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 961 # enough, but on some of those systems, the assert macro relies on requoting
 962 # working properly!
 963 GAS_WORKING_ASSERT
 964
 965 # On some systems, the system header files may not declare malloc, realloc,
 966 # and free.  There are places where gas needs these functions to have been
 967 # declared -- such as when taking their addresses.
 968 gas_test_headers="
 969 #ifdef HAVE_MEMORY_H
 970 #include <memory.h>
 971 #endif
 972 #ifdef HAVE_STRING_H
 973 #include <string.h>
 974 #else
 975 #ifdef HAVE_STRINGS_H
 976 #include <strings.h>
 977 #endif
 978 #endif
 979 #ifdef HAVE_STDLIB_H
 980 #include <stdlib.h>
 981 #endif
 982 #ifdef HAVE_UNISTD_H
 983 #include <unistd.h>
 984 #endif
 985 "
 986 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 987 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 988 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 989 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 990 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 991
 992 # Does errno.h declare errno, or do we have to add a separate declaration
 993 # for it?
 994 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 995 #ifdef HAVE_ERRNO_H
 996 #include <errno.h>
 997 #endif
 998 ])
 999
1000 dnl This must come last.
1001
1002 dnl We used to make symlinks to files in the source directory, but now
1003 dnl we just use the right name for .c files, and create .h files in
1004 dnl the build directory which include the right .h file.  Make sure
1005 dnl the old symlinks don't exist, so that a reconfigure in an existing
1006 dnl directory behaves reasonably.
1007
1008 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1009 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1010  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1011  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1012  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1013  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1014  if test "x$cgen_cpu_prefix" != x ; then
1015    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1016  fi
1017
1018  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1019 [target_cpu_type=${target_cpu_type}
1020  cgen_cpu_prefix=${cgen_cpu_prefix}
1021  obj_format=${obj_format}
1022  te_file=${te_file}])