gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       pjl*)             cpu_type=pj endian=little ;;
 141       pj*)              cpu_type=pj endian=big ;;
 142       powerpcle*)       cpu_type=ppc endian=little ;;
 143       powerpc*)         cpu_type=ppc endian=big ;;
 144       rs6000*)          cpu_type=ppc ;;
 145       s390x*)           cpu_type=s390 arch=s390x ;;
 146       s390*)            cpu_type=s390 arch=s390 ;;
 147       sparclite*)       cpu_type=sparc arch=sparclite ;;
 148       sparclet*)        cpu_type=sparc arch=sparclet ;;
 149       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 150       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 151       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 152       v850*)            cpu_type=v850 ;;
 153       *)                cpu_type=${cpu} ;;
 154     esac
 155
 156     if test ${this_target} = $target ; then
 157       target_cpu_type=${cpu_type}
 158     elif test ${target_cpu_type} != ${cpu_type} ; then
 159       continue
 160     fi
 161
 162     generic_target=${cpu_type}-$vendor-$os
 163     dev=no
 164     bfd_gas=no
 165     em=generic
 166
 167     # assign object format
 168     case ${generic_target} in
 169       a29k-*-coff)          fmt=coff ;;
 170       a29k-amd-udi)         fmt=coff ;;
 171       a29k-amd-ebmon)       fmt=coff ;;
 172       a29k-nyu-sym1)        fmt=coff ;;
 173       a29k-*-rtems*)        fmt=coff ;;
 174       a29k-*-vxworks*)      fmt=coff ;;
 175
 176       alpha*-*-*vms*)       fmt=evax ;;
 177       alpha*-*-netware*)    fmt=ecoff ;;
 178       alpha*-*-openbsd*)    fmt=ecoff ;;
 179       alpha*-*-osf*)        fmt=ecoff ;;
 180       alpha*-*-linuxecoff*) fmt=ecoff ;;
 181       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 182       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 183
 184       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 185
 186       arm-*-aout)                       fmt=aout ;;
 187       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 188       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 189       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 190       arm*-*-conix*)                    fmt=elf ;;
 191       arm-*-linux*aout*)                fmt=aout em=linux ;;
 192       arm*-*-linux-gnu* | arm*-*-uclinux*)
 193                                         fmt=elf  em=linux ;;
 194       arm-*-netbsd*)                    fmt=aout em=nbsd ;;
 195       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 196       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 197       arm-*-wince)                      fmt=coff em=wince-pe ;;
 198       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 199       arm-*-riscix*)                    fmt=aout em=riscix ;;
 200       arm-*-vxworks)                    fmt=coff ;;
 201
 202       avr-*-*)              fmt=elf bfd_gas=yes ;;
 203
 204       cris-*-*)             fmt=multi bfd_gas=yes ;;
 205
 206       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 207       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 208
 209
 210       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 211
 212       hppa-*-linux-gnu*)    case ${cpu} in
 213                                 hppa*64*)
 214                                         fmt=elf em=hppalinux64;;
 215                                 hppa*)
 216                                         fmt=elf em=linux;;
 217                             esac ;;
 218       hppa-*-*elf*)         fmt=elf em=hppa ;;
 219       hppa-*-lites*)        fmt=elf em=hppa ;;
 220       hppa-*-osf*)          fmt=som em=hppa ;;
 221       hppa-*-rtems*)        fmt=elf em=hppa ;;
 222       hppa-*-hpux11*)       case ${cpu} in
 223                                 hppa*64*)
 224                                         fmt=elf em=hppa64 ;;
 225                                 hppa*)
 226                                         fmt=som em=hppa ;;
 227                             esac ;;
 228       hppa-*-hpux*)         fmt=som em=hppa ;;
 229       hppa-*-mpeix*)        fmt=som em=hppa ;;
 230       hppa-*-bsd*)          fmt=som em=hppa ;;
 231       hppa-*-hiux*)         fmt=som em=hppa ;;
 232
 233       h8300-*-rtems*)       fmt=coff ;;
 234       h8300-*-coff)         fmt=coff ;;
 235       h8500-*-rtems*)       fmt=coff ;;
 236       h8500-*-coff)         fmt=coff ;;
 237
 238       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 239       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 240       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 241       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 242       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 243       i386-*-bsd*)          fmt=aout em=386bsd ;;
 244       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 245       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 246       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 247       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 248       i386-*-linux*coff*)   fmt=coff em=linux ;;
 249       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 250       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 251       i386-*-lynxos*)       fmt=coff em=lynx ;;
 252 changequote(,)dnl
 253       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 254                             fmt=elf bfd_gas=yes ;;
 255       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 256                             fmt=aout em=386bsd ;;
 257 changequote([,])dnl
 258       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 259                           fmt=coff ;;
 260       i386-*-sco3.2v5*)      fmt=elf
 261                             if test ${this_target} = $target; then
 262                                 AC_DEFINE(SCO_ELF, 1,
 263                                     [Define if defaulting to ELF on SCO 5.])
 264                             fi
 265                             ;;
 266       i386-*-sco3.2*)       fmt=coff ;;
 267       i386-*-vsta)          fmt=aout ;;
 268       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 269                             fmt=coff em=go32 bfd_gas=yes
 270                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 271                             ;;
 272       i386-*-rtemself*)     fmt=elf ;;
 273       i386-*-rtems*)        fmt=coff ;;
 274       i386-*-gnu*)          fmt=elf ;;
 275       i386-*-mach*)
 276                             fmt=aout em=mach bfd_gas=yes ;;
 277       i386-*-msdos*)        fmt=aout ;;
 278       i386-*-moss*)         fmt=elf ;;
 279       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 280       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 281       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 282       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 283       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 284       i386-*-vxworks*)      fmt=aout ;;
 285       i386-*-chaos)         fmt=elf ;;
 286       i860-stardent-sysv4* | i860-stardent-elf*)
 287                             fmt=elf bfd_gas=yes endian=little
 288                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 289       i960-*-bout)          fmt=bout ;;
 290       i960-*-coff)          fmt=coff em=ic960 ;;
 291       i960-*-rtems*)        fmt=coff em=ic960 ;;
 292       i960-*-nindy*)        fmt=bout ;;
 293       i960-*-vxworks4*)     fmt=bout ;;
 294       i960-*-vxworks5.0)    fmt=bout ;;
 295       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 296       i960-*-vxworks*)      fmt=bout ;;
 297       i960-*-elf*)          fmt=elf ;;
 298
 299       ia64-*-elf*)          fmt=elf ;;
 300       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 301       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 302       ia64-*-hpux*)         fmt=elf em=hpux ;;
 303
 304       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 305
 306       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 307
 308       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 309                             fmt=aout em=sun3 ;;
 310       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 311       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 312       m68k-apollo-*)        fmt=coff em=apollo ;;
 313       m68k-*-sysv4*) # must be before -sysv*
 314                             fmt=elf em=svr4 ;;
 315       m68k-*-elf*)          fmt=elf ;;
 316       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 317                             fmt=coff ;;
 318       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 319       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 320       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 321       m68k-*-gnu*)          fmt=elf ;;
 322       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 323       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 324       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 325       m68k-apple-aux*)      fmt=coff em=aux ;;
 326       m68k-*-psos*)         fmt=elf em=psos;;
 327
 328       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 329       m88k-*-coff*)         fmt=coff ;;
 330
 331       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 332       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 333
 334       # don't change em like *-*-bsd does
 335       mips-dec-netbsd*)     fmt=elf endian=little ;;
 336       mips-dec-openbsd*)    fmt=elf endian=little ;;
 337       mips-dec-bsd*)        fmt=aout endian=little ;;
 338       mips-sony-bsd*)       fmt=ecoff ;;
 339       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 340       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 341       mips-*-osf*)          fmt=ecoff endian=little ;;
 342       mips-*-ecoff*)        fmt=ecoff ;;
 343       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 344       mips-*-irix6*)        fmt=elf ;;
 345       mips-*-irix5*)        fmt=elf ;;
 346       mips-*-irix*)         fmt=ecoff ;;
 347       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 348       mips-*-riscos*)       fmt=ecoff ;;
 349       mips-*-sysv4*MP* | mips-*-linux-gnu* | mips-*-gnu*)
 350                             fmt=elf em=tmips ;;
 351       mips-*-sysv*)         fmt=ecoff ;;
 352       mips-*-elf* | mips-*-rtems* | mips-*-openbsd*)
 353                             fmt=elf ;;
 354       mips-*-vxworks*)      fmt=elf
 355                             AC_DEFINE(MIPS_STABS_ELF, 1,
 356                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 357                             ;;
 358       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 359       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 360       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 361       pj*)                  fmt=elf ;;
 362       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 363                             fmt=coff em=pe ;;
 364       ppc-*-aix*)           fmt=coff ;;
 365       ppc-*-beos*)          fmt=coff ;;
 366       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 367                             fmt=elf ;;
 368       ppc-*-linux-gnu*)     fmt=elf
 369                             case "$endian" in
 370                             big)  ;;
 371                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 372                             esac
 373                             ;;
 374       ppc-*-solaris*)       fmt=elf
 375                             if test ${this_target} = $target; then
 376                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 377                                 [Define if default target is PowerPC Solaris.])
 378                             fi
 379                             if test x${endian} = xbig; then
 380                                 AC_MSG_ERROR(Solaris must be configured little endian)
 381                             fi
 382                             ;;
 383       ppc-*-rtems*)         fmt=elf ;;
 384       ppc-*-macos* | ppc-*-mpw*)
 385                             fmt=coff em=macos ;;
 386       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 387       ppc-*-vxworks*)       fmt=elf ;;
 388
 389       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 390       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 391
 392       sh-*-linux*)          fmt=elf em=linux ;;
 393       sh-*-elf*)            fmt=elf ;;
 394       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 395       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes;;
 396       sh-*-rtemself*)       fmt=elf ;;
 397       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 398
 399       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 400       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 401       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 402
 403       sparc-*-rtemsaout*)   fmt=aout ;;
 404       sparc-*-rtemself*)    fmt=elf ;;
 405       sparc-*-rtems*)       fmt=elf ;;
 406       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 407       sparc-*-aout | sparc*-*-vxworks*)
 408                             fmt=aout em=sparcaout ;;
 409       sparc-*-coff)         fmt=coff ;;
 410       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 411       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 412       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 413       sparc-fujitsu-none)   fmt=aout ;;
 414       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 415                             fmt=elf ;;
 416       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 417                             case ${cpu} in
 418                                 sparc) case ${os} in
 419                                            *elf*) fmt=elf ;;
 420                                            *)     fmt=aout ;;
 421                                        esac ;;
 422                                 sparc64) fmt=elf ;;
 423                             esac
 424                             ;;
 425       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 426
 427       strongarm-*-coff)     fmt=coff ;;
 428       strongarm-*-elf)      fmt=elf ;;
 429       xscale-*-coff)     fmt=coff ;;
 430       xscale-*-elf)      fmt=elf ;;
 431
 432       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 433       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 434       tic54x-*-* | c54x*-*-*)
 435                             fmt=coff bfd_gas=yes need_libm=yes;;
 436       tic80-*-*)            fmt=coff ;;
 437
 438       v850-*-*)             fmt=elf bfd_gas=yes ;;
 439       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 440       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 441
 442       vax-*-bsd* | vax-*-ultrix*)
 443                             fmt=aout ;;
 444       vax-*-vms)            fmt=vms ;;
 445
 446
 447       z8k-*-coff | z8k-*-sim)
 448                             fmt=coff ;;
 449
 450       w65-*-*)              fmt=coff ;;
 451
 452       *-*-aout | *-*-scout)
 453                             fmt=aout ;;
 454       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 455       *-*-nindy*)
 456                             fmt=bout ;;
 457       *-*-bsd*)
 458                             fmt=aout em=sun3 ;;
 459       *-*-generic)          fmt=generic ;;
 460       *-*-xray | *-*-hms)   fmt=coff ;;
 461       *-*-sim)              fmt=coff ;;
 462       *-*-elf | *-*-sysv4* | *-*-solaris*)
 463                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 464                             fmt=elf dev=yes ;;
 465       *-*-vxworks)          fmt=aout ;;
 466       *-*-netware)          fmt=elf ;;
 467     esac
 468
 469     if test ${this_target} = $target ; then
 470       endian_def=
 471       if test x${endian} = xbig; then
 472         endian_def=1
 473       elif test x${endian} = xlittle; then
 474         endian_def=0
 475       fi
 476       if test x${endian_def} != x; then
 477         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 478                            [Define as 1 if big endian.])
 479       fi
 480     fi
 481
 482     case ${cpu_type}-${fmt} in
 483       alpha*-*) bfd_gas=yes ;;
 484       arm-*)    bfd_gas=yes ;;
 485     # not yet
 486     # i386-aout)        bfd_gas=preferred ;;
 487       ia64*-*)  bfd_gas=yes ;;
 488       mips-*)   bfd_gas=yes ;;
 489       ns32k-*)  bfd_gas=yes ;;
 490       pdp11-*)  bfd_gas=yes ;;
 491       ppc-*)    bfd_gas=yes ;;
 492       sparc-*)  bfd_gas=yes ;;
 493       strongarm-*)      bfd_gas=yes ;;
 494       xscale-*) bfd_gas=yes ;;
 495       *-elf)    bfd_gas=yes ;;
 496       *-ecoff)  bfd_gas=yes ;;
 497       *-som)    bfd_gas=yes ;;
 498     #enable bfd for coff and aout to allow testing if a bfd target is
 499     #the primary target, but not for coff or aout as the primary target
 500       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 501       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 502       *)                ;;
 503     esac
 504
 505 # Other random stuff.
 506
 507     # Do we need the opcodes library?
 508     case ${cpu_type} in
 509       vax | i386 | tic30)
 510         ;;
 511
 512       *)
 513         need_opcodes=yes
 514
 515         case "${enable_shared}" in
 516         yes) shared_opcodes=true ;;
 517         *opcodes*) shared_opcodes=true ;;
 518         *) shared_opcodes=false ;;
 519         esac
 520         if test "${shared_opcodes}" = "true"; then
 521           # A shared libopcodes must be linked against libbfd.
 522           need_bfd=yes
 523         fi
 524         ;;
 525     esac
 526
 527     # Any other special object files needed ?
 528     case ${cpu_type} in
 529       fr30 | m32r | openrisc)
 530         using_cgen=yes
 531         ;;
 532
 533       m68k)
 534         case ${extra_objects} in
 535         *m68k-parse.o*) ;;
 536         *) extra_objects="$extra_objects m68k-parse.o" ;;
 537         esac
 538         ;;
 539
 540       s390)
 541        if test $this_target = $target ; then
 542           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 543        fi
 544        ;;
 545
 546       mips)
 547         echo ${extra_objects} | grep -s "itbl-parse.o"
 548         if test $? -ne 0 ; then
 549           extra_objects="$extra_objects itbl-parse.o"
 550         fi
 551
 552         echo ${extra_objects} | grep -s "itbl-lex.o"
 553         if test $? -ne 0 ; then
 554           extra_objects="$extra_objects itbl-lex.o"
 555         fi
 556
 557         echo ${extra_objects} | grep -s "itbl-ops.o"
 558         if test $? -ne 0 ; then
 559           extra_objects="$extra_objects itbl-ops.o"
 560         fi
 561         ;;
 562
 563       i386)
 564         if test $this_target = $target ; then
 565           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 566         fi
 567         ;;
 568       sparc)
 569         if test $this_target = $target ; then
 570           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 571         fi
 572         ;;
 573       *)
 574         ;;
 575     esac
 576
 577     if test $using_cgen = yes ; then
 578         case "x${extra_objects}" in
 579         *cgen.o*) ;;
 580         *) extra_objects="$extra_objects cgen.o" ;;
 581         esac
 582     fi
 583
 584 # See if we really can support this configuration with the emulation code.
 585
 586     if test $this_target = $target ; then
 587       primary_bfd_gas=$bfd_gas
 588       obj_format=$fmt
 589       te_file=$em
 590
 591       if test $bfd_gas = no ; then
 592         # Can't support other configurations this way.
 593         break
 594       fi
 595     elif test $bfd_gas = no ; then
 596       # Can't support this configuration.
 597       break
 598     fi
 599
 600 # From target name and format, produce a list of supported emulations.
 601
 602     case ${generic_target}-${fmt} in
 603       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 604       mips-*-linux-gnu*-*) case "$endian" in
 605                         big)    emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 606                         *)      emulation="mipslelf mipsbelf mipself mipslecoff mipsbecoff mipsecoff" ;;
 607                         esac ;;
 608       mips-*-lnews*-ecoff) ;;
 609       mips-*-*-ecoff)   case "$endian" in
 610                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 611                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 612                         esac ;;
 613       mips-*-*-elf)     case "$endian" in
 614                         big)    emulation="mipsbelf mipslelf mipself" ;;
 615                         *)      emulation="mipslelf mipsbelf mipself" ;;
 616                         esac ;;
 617       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 618       # i386-pc-pe-coff != i386-pc-coff.
 619       i386-*-pe-coff)   ;;
 620       # Uncommenting the next line will turn on support for i386 AOUT
 621       # for the default linux configuration
 622       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 623       #
 624       i386-*-aout)      emulation="i386aout" ;;
 625       i386-*-coff)      emulation="i386coff" ;;
 626       i386-*-elf)       emulation="i386elf" ;;
 627
 628       # Always all formats.  The first stated emulation becomes the default.
 629       cris-*-*aout*)    emulation="crisaout criself" ;;
 630       cris-*-*)         emulation="criself crisaout" ;;
 631     esac
 632
 633     emulations="$emulations $emulation"
 634
 635 done
 636
 637 # Turn on all targets if possible
 638 if test ${all_targets} = "yes"; then
 639   case ${target_cpu_type} in
 640   i386)
 641     case ${obj_format} in
 642     aout)
 643       emulations="$emulations i386coff i386elf"
 644       ;;
 645     coff)
 646       emulations="$emulations i386aout i386elf"
 647     ;;
 648     elf)
 649       emulations="$emulations i386aout i386coff"
 650       ;;
 651     esac
 652   ;;
 653   esac
 654 fi
 655
 656 # Assign floating point type.  Most processors with FP support
 657 # IEEE FP.  On those that don't support FP at all, usually IEEE
 658 # is emulated.
 659 case ${target_cpu} in
 660   vax | tahoe ) atof=${target_cpu} ;;
 661   pdp11)        atof=vax ;;
 662   *)            atof=ieee ;;
 663 esac
 664
 665 case "${obj_format}" in
 666   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 667 esac
 668
 669 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 670 cgen_cpu_prefix=""
 671 if test $using_cgen = yes ; then
 672   case ${target_cpu} in
 673     *) cgen_cpu_prefix=${target_cpu} ;;
 674   esac
 675   AC_SUBST(cgen_cpu_prefix)
 676   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 677 fi
 678
 679 dnl
 680 dnl Make sure the desired support files exist.
 681 dnl
 682
 683 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 684   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 685 fi
 686
 687 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 688   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 689 fi
 690
 691 case ${user_bfd_gas}-${primary_bfd_gas} in
 692   yes-yes | no-no)
 693     # We didn't override user's choice.
 694     ;;
 695   no-yes)
 696     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 697     ;;
 698   no-preferred)
 699     primary_bfd_gas=no
 700     ;;
 701   *-preferred)
 702     primary_bfd_gas=yes
 703     ;;
 704   yes-*)
 705     primary_bfd_gas=yes
 706     ;;
 707   -*)
 708     # User specified nothing.
 709     ;;
 710 esac
 711
 712 # Some COFF configurations want these random other flags set.
 713 case ${obj_format} in
 714   coff)
 715     case ${target_cpu_type} in
 716       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 717       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 718       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 719     esac
 720     ;;
 721 esac
 722
 723 # Getting this done right is going to be a bitch.  Each configuration specified
 724 # with --enable-targets=... should be checked for environment, format, cpu, and
 725 # bfd_gas setting.
 726 #
 727 # For each configuration, the necessary object file support code must be linked
 728 # in.  This might be only one, it might be up to four.  The necessary emulation
 729 # code needs to be provided, too.
 730 #
 731 # And then there's "--enable-targets=all"....
 732 #
 733 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 734
 735 formats="${obj_format}"
 736 emfiles=""
 737 EMULATIONS=""
 738 GAS_UNIQ(emulations)
 739 for em in . $emulations ; do
 740   case $em in
 741     .)  continue ;;
 742     mipsbelf | mipslelf | mipself)
 743         fmt=elf   file=mipself ;;
 744     mipsbecoff | mipslecoff | mipsecoff)
 745         fmt=ecoff file=mipsecoff ;;
 746     *coff)
 747         fmt=coff  file=$em ;;
 748     *aout)
 749         fmt=aout file=$em ;;
 750     *elf)
 751         fmt=elf file=$em ;;
 752   esac
 753   formats="$formats $fmt"
 754   emfiles="$emfiles e-$file.o"
 755   EMULATIONS="$EMULATIONS &$em,"
 756 done
 757 GAS_UNIQ(formats)
 758 GAS_UNIQ(emfiles)
 759 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 760   for fmt in $formats ; do
 761     case $fmt in
 762       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 763       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 764       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 765       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 766       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 767       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 768       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 769       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 770       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 771       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 772     esac
 773     extra_objects="$extra_objects obj-$fmt.o"
 774   done
 775   obj_format=multi
 776 fi
 777 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 778   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 779   # e-mips* has more than one emulation per file, e-i386* has just one at the
 780   # moment.  If only one emulation is specified, then don't define
 781   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 782   case "${obj_format}${emfiles}" in
 783     multi* | *mips*)
 784       extra_objects="$extra_objects $emfiles"
 785       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 786   esac
 787 fi
 788 AC_SUBST(extra_objects)
 789 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 790 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 791                    [Default emulation.])
 792
 793 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 794   yes-*-coff)   need_bfd=yes ;;
 795   no-*-coff)    need_bfd=yes
 796                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 797 esac
 798
 799 reject_dev_configs=yes
 800
 801 case ${reject_dev_configs}-${dev} in
 802   yes-yes) # Oops.
 803     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 804     ;;
 805 esac
 806
 807 AC_SUBST(target_cpu_type)
 808 AC_SUBST(obj_format)
 809 AC_SUBST(te_file)
 810 AC_SUBST(install_tooldir)
 811 AC_SUBST(atof)
 812 dnl AC_SUBST(emulation)
 813
 814 case "${primary_bfd_gas}" in
 815   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 816         need_bfd=yes ;;
 817 esac
 818
 819 # do we need the opcodes library?
 820 case "${need_opcodes}" in
 821 yes)
 822   OPCODES_LIB=../opcodes/libopcodes.la
 823   ;;
 824 esac
 825
 826 case "${need_bfd}" in
 827 yes)
 828   BFDLIB=../bfd/libbfd.la
 829   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 830   ;;
 831 esac
 832
 833 AC_SUBST(BFDLIB)
 834 AC_SUBST(OPCODES_LIB)
 835
 836 AC_SUBST(ALL_OBJ_DEPS)
 837
 838 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 839 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 840 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 841 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 842 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 843
 844 AC_PROG_CC
 845
 846 AC_PROG_YACC
 847 AM_PROG_LEX
 848
 849 ALL_LINGUAS=
 850 CY_GNU_GETTEXT
 851
 852 AM_MAINTAINER_MODE
 853 AC_EXEEXT
 854
 855 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 856
 857 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 858 # people who are not cross-compiling but are compiling cross-assemblers.
 859 AC_MSG_CHECKING(whether compiling a cross-assembler)
 860 if test "${host}" = "${target}"; then
 861   cross_gas=no
 862 else
 863   cross_gas=yes
 864   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 865 fi
 866 AC_MSG_RESULT($cross_gas)
 867
 868 dnl ansidecl.h will deal with const
 869 dnl AC_CONST
 870 AC_FUNC_ALLOCA
 871 AC_C_INLINE
 872
 873 # VMS doesn't have unlink.
 874 AC_CHECK_FUNCS(unlink remove, break)
 875
 876 # Some systems don't have sbrk().
 877 AC_CHECK_FUNCS(sbrk)
 878
 879 # do we need the math library?
 880 case "${need_libm}" in
 881 yes)
 882   AC_CHECK_LIBM
 883   AC_SUBST(LIBM)
 884   ;;
 885 esac
 886
 887 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 888 # enough, but on some of those systems, the assert macro relies on requoting
 889 # working properly!
 890 GAS_WORKING_ASSERT
 891
 892 # On some systems, the system header files may not declare malloc, realloc,
 893 # and free.  There are places where gas needs these functions to have been
 894 # declared -- such as when taking their addresses.
 895 gas_test_headers="
 896 #ifdef HAVE_MEMORY_H
 897 #include <memory.h>
 898 #endif
 899 #ifdef HAVE_STRING_H
 900 #include <string.h>
 901 #else
 902 #ifdef HAVE_STRINGS_H
 903 #include <strings.h>
 904 #endif
 905 #endif
 906 #ifdef HAVE_STDLIB_H
 907 #include <stdlib.h>
 908 #endif
 909 #ifdef HAVE_UNISTD_H
 910 #include <unistd.h>
 911 #endif
 912 "
 913 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 914 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 915 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 916 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 917 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 918
 919 # Does errno.h declare errno, or do we have to add a separate declaration
 920 # for it?
 921 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 922 #ifdef HAVE_ERRNO_H
 923 #include <errno.h>
 924 #endif
 925 ])
 926
 927 dnl This must come last.
 928
 929 dnl We used to make symlinks to files in the source directory, but now
 930 dnl we just use the right name for .c files, and create .h files in
 931 dnl the build directory which include the right .h file.  Make sure
 932 dnl the old symlinks don't exist, so that a reconfigure in an existing
 933 dnl directory behaves reasonably.
 934
 935 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 936 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 937  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 938  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 939  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 940  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 941  if test "x$cgen_cpu_prefix" != x ; then
 942    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 943  fi
 944
 945  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 946 [target_cpu_type=${target_cpu_type}
 947  cgen_cpu_prefix=${cgen_cpu_prefix}
 948  obj_format=${obj_format}
 949  te_file=${te_file}])