opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`grep INIT_AUTOMAKE ${srcdir}/../bfd/configure.in | sed -n -e 's/[  ]//g' -e 's/^.*,\(.*\)).*$/\1/p'`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 build_warnings="-W -Wall"
  47 AC_ARG_ENABLE(build-warnings,
  48 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  49 [case "${enableval}" in
  50   yes)  ;;
  51   no)   build_warnings="-w";;
  52   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  53         build_warnings="${build_warnings} ${t}";;
  54   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  55         build_warnings="${t} ${build_warnings}";;
  56   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  57 esac
  58 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  59   echo "Setting warning flags = $build_warnings" 6>&1
  60 fi])dnl
  61 WARN_CFLAGS=""
  62 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  63     WARN_CFLAGS="${build_warnings}"
  64 fi
  65 AC_SUBST(WARN_CFLAGS)
  66
  67 AM_CONFIG_HEADER(config.h:config.in)
  68
  69 if test -z "$target" ; then
  70     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  71 fi
  72 AC_ARG_PROGRAM
  73
  74 AM_MAINTAINER_MODE
  75 AC_EXEEXT
  76
  77 # host-specific stuff:
  78
  79 AC_PROG_CC
  80
  81 ALL_LINGUAS=
  82 CY_GNU_GETTEXT
  83
  84 . ${srcdir}/../bfd/configure.host
  85
  86 AC_SUBST(HDEFINES)
  87 AC_PROG_INSTALL
  88
  89 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  90
  91
  92 using_cgen=no
  93
  94 # Horrible hacks to build DLLs on Windows.
  95 WIN32LDFLAGS=
  96 WIN32LIBADD=
  97 case "${host}" in
  98 *-*-cygwin*)
  99   if test "$enable_shared" = "yes"; then
 100     WIN32LDFLAGS="-no-undefined"
 101     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 102   fi
 103   ;;
 104 esac
 105 AC_SUBST(WIN32LDFLAGS)
 106 AC_SUBST(WIN32LIBADD)
 107
 108 # target-specific stuff:
 109
 110 # Canonicalize the secondary target names.
 111 if test -n "$enable_targets" ; then
 112     for targ in `echo $enable_targets | sed 's/,/ /g'`
 113     do
 114         result=`$ac_config_sub $targ 2>/dev/null`
 115         if test -n "$result" ; then
 116             canon_targets="$canon_targets $result"
 117         else
 118             # Allow targets that config.sub doesn't recognize, like "all".
 119             canon_targets="$canon_targets $targ"
 120         fi
 121     done
 122 fi
 123
 124 all_targets=false
 125 selarchs=
 126 for targ in $target $canon_targets
 127 do
 128     if test "x$targ" = "xall" ; then
 129         all_targets=true
 130     else
 131         . $srcdir/../bfd/config.bfd
 132         selarchs="$selarchs $targ_archs"
 133     fi
 134 done
 135
 136 # Utility var, documents generic cgen support files.
 137
 138 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 139
 140 # We don't do any links based on the target system, just makefile config.
 141
 142 if test x${all_targets} = xfalse ; then
 143
 144     # Target architecture .o files.
 145     ta=
 146
 147     for arch in $selarchs
 148     do
 149         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 150         archdefs="$archdefs -DARCH_$ad"
 151         case "$arch" in
 152         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 153         bfd_alliant_arch)       ;;
 154         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 155         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo" ;;
 156         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 157         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 158         bfd_convex_arch)        ;;
 159         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 160         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 161         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 162         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 163         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 164         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 165         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 166         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 167         bfd_i860_arch)          ;;
 168         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 169         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 170         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 171         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 172         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 173         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 174         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 175         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 176         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 177         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 178         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 179         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 180         bfd_pyramid_arch)       ;;
 181         bfd_romp_arch)          ;;
 182         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 183         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 184         bfd_sh_arch)            ta="$ta sh-dis.lo" ;;
 185         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 186         bfd_tahoe_arch)         ;;
 187         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 188         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 189         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 190         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 191         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 192         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 193         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 194         bfd_we32k_arch)         ;;
 195         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 196
 197         "")                     ;;
 198         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 199         esac
 200     done
 201
 202     if test $using_cgen = yes ; then
 203         ta="$ta $cgen_files"
 204     fi
 205
 206     # Weed out duplicate .o files.
 207     f=""
 208     for i in $ta ; do
 209         case " $f " in
 210         *" $i "*) ;;
 211         *) f="$f $i" ;;
 212         esac
 213     done
 214     ta="$f"
 215
 216     # And duplicate -D flags.
 217     f=""
 218     for i in $archdefs ; do
 219         case " $f " in
 220         *" $i "*) ;;
 221         *) f="$f $i" ;;
 222         esac
 223     done
 224     archdefs="$f"
 225
 226     BFD_MACHINES="$ta"
 227
 228 else    # all_targets is true
 229     archdefs=-DARCH_all
 230     BFD_MACHINES='$(ALL_MACHINES)'
 231 fi
 232
 233 AC_SUBST(archdefs)
 234 AC_SUBST(BFD_MACHINES)
 235
 236 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 237 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])