ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ldmain.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_BUILD
   9 AC_ISC_POSIX
  10
  11 changequote(,)dnl
  12 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  13 changequote([,])dnl
  14 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  15 AM_MAINTAINER_MODE
  16
  17 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  18 AC_ARG_ENABLE(targets,
  19 [  --enable-targets        alternative target configurations],
  20 [case "${enableval}" in
  21   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(64-bit-bfd,
  27 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  28 [case "${enableval}" in
  29   yes)  want64=true  ;;
  30   no)   want64=false ;;
  31   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  32 esac],[want64=false])dnl
  33
  34 AC_ARG_WITH(sysroot,
  35 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  36 [
  37  case ${with_sysroot} in
  38  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  39  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  40  esac
  41
  42  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  43  use_sysroot=yes
  44
  45  if test "x$prefix" = xNONE; then
  46   test_prefix=/usr/local
  47  else
  48   test_prefix=$prefix
  49  fi
  50  if test "x$exec_prefix" = xNONE; then
  51   test_exec_prefix=$test_prefix
  52  else
  53   test_exec_prefix=$exec_prefix
  54  fi
  55  case ${TARGET_SYSTEM_ROOT} in
  56  "${test_prefix}"|"${test_prefix}/"*|\
  57  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  58  '${prefix}'|'${prefix}/'*|\
  59  '${exec_prefix}'|'${exec_prefix}/'*)
  60    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  61    TARGET_SYSTEM_ROOT_DEFINE="$t"
  62    ;;
  63  esac
  64 ], [
  65  use_sysroot=no
  66  TARGET_SYSTEM_ROOT=
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  68 ])
  69 AC_SUBST(use_sysroot)
  70 AC_SUBST(TARGET_SYSTEM_ROOT)
  71 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  72
  73 dnl Use --enable-gold to decide if this linker should be the default.
  74 dnl "install_as_default" is set to false if gold is the default linker.
  75 dnl "installed_linker" is the installed BFD linker name.
  76 AC_ARG_ENABLE(gold,
  77 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  78 [case "${enableval}" in
  79  default)
  80    install_as_default=no
  81    installed_linker=ld.bfd
  82    ;;
  83  yes|no)
  84    install_as_default=yes
  85    installed_linker=ld.bfd
  86    ;;
  87  *)
  88    AC_MSG_ERROR([invalid --enable-gold argument])
  89    ;;
  90  esac],
  91 [install_as_default=yes
  92  installed_linker=ld.bfd])
  93 AC_SUBST(install_as_default)
  94 AC_SUBST(installed_linker)
  95
  96 AC_ARG_ENABLE([got],
  97 AS_HELP_STRING([--enable-got=<type>],
  98                [GOT handling scheme (target, single, negative, multigot)]),
  99 [case "${enableval}" in
 100   target | single | negative | multigot)  got_handling=$enableval ;;
 101   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 102 esac],
 103 [got_handling=target])
 104
 105 case "${got_handling}" in
 106   target)
 107     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 108               [Define to choose default GOT handling scheme]) ;;
 109   single)
 110     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 111               [Define to choose default GOT handling scheme]) ;;
 112   negative)
 113     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 114               [Define to choose default GOT handling scheme]) ;;
 115   multigot)
 116     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 117               [Define to choose default GOT handling scheme]) ;;
 118   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 119 esac
 120
 121 AM_BINUTILS_WARNINGS
 122
 123 AC_CONFIG_HEADERS([config.h:config.in])
 124
 125 if test -z "$target" ; then
 126     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 127 fi
 128 if test -z "$host" ; then
 129     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 130 fi
 131
 132 # host-specific stuff:
 133
 134 AC_PROG_CC
 135 AC_PROG_CXX
 136 AC_GNU_SOURCE
 137 AC_USE_SYSTEM_EXTENSIONS
 138 ACX_LARGEFILE
 139 AC_PROG_INSTALL
 140
 141 LT_INIT
 142
 143 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it"
 144 ZW_GNU_GETTEXT_SISTER_DIR
 145 AM_PO_SUBDIRS
 146
 147 AC_EXEEXT
 148
 149 AC_PROG_YACC
 150 AM_PROG_LEX
 151
 152 AM_MAINTAINER_MODE
 153 AM_CONDITIONAL(GENINSRC_NEVER, false)
 154 ACX_PROG_CMP_IGNORE_INITIAL
 155
 156 . ${srcdir}/configure.host
 157
 158 AC_SUBST(HDEFINES)
 159 AC_SUBST(HOSTING_CRT0)
 160 AC_SUBST(HOSTING_LIBS)
 161 AC_SUBST(NATIVE_LIB_DIRS)
 162
 163 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 164 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 165 AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid)
 166 AC_CHECK_FUNCS(open lseek close)
 167 AC_HEADER_DIRENT
 168
 169 # Check for dlopen support and enable plugins if possible.
 170 enable_plugins=yes
 171 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 172 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 173 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 174 # We also support plugins on Windows (MinGW).
 175 if test x$enable_plugins = xno ; then
 176   AC_CHECK_HEADERS([windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 177 fi
 178 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 179
 180 AC_ARG_ENABLE(initfini-array,
 181         [  --enable-initfini-array      use .init_array/.fini_array sections],
 182         [], [
 183 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 184                  gcc_cv_initfini_array, [dnl
 185   if test "x${build}" = "x${target}" ; then
 186     AC_RUN_IFELSE([AC_LANG_SOURCE([
 187 static int x = -1;
 188 int main (void) { return x; }
 189 int foo (void) { x = 0; }
 190 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 191              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 192              [gcc_cv_initfini_array=no])
 193    else
 194      gcc_cv_initfini_array=no
 195    fi])
 196   enable_initfini_array=$gcc_cv_initfini_array
 197 ])
 198 AC_SUBST(enable_initfini_array)
 199 if test $enable_initfini_array = yes; then
 200   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 201     [Define .init_array/.fini_array sections are available and working.])
 202 fi
 203
 204 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 205 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 206 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 207 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 208 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 209 if test $ld_cv_decl_getopt_unistd_h = yes; then
 210   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 211             [Is the prototype for getopt in <unistd.h> in the expected format?])
 212 fi
 213
 214 BFD_BINARY_FOPEN
 215
 216 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 217
 218 # Link in zlib if we can.  This is needed only for the bootstrap tests
 219 # right now, since those tests use libbfd, which depends on zlib.
 220 AM_ZLIB
 221
 222 # When converting linker scripts into strings for use in emulation
 223 # files, use astring.sed if the compiler supports ANSI string
 224 # concatenation, or ostring.sed otherwise.  This is to support the
 225 # broken Microsoft MSVC compiler, which limits the length of string
 226 # constants, while still supporting pre-ANSI compilers which do not
 227 # support string concatenation.
 228 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 229 AC_CACHE_VAL(ld_cv_string_concatenation,
 230 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 231   ld_cv_string_concatenation=yes,
 232   ld_cv_string_concatenation=no)])
 233 AC_MSG_RESULT($ld_cv_string_concatenation)
 234 if test "$ld_cv_string_concatenation" = "yes"; then
 235   STRINGIFY=astring.sed
 236 else
 237   STRINGIFY=ostring.sed
 238 fi
 239 AC_SUBST(STRINGIFY)
 240
 241 # target-specific stuff:
 242
 243 all_targets=
 244 EMUL=
 245 all_emuls=
 246 all_emul_extras=
 247 all_libpath=
 248
 249 dnl We need to get an arbitrary number of tdir definitions into
 250 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 251 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 252 dnl file.
 253 rm -f tdirs
 254
 255 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 256 do
 257   if test "$targ_alias" = "all"; then
 258     all_targets=true
 259   else
 260     # Canonicalize the secondary target names.
 261     result=`$ac_config_sub $targ_alias 2>/dev/null`
 262     if test -n "$result"; then
 263         targ=$result
 264     else
 265         targ=$targ_alias
 266     fi
 267
 268     . ${srcdir}/configure.tgt
 269
 270     if test "$targ" = "$target"; then
 271       EMUL=$targ_emul
 272     fi
 273
 274     if test x${want64} = xfalse; then
 275       . ${srcdir}/../bfd/config.bfd
 276     fi
 277
 278     if test x${want64} = xtrue; then
 279       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 280       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 281     fi
 282
 283     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 284         case " $all_emuls " in
 285         *" e${i}.o "*) ;;
 286         *)
 287           all_emuls="$all_emuls e${i}.o"
 288           eval result=\$tdir_$i
 289           test -z "$result" && result=$targ_alias
 290           echo tdir_$i=$result >> tdirs
 291           ;;
 292         esac
 293     done
 294
 295     for i in $targ_emul $targ_extra_libpath; do
 296         case " $all_libpath " in
 297         *" ${i} "*) ;;
 298         *)
 299           if test -z "$all_libpath"; then
 300             all_libpath=${i}
 301           else
 302             all_libpath="$all_libpath ${i}"
 303           fi
 304           ;;
 305         esac
 306     done
 307
 308     for i in $targ_extra_ofiles; do
 309         case " $all_emul_extras " in
 310         *" ${i} "*) ;;
 311         *)
 312           all_emul_extras="$all_emul_extras ${i}"
 313           ;;
 314         esac
 315     done
 316   fi
 317 done
 318
 319 AC_SUBST(EMUL)
 320
 321 TDIRS=tdirs
 322 AC_SUBST_FILE(TDIRS)
 323
 324 if test x${all_targets} = xtrue; then
 325   if test x${want64} = xfalse; then
 326     AC_CHECK_SIZEOF(long)
 327     if test "x${ac_cv_sizeof_long}" = "x8"; then
 328       want64=true
 329     fi
 330   fi
 331   if test x${want64} = xtrue; then
 332     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 333   else
 334     EMULATION_OFILES='$(ALL_EMULATIONS)'
 335   fi
 336   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 337 else
 338   EMULATION_OFILES=$all_emuls
 339   EMUL_EXTRA_OFILES=$all_emul_extras
 340 fi
 341 AC_SUBST(EMULATION_OFILES)
 342 AC_SUBST(EMUL_EXTRA_OFILES)
 343 AC_SUBST(LIB_PATH)
 344
 345 EMULATION_LIBPATH=$all_libpath
 346 AC_SUBST(EMULATION_LIBPATH)
 347
 348 if test x${enable_static} = xno; then
 349   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 350 else
 351   TESTBFDLIB="../bfd/.libs/libbfd.a"
 352 fi
 353 AC_SUBST(TESTBFDLIB)
 354
 355 target_vendor=${target_vendor=$host_vendor}
 356 case "$target_vendor" in
 357   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 358   *)  EXTRA_SHLIB_EXTENSION= ;;
 359 esac
 360
 361 case "$target_os" in
 362   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 363 esac
 364
 365 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 366   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 367    [Additional extension a shared object might have.])
 368 fi
 369
 370 dnl Required by html, pdf, install-pdf and install-html
 371 AC_SUBST(datarootdir)
 372 AC_SUBST(docdir)
 373 AC_SUBST(htmldir)
 374 AC_SUBST(pdfdir)
 375
 376 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 377 AC_OUTPUT