bfd/acinclude.m4

   1 sinclude(../config/acx.m4)
   2 sinclude(../config/gettext-sister.m4)
   3 sinclude(../config/nls.m4)
   4 sinclude(../config/po.m4)
   5 sinclude(../config/progtest.m4)
   6 sinclude(../bfd/bfd.m4)
   7 sinclude(../bfd/warning.m4)
   8
   9 dnl See whether we need to use fopen-bin.h rather than fopen-same.h.
  10 AC_DEFUN([BFD_BINARY_FOPEN],
  11 [AC_REQUIRE([AC_CANONICAL_TARGET])
  12 case "${host}" in
  13 changequote(,)dnl
  14 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  15 changequote([,])dnl
  16   AC_DEFINE(USE_BINARY_FOPEN, 1, [Use b modifier when opening binary files?]) ;;
  17 esac])dnl
  18
  19 dnl Get a default for CC_FOR_BUILD to put into Makefile.
  20 AC_DEFUN([BFD_CC_FOR_BUILD],
  21 [# Put a plausible default for CC_FOR_BUILD in Makefile.
  22 if test -z "$CC_FOR_BUILD"; then
  23   if test "x$cross_compiling" = "xno"; then
  24     CC_FOR_BUILD='$(CC)'
  25   else
  26     CC_FOR_BUILD=gcc
  27   fi
  28 fi
  29 AC_SUBST(CC_FOR_BUILD)
  30 # Also set EXEEXT_FOR_BUILD.
  31 if test "x$cross_compiling" = "xno"; then
  32   EXEEXT_FOR_BUILD='$(EXEEXT)'
  33 else
  34   AC_CACHE_CHECK([for build system executable suffix], bfd_cv_build_exeext,
  35     [rm -f conftest*
  36      echo 'int main () { return 0; }' > conftest.c
  37      bfd_cv_build_exeext=
  38      ${CC_FOR_BUILD} -o conftest conftest.c 1>&5 2>&5
  39      for file in conftest.*; do
  40        case $file in
  41        *.c | *.o | *.obj | *.ilk | *.pdb) ;;
  42        *) bfd_cv_build_exeext=`echo $file | sed -e s/conftest//` ;;
  43        esac
  44      done
  45      rm -f conftest*
  46      test x"${bfd_cv_build_exeext}" = x && bfd_cv_build_exeext=no])
  47   EXEEXT_FOR_BUILD=""
  48   test x"${bfd_cv_build_exeext}" != xno && EXEEXT_FOR_BUILD=${bfd_cv_build_exeext}
  49 fi
  50 AC_SUBST(EXEEXT_FOR_BUILD)])dnl
  51
  52 sinclude(../libtool.m4)
  53 dnl The lines below arrange for aclocal not to bring libtool.m4
  54 dnl AM_PROG_LIBTOOL into aclocal.m4, while still arranging for automake
  55 dnl to add a definition of LIBTOOL to Makefile.in.
  56 ifelse(yes,no,[
  57 AC_DEFUN([AM_PROG_LIBTOOL],)
  58 AC_DEFUN([AM_DISABLE_SHARED],)
  59 AC_SUBST(LIBTOOL)
  60 ])
  61
  62 AC_DEFUN([AM_INSTALL_LIBBFD],
  63 [AC_MSG_CHECKING([whether to install libbfd])
  64   AC_ARG_ENABLE(install-libbfd,
  65 [  --enable-install-libbfd controls installation of libbfd and related headers],
  66       install_libbfd_p=$enableval,
  67       if test "${host}" = "${target}" || test "$enable_shared" = "yes"; then
  68         install_libbfd_p=yes
  69       else
  70         install_libbfd_p=no
  71       fi)
  72   AC_MSG_RESULT($install_libbfd_p)
  73   AM_CONDITIONAL(INSTALL_LIBBFD, test $install_libbfd_p = yes)
  74   # Need _noncanonical variables for this.
  75   ACX_NONCANONICAL_HOST
  76   ACX_NONCANONICAL_TARGET
  77   # libbfd.a is a host library containing target dependent code
  78   bfdlibdir='$(libdir)'
  79   bfdincludedir='$(includedir)'
  80   if test "${host}" != "${target}"; then
  81     bfdlibdir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/lib'
  82     bfdincludedir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/include'
  83   fi
  84   AC_SUBST(bfdlibdir)
  85   AC_SUBST(bfdincludedir)
  86 ]
  87 )