bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.17.50)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AC_ARG_ENABLE(secureplt,
  55 [  --enable-secureplt      Default to creating read-only plt entries],
  56 [case "${enableval}" in
  57   yes)  use_secureplt=true  ;;
  58   no)   use_secureplt=false ;;
  59   *)    AC_MSG_ERROR(bad value ${enableval} for secureplt option) ;;
  60 esac],[use_secureplt=false])dnl
  61 if test $use_secureplt = true; then
  62   AC_DEFINE(USE_SECUREPLT, 1,
  63     [Define if we should default to creating read-only plt entries])
  64 fi
  65
  66 AM_BINUTILS_WARNINGS
  67
  68 AM_CONFIG_HEADER(config.h:config.in)
  69
  70 if test -z "$target" ; then
  71     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  72 fi
  73
  74 AM_MAINTAINER_MODE
  75 AM_INSTALL_LIBBFD
  76 AC_EXEEXT
  77
  78 host64=false
  79 target64=false
  80 bfd_default_target_size=32
  81
  82 # host stuff:
  83
  84 AC_PROG_CC
  85 AC_GNU_SOURCE
  86
  87 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw vi"
  88 ZW_GNU_GETTEXT_SISTER_DIR
  89 AM_PO_SUBDIRS
  90
  91 # Permit host specific settings.
  92 . ${srcdir}/configure.host
  93
  94 AC_SUBST(HDEFINES)
  95 AC_PROG_INSTALL
  96
  97 BFD_HOST_64BIT_LONG=0
  98 BFD_HOST_LONG_LONG=0
  99 BFD_HOST_64_BIT_DEFINED=0
 100 BFD_HOST_64_BIT=
 101 BFD_HOST_U_64_BIT=
 102
 103 AC_MSG_CHECKING([for long long])
 104 AC_CACHE_VAL(bfd_cv_has_long_long,
 105 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 106 AC_MSG_RESULT($bfd_cv_has_long_long)
 107 if test $bfd_cv_has_long_long = yes; then
 108   BFD_HOST_LONG_LONG=1
 109   AC_CHECK_SIZEOF(long long)
 110 fi
 111
 112 AC_CHECK_SIZEOF(long)
 113 if test "x${ac_cv_sizeof_long}" = "x8"; then
 114   host64=true
 115   BFD_HOST_64BIT_LONG=1
 116   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 117   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 118 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 119   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 120   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 121 fi
 122
 123 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 124   BFD_HOST_64_BIT_DEFINED=1
 125   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 126   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 127 fi
 128
 129 AC_SUBST(BFD_HOST_64BIT_LONG)
 130 AC_SUBST(BFD_HOST_LONG_LONG)
 131 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 132 AC_SUBST(BFD_HOST_64_BIT)
 133 AC_SUBST(BFD_HOST_U_64_BIT)
 134
 135 BFD_CC_FOR_BUILD
 136
 137 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 138 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 139 AC_HEADER_TIME
 140 AC_HEADER_DIRENT
 141 ACX_HEADER_STRING
 142 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 143 AC_CHECK_FUNCS(strtoull)
 144
 145 AC_CHECK_DECLS(basename)
 146 AC_CHECK_DECLS(ftello)
 147 AC_CHECK_DECLS(ftello64)
 148 AC_CHECK_DECLS(fseeko)
 149 AC_CHECK_DECLS(fseeko64)
 150
 151 BFD_BINARY_FOPEN
 152
 153 AC_CHECK_DECLS(ffs)
 154 AC_CHECK_DECLS(free)
 155 AC_CHECK_DECLS(getenv)
 156 AC_CHECK_DECLS(malloc)
 157 AC_CHECK_DECLS(realloc)
 158 AC_CHECK_DECLS(stpcpy)
 159 AC_CHECK_DECLS(strstr)
 160 AC_CHECK_DECLS(snprintf)
 161 AC_CHECK_DECLS(vsnprintf)
 162
 163 # If we are configured native, pick a core file support file.
 164 COREFILE=
 165 COREFLAG=
 166 TRAD_HEADER=
 167 if test "${target}" = "${host}"; then
 168   case "${host}" in
 169   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 170         COREFILE=''
 171         ;;
 172   alpha*-*-linux-*)
 173         COREFILE=trad-core.lo
 174         TRAD_HEADER='"hosts/alphalinux.h"'
 175         ;;
 176   alpha*-*-netbsd* | alpha*-*-openbsd*)
 177         COREFILE=netbsd-core.lo
 178         ;;
 179   alpha*-*-*)           COREFILE=osf-core.lo ;;
 180   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 181                         COREFILE='' ;;
 182   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 183   arm-*-riscix)         COREFILE=trad-core.lo ;;
 184   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 185   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 186   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 187   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 188                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 189   hppa*-*-netbsd* | hppa*-*-openbsd*)
 190         COREFILE=netbsd-core.lo
 191         ;;
 192
 193   i370-*-*)
 194         COREFILE=trad-core.lo
 195         TRAD_HEADER='"hosts/i370linux.h"'
 196         ;;
 197
 198 changequote(,)dnl
 199   i[3-7]86-sequent-bsd*)
 200 changequote([,])dnl
 201         COREFILE=trad-core.lo
 202         TRAD_HEADER='"hosts/symmetry.h"'
 203         ;;
 204 changequote(,)dnl
 205   i[3-7]86-sequent-sysv4*) ;;
 206   i[3-7]86-sequent-sysv*)
 207 changequote([,])dnl
 208         COREFILE=trad-core.lo
 209         TRAD_HEADER='"hosts/symmetry.h"'
 210         ;;
 211 changequote(,)dnl
 212   i[3-7]86-*-bsdi)
 213 changequote([,])dnl
 214         COREFILE=
 215         ;;
 216 changequote(,)dnl
 217   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 218 changequote([,])dnl
 219         COREFILE=trad-core.lo
 220         TRAD_HEADER='"hosts/i386bsd.h"'
 221         ;;
 222 changequote(,)dnl
 223   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 224 changequote([,])dnl
 225         COREFILE=''
 226         TRAD_HEADER='"hosts/i386bsd.h"'
 227         ;;
 228 changequote(,)dnl
 229   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 230 changequote([,])dnl
 231         COREFILE=netbsd-core.lo
 232         ;;
 233 changequote(,)dnl
 234   i[3-7]86-esix-sysv3*)
 235 changequote([,])dnl
 236         COREFILE=trad-core.lo
 237         TRAD_HEADER='"hosts/esix.h"'
 238         ;;
 239 changequote(,)dnl
 240   i[3-7]86-*-sco3.2v5*)
 241 changequote([,])dnl
 242         COREFILE=sco5-core.lo
 243         ;;
 244 changequote(,)dnl
 245   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 246 changequote([,])dnl
 247         COREFILE=trad-core.lo
 248         TRAD_HEADER='"hosts/i386sco.h"'
 249         ;;
 250 changequote(,)dnl
 251   i[3-7]86-*-mach3*)
 252 changequote([,])dnl
 253         COREFILE=trad-core.lo
 254         TRAD_HEADER='"hosts/i386mach3.h"'
 255         ;;
 256 changequote(,)dnl
 257   i[3-7]86-*-linux-*)
 258 changequote([,])dnl
 259         COREFILE=trad-core.lo
 260         TRAD_HEADER='"hosts/i386linux.h"'
 261         ;;
 262 changequote(,)dnl
 263   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 264   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 265 changequote([,])dnl
 266   i860-*-mach3* | i860-*-osf1*)
 267         COREFILE=trad-core.lo
 268         TRAD_HEADER='"hosts/i860mach3.h"'
 269         ;;
 270   mips-*-netbsd* | mips*-*-openbsd*)
 271         COREFILE=netbsd-core.lo
 272         ;;
 273   mips-dec-*)
 274         COREFILE=trad-core.lo
 275         TRAD_HEADER='"hosts/decstation.h"'
 276         ;;
 277   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 278   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 279   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 280   mips-*-sysv4*)        ;;
 281   mips-*-sysv* | mips-*-riscos*)
 282         COREFILE=trad-core.lo
 283         TRAD_HEADER='"hosts/riscos.h"'
 284         ;;
 285   mips-sony-bsd*)
 286         COREFILE=trad-core.lo
 287         TRAD_HEADER='"hosts/news-mips.h"'
 288         ;;
 289   m68*-bull*-sysv*)
 290         COREFILE=trad-core.lo
 291         TRAD_HEADER='"hosts/dpx2.h"'
 292         ;;
 293   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 294   m68*-hp-bsd*)
 295         COREFILE=trad-core.lo
 296         TRAD_HEADER='"hosts/hp300bsd.h"'
 297         ;;
 298   m68*-*-linux-*)
 299         COREFILE=trad-core.lo
 300         TRAD_HEADER='"hosts/m68klinux.h"'
 301         ;;
 302   m68*-motorola-sysv*)
 303         COREFILE=trad-core.lo
 304         TRAD_HEADER='"hosts/delta68.h"'
 305         ;;
 306   m68*-sony-*)
 307         COREFILE=trad-core.lo
 308         TRAD_HEADER='"hosts/news.h"'
 309         ;;
 310   m68*-*-netbsd* | m68*-*-openbsd*)
 311         COREFILE=netbsd-core.lo
 312         ;;
 313   m68*-apple-aux*)
 314         COREFILE=trad-core.lo
 315         TRAD_HEADER='"hosts/m68kaux.h"'
 316         ;;
 317   m88*-*-sysv4*)
 318         ;;
 319   m88*-motorola-sysv*)
 320         COREFILE=ptrace-core.lo
 321         ;;
 322   m88*-*-mach3*)
 323         COREFILE=trad-core.lo
 324         TRAD_HEADER='"hosts/m88kmach3.h"'
 325         ;;
 326   m88*-*-openbsd*)
 327         COREFILE=netbsd-core.lo
 328         ;;
 329   ns32k-pc532-mach)
 330         COREFILE=trad-core.lo
 331         TRAD_HEADER='"hosts/pc532mach.h"'
 332         ;;
 333   ns32k-*-netbsd* | ns32k-*-openbsd*)
 334         COREFILE=netbsd-core.lo
 335         ;;
 336   rs6000-*-lynx*)
 337         COREFILE=lynx-core.lo
 338         ;;
 339   rs6000-*-aix5.* | powerpc-*-aix5.*)
 340         COREFILE=rs6000-core.lo
 341         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 342         ;;
 343 changequote(,)dnl
 344   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 345 changequote([,])dnl
 346         COREFILE=rs6000-core.lo
 347         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 348         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 349         # have c_impl as a member of struct core_dumpx
 350         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 351         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 352             [Define if struct core_dumpx has member c_impl])
 353           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 354         ;;
 355   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 356   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 357   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 358   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 359   powerpc-*-beos*)      ;;
 360   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 361                         COREFILE='' ;;
 362   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 363   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 364   s390*-*-*)            COREFILE=trad-core.lo ;;
 365   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 366   sparc-*-netbsd* | sparc*-*-openbsd*)
 367         COREFILE=netbsd-core.lo
 368         ;;
 369   tahoe-*-*)
 370         COREFILE=trad-core.lo
 371         TRAD_HEADER='"hosts/tahoe.h"'
 372         ;;
 373   vax-*-netbsd* | vax-*-openbsd*)
 374         COREFILE=netbsd-core.lo
 375         ;;
 376   vax-*-ultrix2*)
 377         COREFILE=trad-core.lo
 378         TRAD_HEADER='"hosts/vaxult2.h"'
 379         ;;
 380   vax-*-ultrix*)
 381         COREFILE=trad-core.lo
 382         TRAD_HEADER='"hosts/vaxult2.h"'
 383         ;;
 384   vax-*-linux-*)
 385         COREFILE=trad-core.lo
 386         TRAD_HEADER='"hosts/vaxlinux.h"'
 387         ;;
 388   vax-*-*)
 389         COREFILE=trad-core.lo
 390         TRAD_HEADER='"hosts/vaxbsd.h"'
 391         ;;
 392   x86_64-*-netbsd* | x86_64-*-openbsd*)
 393         COREFILE=netbsd-core.lo
 394         ;;
 395   esac
 396
 397   case "$COREFILE" in
 398   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 399   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 400   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 401   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 402   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 403   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 404   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 405   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 406   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 407   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 408   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 409   esac
 410
 411   # ELF corefile support has several flavors, but all of
 412   # them use something called <sys/procfs.h>
 413   AC_CHECK_HEADERS(sys/procfs.h)
 414   if test "$ac_cv_header_sys_procfs_h" = yes; then
 415     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 416     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 417     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 418     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 419     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 420     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 421     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 422     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 423     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 424     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 425     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 426     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 427     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 428     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 429     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 430     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 431   fi
 432 fi
 433 AC_SUBST(COREFILE)
 434 AC_SUBST(COREFLAG)
 435 if test -n "$TRAD_HEADER"; then
 436   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 437     [Name of host specific header file to include in trad-core.c.])
 438 fi
 439
 440 # Horrible hacks to build DLLs on Windows.
 441 WIN32LDFLAGS=
 442 WIN32LIBADD=
 443 case "${host}" in
 444 *-*-cygwin*)
 445   if test "$enable_shared" = "yes"; then
 446     WIN32LDFLAGS="-no-undefined"
 447     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 448   fi
 449   ;;
 450 *-*-linux*)
 451   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 452   # libiberty.a.
 453   case "${host}" in
 454   mips*-*-linux*)
 455     # Linux/MIPS uses PIC by default.
 456     if test "$enable_shared" = "yes"; then
 457       WIN32LIBADD="-L../libiberty -liberty"
 458     fi
 459     ;;
 460   *)
 461 changequote(,)dnl
 462     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 463 changequote([,])dnl
 464     if test -n "$x"; then
 465       WIN32LIBADD="-L../libiberty/pic -liberty"
 466     fi
 467   ;;
 468   esac
 469   ;;
 470 esac
 471 AC_SUBST(WIN32LDFLAGS)
 472 AC_SUBST(WIN32LIBADD)
 473
 474 # target stuff:
 475
 476 # Canonicalize the secondary target names.
 477 if test -n "$enable_targets" ; then
 478     for targ in `echo $enable_targets | sed 's/,/ /g'`
 479     do
 480         result=`$ac_config_sub $targ 2>/dev/null`
 481         if test -n "$result" ; then
 482             canon_targets="$canon_targets $result"
 483         else
 484             # Allow targets that config.sub doesn't recognize, like "all".
 485             canon_targets="$canon_targets $targ"
 486         fi
 487     done
 488 fi
 489
 490 all_targets=false
 491 defvec=
 492 selvecs=
 493 assocvecs=
 494 selarchs=
 495 TDEFINES=
 496 for targ in $target $canon_targets
 497 do
 498     if test "x$targ" = "xall"; then
 499         all_targets=true
 500         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 501     else
 502         . $srcdir/config.bfd
 503         if test "x$targ" = "x$target"; then
 504             defvec=$targ_defvec
 505         fi
 506         selvecs="$selvecs $targ_defvec $targ_selvecs"
 507         selarchs="$selarchs $targ_archs"
 508         TDEFINES="$TDEFINES $targ_cflags"
 509     fi
 510 done
 511 AC_SUBST(TDEFINES)
 512
 513 # This processing still needs to be done if we're to decide properly whether
 514 # 64-bit support needs to be compiled in.  Currently, it will be included if
 515 # the default or any other explicitly requested target requires it; it
 516 # will not be included on a 32-bit host if no 64-bit target is requested, and
 517 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 518 # used.
 519
 520 # uniq the default and selected vectors in all the configured targets.
 521 f=""
 522 for i in $selvecs ; do
 523     case " $f " in
 524     *" $i "*) ;;
 525     *) f="$f $i" ;;
 526     esac
 527 done
 528 selvecs="$f"
 529
 530
 531 # uniq the associated vectors in all the configured targets.
 532 f=""
 533 for i in $assocvecs ; do
 534     case " $f " in
 535     *" $i "*) ;;
 536     *) f="$f $i" ;;
 537     esac
 538 done
 539 assocvecs="$f"
 540
 541
 542 # uniq the architectures in all the configured targets.
 543 f=""
 544 for i in $selarchs ; do
 545     case " $f " in
 546     *" $i "*) ;;
 547     *) f="$f $i" ;;
 548     esac
 549 done
 550 selarchs="$f"
 551
 552 # Target backend .o files.
 553 tb=
 554
 555 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 556
 557 for vec in $selvecs
 558 do
 559     target_size=32
 560     case "$vec" in
 561     # This list is alphabetized to make it easy to compare
 562     # with the two vector lists in targets.c.  For the same reason,
 563     # use one entry per line, even though this leads to long lines.
 564     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 565     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 566     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 567     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 568     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 569     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 570     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 571     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 572     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 573     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 574     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 575     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 576     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 577     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 578     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 579     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 580     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 581     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 582     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 583     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 584     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 585     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 586     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 587     bfd_elf32_bfin_vec)         tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 588     bfd_elf32_bfinfdpic_vec)    tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 589     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 590     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 591     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 592     bfd_elf32_bigarm_symbian_vec)
 593                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 594     bfd_elf32_bigarm_vxworks_vec)
 595                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 596     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 597     bfd_elf32_bigmips_vxworks_vec)
 598                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 599     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 600     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 601     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 602     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 603     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 604     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 605     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 606     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 607     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 608     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 609     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 610     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 611     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 612     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 613     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 614     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 615     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 616     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 617     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 618     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 619     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 620     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 621     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 622     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 623     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 624     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 625     bfd_elf32_littlearm_symbian_vec)
 626                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 627     bfd_elf32_littlearm_vxworks_vec)
 628                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 629     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 630     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 631     bfd_elf32_littlemips_vxworks_vec)
 632                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 633     bfd_elf32_m32c_vec)         tb="$tb elf32-m32c.lo elf32.lo $elf" ;;
 634     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 635     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 636     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 637     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 638     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 639     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 640     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 641     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 642     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 643     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 644     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 645     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 646     bfd_elf32_mt_vec)           tb="$tb elf32-mt.lo elf32.lo $elf" ;;
 647     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 648     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 649     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 650     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 651     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 652     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 653     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 654     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 655     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 656     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 657     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 658     bfd_elf32_powerpc_vxworks_vec) tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 659     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 660     # FIXME: We include cofflink.lo not because it's needed for
 661     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 662     # which needs it but does not list it.  Should be fixed in right place.
 663     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 664     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 665     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 666     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 667     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 668     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 669     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 670     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 671     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 672     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 673     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 674     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 675     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 676     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 677     bfd_elf32_sparc_vxworks_vec) tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 678     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 679     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 680     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 681     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 682     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 683     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 684     bfd_elf32_xc16x_vec)                tb="$tb elf32-xc16x.lo elf32.lo $elf" ;;
 685     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 686     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 687     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 688     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 689     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 690     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 691     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 692     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 693     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 694     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 695     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 696     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 697     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 698     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 699     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 700     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 701     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 702     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 703     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 704     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 705     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 706     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 707     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 708     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf64.lo $elf"; target_size=64 ;;
 709     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 710     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 711     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 712     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 713     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 714     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 715     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 716     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 717     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 718     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 719     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 720     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 721     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 722     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 723     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 724     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 725     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 726     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 727     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 728     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 729     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 730     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 731     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 732     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 733     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 734     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 735     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 736     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 737     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 738     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 739     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 740     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 741     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 742     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 743     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 744     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 745     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 746     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 747     ieee_vec)                   tb="$tb ieee.lo" ;;
 748     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 749     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 750     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 751     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 752     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 753     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 754     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 755     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 756     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 757     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 758     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 759     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 760     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 761     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 762     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 763     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 764     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 765     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 766     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 767     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 768     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 769     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 770     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 771     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 772     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 773     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 774     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 775     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 776     pef_vec)                    tb="$tb pef.lo" ;;
 777     pef_xlib_vec)               tb="$tb pef.lo" ;;
 778     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 779     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 780     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 781     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 782     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 783     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 784     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 785     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 786     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 787     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 788     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 789     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 790     som_vec)                    tb="$tb som.lo" ;;
 791     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 792     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 793     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 794     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 795     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 796     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 797     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 798     sym_vec)                    tb="$tb xsym.lo" ;;
 799     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 800     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 801     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 802     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 803     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 804     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 805     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 806     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 807     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 808     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 809     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 810     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 811     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 812     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 813     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 814     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 815     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 816     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 817     versados_vec)               tb="$tb versados.lo" ;;
 818     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 819     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 820     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 821     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 822     z80coff_vec)                tb="$tb coff-z80.lo reloc16.lo" ;;
 823     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo cofflink.lo" ;;
 824
 825     # These appear out of order in targets.c
 826     srec_vec)                   tb="$tb srec.lo" ;;
 827     symbolsrec_vec)             tb="$tb srec.lo" ;;
 828     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 829     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 830     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 831
 832     "")                 ;;
 833     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 834     esac
 835
 836     if test ${target_size} = 64; then
 837         target64=true
 838     fi
 839     if test x"${vec}" = x"${defvec}"; then
 840         bfd_default_target_size=${target_size}
 841     fi
 842 done
 843
 844 # Target architecture .o files.
 845 # A couple of CPUs use shorter file names to avoid problems on DOS
 846 # filesystems.
 847 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 848
 849 # Weed out duplicate .o files.
 850 f=""
 851 for i in $tb ; do
 852     case " $f " in
 853     *" $i "*) ;;
 854     *) f="$f $i" ;;
 855     esac
 856 done
 857 tb="$f"
 858
 859 f=""
 860 for i in $ta ; do
 861     case " $f " in
 862     *" $i "*) ;;
 863     *) f="$f $i" ;;
 864     esac
 865 done
 866 ta="$f"
 867
 868 bfd_backends="$tb"
 869 bfd_machines="$ta"
 870
 871 if test x${all_targets} = xtrue ; then
 872   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 873   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 874   selvecs=
 875   havevecs=
 876   selarchs=
 877   test -n "$assocvecs" &&
 878     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 879 else    # all_targets is true
 880   # Only set these if they will be nonempty, for the clever echo.
 881   havevecs=
 882   assocvecs=
 883   test -n "$selvecs" &&
 884     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 885   test -n "$selvecs" &&
 886     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 887   test -n "$selarchs" &&
 888     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 889 fi      # all_targets is true
 890
 891 case ${host64}-${target64}-${want64} in
 892   *true*)
 893     wordsize=64
 894     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 895     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 896     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 897       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 898       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 899     fi
 900     if test -n "$GCC" ; then
 901        bad_64bit_gcc=no;
 902        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 903        # Add more tests for gcc versions with non-working 64-bit support here.
 904        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 905                     bad_64bit_gcc=yes;
 906                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 907                     AC_MSG_RESULT(no))
 908        if test $bad_64bit_gcc = yes ; then
 909          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 910        fi
 911     fi
 912     ;;
 913   false-false-false)
 914     wordsize=32
 915     bfd_libs='$(BFD32_LIBS)'
 916     all_backends='$(BFD32_BACKENDS)'
 917     ;;
 918 esac
 919
 920 AC_SUBST(wordsize)
 921 AC_SUBST(bfd_libs)
 922 AC_SUBST(all_backends)
 923 AC_SUBST(bfd_backends)
 924 AC_SUBST(bfd_machines)
 925 AC_SUBST(bfd_default_target_size)
 926
 927 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 928 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 929 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 930 # Hopefully a reasonable assumption since fseeko et.al. should be
 931 # upward compatible.
 932 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64 fopen64)
 933 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 934     AC_CHECK_SIZEOF(off_t)
 935 fi
 936 AC_MSG_CHECKING([file_ptr type])
 937 bfd_file_ptr="long"
 938 bfd_ufile_ptr="unsigned long"
 939 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 940         -o x"${ac_cv_sizeof_off_t}" = x8; then
 941     bfd_file_ptr=BFD_HOST_64_BIT
 942     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 943 fi
 944 AC_MSG_RESULT($bfd_file_ptr)
 945 AC_SUBST(bfd_file_ptr)
 946 AC_SUBST(bfd_ufile_ptr)
 947
 948
 949 tdefaults=""
 950 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 951 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 952 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 953 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 954 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 955 AC_SUBST(tdefaults)
 956
 957 dnl AC_CHECK_HEADERS(sys/mman.h)
 958 AC_FUNC_MMAP
 959 AC_CHECK_FUNCS(madvise mprotect)
 960 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 961   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 962 esac
 963
 964 rm -f doc/config.status
 965 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 966
 967 dnl We need this duplication, even though we use AM_PO_SUBDIRS, because of
 968 dnl our two separate POTFILES.  Yuck.
 969 AC_CONFIG_COMMANDS([default],
 970 [[
 971 case "$srcdir" in
 972   .) srcdirpre= ;;
 973   *) srcdirpre='$(srcdir)/' ;;
 974 esac
 975 POFILES=
 976 GMOFILES=
 977 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 978   if test $lang != dummy; then
 979     POFILES="$POFILES $srcdirpre$lang.po"
 980     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 981   fi
 982 done
 983 sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' \
 984     -e '/BLD-POTFILES =/r po/BLD-POTFILES' \
 985     -e "s,@POFILES@,$POFILES," \
 986     -e "s,@GMOFILES@,$GMOFILES," \
 987     po/Makefile.in > po/Makefile]],[[]])
 988
 989 dnl Required by html and install-html
 990 AC_SUBST(datarootdir)
 991 AC_SUBST(docdir)
 992 AC_SUBST(htmldir)
 993
 994 AC_OUTPUT
 995