binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_ENABLE(targets,
  17 [  --enable-targets        alternative target configurations],
  18 [case "${enableval}" in
  19   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  20             ;;
  21   no)       enable_targets= ;;
  22   *)        enable_targets=$enableval ;;
  23 esac])dnl
  24 AC_ARG_ENABLE(commonbfdlib,
  25 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  26 [case "${enableval}" in
  27   yes) commonbfdlib=true ;;
  28   no)  commonbfdlib=false ;;
  29   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  30 esac])dnl
  31
  32 AM_BINUTILS_WARNINGS
  33
  34 AM_CONFIG_HEADER(config.h:config.in)
  35
  36 if test -z "$target" ; then
  37     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  38 fi
  39 if test -z "$host" ; then
  40     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  41 fi
  42
  43 AC_PROG_CC
  44 AC_GNU_SOURCE
  45
  46 AC_PROG_YACC
  47 AM_PROG_LEX
  48
  49 ALL_LINGUAS="fr tr ja es sv da zh_CN ru ro rw zh_TW fi vi"
  50 ZW_GNU_GETTEXT_SISTER_DIR
  51 AM_PO_SUBDIRS
  52
  53 AM_MAINTAINER_MODE
  54 AC_EXEEXT
  55 if test -n "$EXEEXT"; then
  56   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  57             [Does the platform use an executable suffix?])
  58 fi
  59 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  60                    [Suffix used for executables, if any.])
  61
  62 # host-specific stuff:
  63
  64 HDEFINES=
  65
  66 . ${srcdir}/../bfd/configure.host
  67
  68 AC_SUBST(HDEFINES)
  69 AR=${AR-ar}
  70 AC_SUBST(AR)
  71 AC_PROG_RANLIB
  72 AC_PROG_INSTALL
  73
  74 BFD_CC_FOR_BUILD
  75
  76 DEMANGLER_NAME=c++filt
  77 case "${host}" in
  78   *-*-go32* | *-*-msdos*)
  79     DEMANGLER_NAME=cxxfilt
  80 esac
  81 AC_SUBST(DEMANGLER_NAME)
  82
  83 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h)
  84 AC_HEADER_SYS_WAIT
  85 AC_FUNC_ALLOCA
  86 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  87 AC_CHECK_FUNC([mkstemp],
  88               AC_DEFINE([HAVE_MKSTEMP], 1,
  89               [Define to 1 if you have the `mkstemp' function.]))
  90 AC_CHECK_FUNC([mkdtemp],
  91               AC_DEFINE([HAVE_MKDTEMP], 1,
  92               [Define to 1 if you have the `mkdtemp' function.]))
  93
  94 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  95 # needs to be defined for it
  96 AC_MSG_CHECKING([for fopen64])
  97 AC_CACHE_VAL(bu_cv_have_fopen64,
  98 [AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
  99 bu_cv_have_fopen64=yes,
 100 [saved_CPPFLAGS=$CPPFLAGS
 101  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 102  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
 103 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 104 bu_cv_have_fopen64=no)
 105  CPPFLAGS=$saved_CPPFLAGS])])
 106 AC_MSG_RESULT($bu_cv_have_fopen64)
 107 if test "$bu_cv_have_fopen64" != no; then
 108   AC_DEFINE([HAVE_FOPEN64], 1,
 109             [Is fopen64 available?])
 110 fi
 111 AC_MSG_CHECKING([for stat64])
 112 AC_CACHE_VAL(bu_cv_have_stat64,
 113 [AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 114 bu_cv_have_stat64=yes,
 115 [saved_CPPFLAGS=$CPPFLAGS
 116  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 117  AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 118 bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 119 bu_cv_have_stat64=no)
 120  CPPFLAGS=$saved_CPPFLAGS])])
 121 AC_MSG_RESULT($bu_cv_have_stat64)
 122 if test "$bu_cv_have_stat64" != no; then
 123   AC_DEFINE([HAVE_STAT64], 1,
 124             [Is stat64 available?])
 125 fi
 126 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 127    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 128   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 129             [Enable LFS])
 130   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 131 fi
 132
 133 # Some systems have frexp only in -lm, not in -lc.
 134 AC_SEARCH_LIBS(frexp, m)
 135
 136 AC_MSG_CHECKING(for time_t in time.h)
 137 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 138 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
 139 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 140 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 141 if test $bu_cv_decl_time_t_time_h = yes; then
 142   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 143             [Is the type time_t defined in <time.h>?])
 144 fi
 145
 146 AC_MSG_CHECKING(for time_t in sys/types.h)
 147 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 148 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
 149 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 150 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 151 if test $bu_cv_decl_time_t_types_h = yes; then
 152   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 153             [Is the type time_t defined in <sys/types.h>?])
 154 fi
 155
 156 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 157 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 158 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 159 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 160 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 161 if test $bu_cv_decl_getopt_unistd_h = yes; then
 162   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 163             [Is the prototype for getopt in <unistd.h> in the expected format?])
 164 fi
 165
 166 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 167 # by default.
 168 AC_MSG_CHECKING([for utime.h])
 169 AC_CACHE_VAL(bu_cv_header_utime_h,
 170 [AC_TRY_COMPILE([#include <sys/types.h>
 171 #ifdef HAVE_TIME_H
 172 #include <time.h>
 173 #endif
 174 #include <utime.h>],
 175 [struct utimbuf s;],
 176 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 177 AC_MSG_RESULT($bu_cv_header_utime_h)
 178 if test $bu_cv_header_utime_h = yes; then
 179   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 180 fi
 181
 182 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 183                 snprintf, vsnprintf])
 184
 185 BFD_BINARY_FOPEN
 186
 187 # target-specific stuff:
 188
 189 # Canonicalize the secondary target names.
 190 if test -n "$enable_targets"; then
 191     for targ in `echo $enable_targets | sed 's/,/ /g'`
 192     do
 193         result=`$ac_config_sub $targ 2>/dev/null`
 194         if test -n "$result"; then
 195             canon_targets="$canon_targets $result"
 196         else
 197             # Allow targets that config.sub doesn't recognize, like "all".
 198             canon_targets="$canon_targets $targ"
 199         fi
 200     done
 201 fi
 202
 203 all_targets=false
 204 BUILD_NLMCONV=
 205 NLMCONV_DEFS=
 206 BUILD_SRCONV=
 207 BUILD_DLLTOOL=
 208 DLLTOOL_DEFS=
 209 BUILD_WINDRES=
 210 BUILD_DLLWRAP=
 211 BUILD_MISC=
 212 OBJDUMP_DEFS=
 213
 214 for targ in $target $canon_targets
 215 do
 216     if test "x$targ" = "xall"; then
 217         all_targets=true
 218         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 219         BUILD_SRCONV='$(SRCONV_PROG)'
 220         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 221     else
 222         case $targ in
 223 changequote(,)dnl
 224         i[3-7]86*-*-netware*)
 225 changequote([,])dnl
 226           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 227           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 228           ;;
 229         alpha*-*-netware*)
 230           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 231           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 232           ;;
 233         powerpc*-*-netware*)
 234           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 235           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 236           ;;
 237         sparc*-*-netware*)
 238           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 239           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 240           ;;
 241         esac
 242         case $targ in
 243         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 244         esac
 245         case $targ in
 246         arm-epoc-pe*)
 247           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 248           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 249           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 250           ;;
 251         arm-wince-pe* | arm-*-wince)
 252           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 253           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 254           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 255           ;;
 256         arm-*-pe*)
 257           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 258           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 259           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 260           ;;
 261         thumb-*-pe*)
 262           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 263           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 264           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 265           ;;
 266         x86_64-*-mingw64*)
 267           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 268           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 269           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 270           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 271           ;;
 272 changequote(,)dnl
 273         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 274 changequote([,])dnl
 275           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 276           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 277           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 278           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 279           ;;
 280 changequote(,)dnl
 281         i[3-7]86-*-interix)
 282 changequote([,])dnl
 283           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 284           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 285           ;;
 286 changequote(,)dnl
 287         powerpc*-aix5.[01])
 288 changequote([,])dnl
 289           ;;
 290         powerpc*-aix5.*)
 291           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 292           ;;
 293         powerpc*-*-pe* | powerpc*-*-cygwin*)
 294           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 295           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 296           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 297           ;;
 298         sh*-*-pe)
 299           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 300           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 301           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 302           ;;
 303         mips*-*-pe)
 304           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 305           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 306           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 307           ;;
 308         mcore-*-pe)
 309           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 310           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 311           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 312           ;;
 313         mcore-*-elf)
 314           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 315           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 316           ;;
 317         esac
 318     fi
 319 done
 320
 321 if test "${with_windres+set}" = set; then
 322           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 323 fi
 324
 325 AC_SUBST(NLMCONV_DEFS)
 326 AC_SUBST(BUILD_NLMCONV)
 327 AC_SUBST(BUILD_SRCONV)
 328 AC_SUBST(BUILD_DLLTOOL)
 329 AC_SUBST(DLLTOOL_DEFS)
 330 AC_SUBST(BUILD_WINDRES)
 331 AC_SUBST(BUILD_DLLWRAP)
 332 AC_SUBST(BUILD_MISC)
 333 AC_SUBST(OBJDUMP_DEFS)
 334
 335 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 336
 337 targ=$target
 338 . $srcdir/../bfd/config.bfd
 339 if test "x$targ_underscore" = "xyes"; then
 340     UNDERSCORE=1
 341 else
 342     UNDERSCORE=0
 343 fi
 344 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 345  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 346
 347 # Emulation
 348 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 349 do
 350   # Canonicalize the secondary target names.
 351  result=`$ac_config_sub $targ_alias 2>/dev/null`
 352  if test -n "$result"; then
 353    targ=$result
 354  else
 355    targ=$targ_alias
 356  fi
 357
 358  . ${srcdir}/configure.tgt
 359
 360   EMULATION=$targ_emul
 361   EMULATION_VECTOR=$targ_emul_vector
 362 done
 363
 364 AC_SUBST(EMULATION)
 365 AC_SUBST(EMULATION_VECTOR)
 366
 367 # Required for html and install-html
 368 AC_SUBST(datarootdir)
 369 AC_SUBST(docdir)
 370 AC_SUBST(htmldir)
 371
 372 AC_OUTPUT(Makefile doc/Makefile po/Makefile.in:po/Make-in)