gprof/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.13)
   3 AC_INIT(gprof.c)
   4
   5 AC_CANONICAL_SYSTEM
   6
   7 AM_INIT_AUTOMAKE(gprof, 2.9.5)
   8
   9 AM_PROG_LIBTOOL
  10
  11 dnl For simplicity, we use the BFD configuration file for most
  12 dnl things.  However, we also need our own configuration file for
  13 dnl the automake PACKAGE and VERSION macros.  We don't name it
  14 dnl config.h, to avoid any possible confusion with the bfd config.h.
  15 AM_CONFIG_HEADER(gconfig.h:gconfig.in)
  16
  17 AC_PROG_CC
  18 AC_PROG_INSTALL
  19
  20 AC_ISC_POSIX
  21 AC_CHECK_FUNCS(setmode)
  22
  23 ALL_LINGUAS=
  24 CY_GNU_GETTEXT
  25
  26 AM_MAINTAINER_MODE
  27 AC_EXEEXT
  28
  29 build_warnings="-W -Wall"
  30 AC_ARG_ENABLE(build-warnings,
  31 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  32 [case "${enableval}" in
  33   yes)  ;;
  34   no)   build_warnings="-w";;
  35   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  36         build_warnings="${build_warnings} ${t}";;
  37   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  38         build_warnings="${t} ${build_warnings}";;
  39   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  40 esac
  41 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  42   echo "Setting warning flags = $build_warnings" 6>&1
  43 fi])dnl
  44 WARN_CFLAGS=""
  45 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  46     WARN_CFLAGS="${build_warnings}"
  47 fi
  48 AC_SUBST(WARN_CFLAGS)
  49
  50 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
  51 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])