gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       ip2k)             cpu_type=ip2k endian=big ;;
 132       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 133       m680[012346]0)    cpu_type=m68k ;;
 134 changequote([,])dnl
 135       m68008)           cpu_type=m68k ;;
 136       m683??)           cpu_type=m68k ;;
 137       m5200)            cpu_type=m68k ;;
 138       m8*)              cpu_type=m88k ;;
 139       mips*el)          cpu_type=mips endian=little ;;
 140       mips*)            cpu_type=mips endian=big ;;
 141       or32*)            cpu_type=or32 endian=big ;;
 142       pjl*)             cpu_type=pj endian=little ;;
 143       pj*)              cpu_type=pj endian=big ;;
 144       powerpc*le*)      cpu_type=ppc endian=little ;;
 145       powerpc*)         cpu_type=ppc endian=big ;;
 146       rs6000*)          cpu_type=ppc ;;
 147       s390x*)           cpu_type=s390 arch=s390x ;;
 148       s390*)            cpu_type=s390 arch=s390 ;;
 149       sh5*)             cpu_type=sh64 endian=big ;;
 150       sh5le*)           cpu_type=sh64 endian=little ;;
 151       sh64*)            cpu_type=sh64 endian=big ;;
 152       sh64le*)          cpu_type=sh64 endian=little ;;
 153       sh*le)            cpu_type=sh endian=little ;;
 154       sh*)              cpu_type=sh endian=big ;;
 155       sparclite*)       cpu_type=sparc arch=sparclite ;;
 156       sparclet*)        cpu_type=sparc arch=sparclet ;;
 157       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 158       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 159       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 160       v850*)            cpu_type=v850 ;;
 161       *)                cpu_type=${cpu} ;;
 162     esac
 163
 164     if test ${this_target} = $target ; then
 165       target_cpu_type=${cpu_type}
 166     elif test ${target_cpu_type} != ${cpu_type} ; then
 167       continue
 168     fi
 169
 170     generic_target=${cpu_type}-$vendor-$os
 171     dev=no
 172     bfd_gas=no
 173     em=generic
 174
 175     # assign object format
 176     case ${generic_target} in
 177       a29k-*-coff)                      fmt=coff ;;
 178       a29k-amd-udi)                     fmt=coff ;;
 179       a29k-amd-ebmon)                   fmt=coff ;;
 180       a29k-nyu-sym1)                    fmt=coff ;;
 181       a29k-*-rtems*)                    fmt=coff ;;
 182       a29k-*-vxworks*)                  fmt=coff ;;
 183
 184       alpha*-*-*vms*)                   fmt=evax ;;
 185       alpha*-*-netware*)                fmt=ecoff ;;
 186       alpha*-*-osf*)                    fmt=ecoff ;;
 187       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 188       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 189       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 190       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 191
 192       arc-*-elf*)                       fmt=elf ;;
 193
 194       arm-*-aout)                       fmt=aout ;;
 195       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 196       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 197       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 198       arm*-*-conix*)                    fmt=elf ;;
 199       arm-*-linux*aout*)                fmt=aout em=linux ;;
 200       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 201       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 202       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 203       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 204       arm-**-nto*)                      fmt=elf ;;
 205       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 206       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 207       arm-*-wince)                      fmt=coff em=wince-pe ;;
 208       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 209       arm-*-riscix*)                    fmt=aout em=riscix ;;
 210       arm-*-vxworks)                    fmt=coff ;;
 211
 212       avr-*-*)                          fmt=elf ;;
 213
 214       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 215
 216       d10v-*-*)                         fmt=elf ;;
 217       d30v-*-*)                         fmt=elf ;;
 218       dlx-*-*)                          fmt=elf ;;
 219
 220       fr30-*-*)                         fmt=elf ;;
 221       frv-*-*)                          fmt=elf ;;
 222
 223       hppa-*-linux*)    case ${cpu} in
 224                             hppa*64*)   fmt=elf em=hppalinux64;;
 225                             hppa*)      fmt=elf em=linux;;
 226                         esac ;;
 227       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 228       hppa-*-lites*)                    fmt=elf em=hppa ;;
 229       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 230       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 231       hppa-*-osf*)                      fmt=som em=hppa ;;
 232       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 233       hppa-*-hpux11*)   case ${cpu} in
 234                             hppa*64*)   fmt=elf em=hppa64 ;;
 235                             hppa*)      fmt=som em=hppa ;;
 236                         esac ;;
 237       hppa-*-hpux*)                     fmt=som em=hppa ;;
 238       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 239       hppa-*-bsd*)                      fmt=som em=hppa ;;
 240       hppa-*-hiux*)                     fmt=som em=hppa ;;
 241
 242       h8300-*-rtems*)                   fmt=coff ;;
 243       h8300-*-coff)                     fmt=coff ;;
 244       h8300-*-elf)                      fmt=elf ;;
 245       h8500-*-rtems*)                   fmt=coff ;;
 246       h8500-*-coff)                     fmt=coff ;;
 247
 248       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 249       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 250       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 251       i386-*-beospe*)                   fmt=coff em=pe ;;
 252       i386-*-beos*)                     fmt=elf ;;
 253       i386-*-coff)                      fmt=coff ;;
 254       i386-*-elf)                       fmt=elf ;;
 255       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 256       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 257       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 258       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 259       i386-*-*n*bsd*)   case ${cpu} in
 260                             x86_64)     fmt=elf em=nbsd ;;
 261                             *)          fmt=aout em=nbsd ;;
 262                         esac ;;
 263       i386-*-linux*aout*)               fmt=aout em=linux ;;
 264       i386-*-linux*oldld)               fmt=aout em=linux ;;
 265       i386-*-linux*coff*)               fmt=coff em=linux ;;
 266       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 267       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 268       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 269 changequote(,)dnl
 270       i386-*-sysv[45]*)                 fmt=elf ;;
 271       i386-*-solaris*)                  fmt=elf ;;
 272       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 273       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 274       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 275 changequote([,])dnl
 276       i386-*-sysv*)                     fmt=coff ;;
 277       i386-*-sco3.2v5*coff)             fmt=coff ;;
 278       i386-*-isc*)                      fmt=coff ;;
 279       i386-*-sco3.2v5*)                 fmt=elf
 280           if test ${this_target} = $target; then
 281             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 282           fi ;;
 283       i386-*-sco3.2*)                   fmt=coff ;;
 284       i386-*-vsta)                      fmt=aout ;;
 285       i386-*-msdosdjgpp* \
 286       | i386-*-go32* \
 287       | i386-go32-rtems*)               fmt=coff em=go32
 288             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 289       i386-*-rtemself*)                 fmt=elf ;;
 290       i386-*-rtemscoff*)                fmt=coff ;;
 291       i386-*-rtems*)                    fmt=elf ;;
 292       i386-*-gnu*)                      fmt=elf ;;
 293       i386-*-mach*)                     fmt=aout em=mach ;;
 294       i386-*-msdos*)                    fmt=aout ;;
 295       i386-*-moss*)                     fmt=elf ;;
 296       i386-*-pe)                        fmt=coff em=pe ;;
 297       i386-*-cygwin*)                   fmt=coff em=pe ;;
 298       i386-*-interix*)                  fmt=coff em=interix ;;
 299       i386-*-mingw32*)                  fmt=coff em=pe ;;
 300       i386-*-nto-qnx*)                  fmt=elf ;;
 301       i386-*-*nt*)                      fmt=coff em=pe ;;
 302       i386-*-vxworks*)                  fmt=aout ;;
 303       i386-*-chaos)                     fmt=elf ;;
 304
 305       i860-*-*)                         fmt=elf endian=little
 306                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 307       i960-*-bout)                      fmt=bout ;;
 308       i960-*-coff)                      fmt=coff em=ic960 ;;
 309       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 310       i960-*-nindy*)                    fmt=bout ;;
 311       i960-*-vxworks5.0)                fmt=bout ;;
 312       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 313       i960-*-vxworks*)                  fmt=bout ;;
 314       i960-*-elf*)                      fmt=elf ;;
 315
 316       ia64-*-elf*)                      fmt=elf ;;
 317       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 318       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 319       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 320       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 321
 322       ip2k-*-*)                         fmt=elf ;;
 323
 324       m32r-*-*)                         fmt=elf ;;
 325
 326       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 327       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 328
 329       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 330       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 331       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 332       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 333       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 334       m68k-apollo-*)                    fmt=coff em=apollo ;;
 335       m68k-*-elf*)                      fmt=elf ;;
 336       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 337       m68k-*-sysv*)                     fmt=coff ;;
 338       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 339       m68k-*-rtems*)                    fmt=elf ;;
 340       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 341       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 342       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 343       m68k-*-gnu*)                      fmt=elf ;;
 344       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 345       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 346       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 347       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 348       m68k-apple-aux*)                  fmt=coff em=aux ;;
 349       m68k-*-psos*)                     fmt=elf em=psos;;
 350
 351       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 352       m88k-*-coff*)                     fmt=coff ;;
 353
 354       mcore-*-elf)                      fmt=elf ;;
 355       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 356
 357       # don't change em like *-*-bsd does
 358       mips-dec-openbsd*)                fmt=elf endian=little ;;
 359       mips-dec-bsd*)                    fmt=aout endian=little ;;
 360       mips-sony-bsd*)                   fmt=ecoff ;;
 361       mips-*-bsd*)
 362             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 363       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 364       mips-*-osf*)                      fmt=ecoff endian=little ;;
 365       mips-*-ecoff*)                    fmt=ecoff ;;
 366       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 367       mips-*-irix6*)                    fmt=elf ;;
 368       mips-*-irix5*)                    fmt=elf ;;
 369       mips-*-irix*)                     fmt=ecoff ;;
 370       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 371       mips-*-riscos*)                   fmt=ecoff ;;
 372       mips*-*-linux*)                   fmt=elf em=tmips ;;
 373       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 374       mips-*-sysv*)                     fmt=ecoff ;;
 375       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 376       mips-*-*n*bsd*)                   fmt=elf ;;
 377       mips-*-vxworks*)                  fmt=elf ;;
 378
 379       mmix-*-*)                         fmt=elf ;;
 380       mn10200-*-*)                      fmt=elf ;;
 381       mn10300-*-*)                      fmt=elf ;;
 382       openrisc-*-*)                     fmt=elf ;;
 383       or32-*-rtems*)                    fmt=coff ;;
 384       or32-*-coff)                      fmt=coff ;;
 385       or32-*-elf)                       fmt=elf ;;
 386       pj*)                              fmt=elf ;;
 387
 388       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 389       ppc-*-winnt*)                     fmt=coff em=pe ;;
 390       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 391       ppc-*-aix*)                       fmt=coff ;;
 392       ppc-*-beos*)                      fmt=coff ;;
 393       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 394       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 395       ppc-*-linux-gnu*)                 fmt=elf
 396             case "$endian" in
 397                 big)  ;;
 398                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 399             esac ;;
 400       ppc-*-solaris*)                   fmt=elf
 401             if test ${this_target} = $target; then
 402                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 403                           [Define if default target is PowerPC Solaris.])
 404             fi
 405             if test x${endian} = xbig; then
 406                 AC_MSG_ERROR(Solaris must be configured little endian)
 407             fi ;;
 408       ppc-*-rtems*)                     fmt=elf ;;
 409       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 410       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 411       ppc-**-nto*)                      fmt=elf ;;
 412       ppc-*-vxworks*)                   fmt=elf ;;
 413       ppc-*-windiss*)                   fmt=elf ;;
 414
 415       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 416       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 417
 418       sh*-*-linux*)                     fmt=elf em=linux
 419             case ${cpu} in
 420                 sh*eb)  endian=big ;;
 421                 *)      endian=little ;;
 422             esac ;;
 423       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 424       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 425       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 426       sh-*-elf*)                        fmt=elf ;;
 427       sh-*-coff*)                       fmt=coff ;;
 428       sh-*-nto*)                        fmt=elf ;;
 429       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 430       sh-*-rtemself*)                   fmt=elf ;;
 431       sh-*-rtems*)                      fmt=coff ;;
 432       sh64-*-elf*)                      fmt=elf ;;
 433
 434       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 435       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 436       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 437       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 438
 439       sparc-*-rtemsaout*)               fmt=aout ;;
 440       sparc-*-rtemself*)                fmt=elf ;;
 441       sparc-*-rtems*)                   fmt=elf ;;
 442       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 443       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 444       sparc-*-coff)                     fmt=coff ;;
 445       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 446       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 447       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 448       sparc-fujitsu-none)               fmt=aout ;;
 449       sparc-*-elf)                      fmt=elf ;;
 450       sparc-*-sysv4*)                   fmt=elf ;;
 451       sparc-*-solaris*)                 fmt=elf ;;
 452       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 453       sparc-*-*n*bsd*)  case ${cpu} in
 454                             sparc64)    fmt=elf em=nbsd ;;
 455                             *)          fmt=aout em=nbsd ;;
 456                         esac ;;
 457       strongarm-*-coff)                 fmt=coff ;;
 458       strongarm-*-elf)                  fmt=elf ;;
 459       xscale-*-coff)                    fmt=coff ;;
 460       xscale-*-elf)                     fmt=elf ;;
 461
 462       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 463       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 464       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 465       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 466       tic80-*-*)                        fmt=coff ;;
 467
 468       v850-*-*)                         fmt=elf ;;
 469       v850e-*-*)                        fmt=elf ;;
 470       v850ea-*-*)                       fmt=elf ;;
 471
 472       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 473       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 474       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 475       vax-*-vms)                        fmt=vms ;;
 476
 477       w65-*-*)                          fmt=coff ;;
 478
 479       xstormy16-*-*)                    fmt=elf ;;
 480
 481       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 482
 483       *-*-aout | *-*-scout)             fmt=aout ;;
 484       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 485       *-*-nindy*)                       fmt=bout ;;
 486       *-*-bsd*)                         fmt=aout em=sun3 ;;
 487       *-*-generic)                      fmt=generic ;;
 488       *-*-xray | *-*-hms)               fmt=coff ;;
 489       *-*-sim)                          fmt=coff ;;
 490       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 491       *-*-vxworks)                      fmt=aout ;;
 492       *-*-netware)                      fmt=elf ;;
 493     esac
 494
 495     if test ${this_target} = $target ; then
 496       endian_def=
 497       if test x${endian} = xbig; then
 498         endian_def=1
 499       elif test x${endian} = xlittle; then
 500         endian_def=0
 501       fi
 502       if test x${endian_def} != x; then
 503         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 504                            [Define as 1 if big endian.])
 505       fi
 506     fi
 507
 508     case ${cpu_type}-${fmt} in
 509         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 510                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 511                 | *-elf | *-ecoff | *-som)
 512             bfd_gas=yes ;;
 513     esac
 514
 515 # Other random stuff.
 516
 517     case ${cpu_type} in
 518       mips)
 519         # Set mips_cpu to the name of the default CPU.
 520         case ${target_cpu} in
 521           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 522             mips_cpu=from-abi
 523             ;;
 524           mipsisa32 | mipsisa32el)
 525             mips_cpu=mips32
 526             ;;
 527           mipsisa64 | mipsisa64el)
 528             mips_cpu=mips64
 529             ;;
 530           mipstx39 | mipstx39el)
 531             mips_cpu=r3900
 532             ;;
 533           mips64vr | mips64vrel)
 534             mips_cpu=vr4100
 535             ;;
 536           mips64* | mipsisa64* | mipsisa32*)
 537 changequote(,)dnl
 538             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 539 changequote([,])dnl
 540             ;;
 541           *)
 542             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 543             ;;
 544         esac
 545         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 546         # binaries.  It's a GNU extension that some OSes don't understand.
 547         # The value only matters on ELF targets.
 548         case ${target} in
 549           *-*-irix*)
 550             use_e_mips_abi_o32=0
 551             ;;
 552           *)
 553             use_e_mips_abi_o32=1
 554             ;;
 555         esac
 556         # Decide whether to generate 32-bit or 64-bit code by default.
 557         # Used to resolve -march=from-abi when an embedded ABI is selected.
 558         case ${target} in
 559           mips64*-*-* | mipsisa64*-*-*)
 560             mips_default_64bit=1
 561             ;;
 562           *)
 563             mips_default_64bit=0
 564             ;;
 565         esac
 566         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 567                            [Default CPU for MIPS targets. ])
 568         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 569                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 570         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 571                            [Generate 64-bit code by default on MIPS targets. ])
 572         ;;
 573     esac
 574
 575     # Do we need the opcodes library?
 576     case ${cpu_type} in
 577       vax | i386 | tic30)
 578         ;;
 579
 580       *)
 581         need_opcodes=yes
 582
 583         case "${enable_shared}" in
 584         yes) shared_opcodes=true ;;
 585         *opcodes*) shared_opcodes=true ;;
 586         *) shared_opcodes=false ;;
 587         esac
 588         if test "${shared_opcodes}" = "true"; then
 589           # A shared libopcodes must be linked against libbfd.
 590           need_bfd=yes
 591         fi
 592         ;;
 593     esac
 594
 595     # Any other special object files needed ?
 596     case ${cpu_type} in
 597       fr30 | ip2k | m32r | openrisc)
 598         using_cgen=yes
 599         ;;
 600
 601       frv)
 602         using_cgen=yes
 603         ;;
 604       m68k)
 605         case ${extra_objects} in
 606         *m68k-parse.o*) ;;
 607         *) extra_objects="$extra_objects m68k-parse.o" ;;
 608         esac
 609         ;;
 610
 611       mips)
 612         echo ${extra_objects} | grep -s "itbl-parse.o"
 613         if test $? -ne 0 ; then
 614           extra_objects="$extra_objects itbl-parse.o"
 615         fi
 616
 617         echo ${extra_objects} | grep -s "itbl-lex.o"
 618         if test $? -ne 0 ; then
 619           extra_objects="$extra_objects itbl-lex.o"
 620         fi
 621
 622         echo ${extra_objects} | grep -s "itbl-ops.o"
 623         if test $? -ne 0 ; then
 624           extra_objects="$extra_objects itbl-ops.o"
 625         fi
 626         ;;
 627
 628       i386 | s390 | sparc)
 629         if test $this_target = $target ; then
 630           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 631         fi
 632         ;;
 633
 634       xstormy16)
 635         using_cgen=yes
 636         ;;
 637
 638       *)
 639         ;;
 640     esac
 641
 642     if test $using_cgen = yes ; then
 643         case "x${extra_objects}" in
 644         *cgen.o*) ;;
 645         *) extra_objects="$extra_objects cgen.o" ;;
 646         esac
 647     fi
 648
 649 # See if we really can support this configuration with the emulation code.
 650
 651     if test $this_target = $target ; then
 652       primary_bfd_gas=$bfd_gas
 653       obj_format=$fmt
 654       te_file=$em
 655
 656       if test $bfd_gas = no ; then
 657         # Can't support other configurations this way.
 658         break
 659       fi
 660     elif test $bfd_gas = no ; then
 661       # Can't support this configuration.
 662       break
 663     fi
 664
 665 # From target name and format, produce a list of supported emulations.
 666
 667     case ${generic_target}-${fmt} in
 668       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 669       mips*-*-linux*-*) case "$endian" in
 670                         big)    emulation="mipsbelf mipslelf mipself" ;;
 671                         *)      emulation="mipslelf mipsbelf mipself" ;;
 672                         esac ;;
 673       mips-*-lnews*-ecoff) ;;
 674       mips-*-*-ecoff)   case "$endian" in
 675                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 676                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 677                         esac ;;
 678       mips-*-*-elf)     case "$endian" in
 679                         big)    emulation="mipsbelf mipslelf mipself" ;;
 680                         *)      emulation="mipslelf mipsbelf mipself" ;;
 681                         esac ;;
 682       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 683       # i386-pc-pe-coff != i386-pc-coff.
 684       i386-*-pe-coff)   ;;
 685       # Uncommenting the next line will turn on support for i386 AOUT
 686       # for the default linux configuration
 687       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 688       #
 689       i386-*-aout)      emulation="i386aout" ;;
 690       i386-*-coff)      emulation="i386coff" ;;
 691       i386-*-elf)       emulation="i386elf" ;;
 692
 693       # Always all formats.  The first stated emulation becomes the default.
 694       cris-*-*aout*)    emulation="crisaout criself" ;;
 695       cris-*-*)         emulation="criself crisaout" ;;
 696     esac
 697
 698     emulations="$emulations $emulation"
 699
 700 done
 701
 702 # Turn on all targets if possible
 703 if test ${all_targets} = "yes"; then
 704   case ${target_cpu_type} in
 705   i386)
 706     case ${obj_format} in
 707     aout)
 708       emulations="$emulations i386coff i386elf"
 709       ;;
 710     coff)
 711       emulations="$emulations i386aout i386elf"
 712     ;;
 713     elf)
 714       emulations="$emulations i386aout i386coff"
 715       ;;
 716     esac
 717   ;;
 718   esac
 719 fi
 720
 721 # Assign floating point type.  Most processors with FP support
 722 # IEEE FP.  On those that don't support FP at all, usually IEEE
 723 # is emulated.
 724 case ${target_cpu} in
 725   vax | tahoe ) atof=${target_cpu} ;;
 726   pdp11)        atof=vax ;;
 727   *)            atof=ieee ;;
 728 esac
 729
 730 case "${obj_format}" in
 731   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 732 esac
 733
 734 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 735 cgen_cpu_prefix=""
 736 if test $using_cgen = yes ; then
 737   case ${target_cpu} in
 738     *) cgen_cpu_prefix=${target_cpu} ;;
 739   esac
 740   AC_SUBST(cgen_cpu_prefix)
 741   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 742 fi
 743
 744 dnl
 745 dnl Make sure the desired support files exist.
 746 dnl
 747
 748 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 749   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 750 fi
 751
 752 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 753   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 754 fi
 755
 756 case ${user_bfd_gas}-${primary_bfd_gas} in
 757   yes-yes | no-no)
 758     # We didn't override user's choice.
 759     ;;
 760   no-yes)
 761     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 762     ;;
 763   no-preferred)
 764     primary_bfd_gas=no
 765     ;;
 766   *-preferred)
 767     primary_bfd_gas=yes
 768     ;;
 769   yes-*)
 770     primary_bfd_gas=yes
 771     ;;
 772   -*)
 773     # User specified nothing.
 774     ;;
 775 esac
 776
 777 # Some COFF configurations want these random other flags set.
 778 case ${obj_format} in
 779   coff)
 780     case ${target_cpu_type} in
 781       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 782       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 783       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 784     esac
 785     ;;
 786 esac
 787
 788 # Getting this done right is going to be a bitch.  Each configuration specified
 789 # with --enable-targets=... should be checked for environment, format, cpu, and
 790 # bfd_gas setting.
 791 #
 792 # For each configuration, the necessary object file support code must be linked
 793 # in.  This might be only one, it might be up to four.  The necessary emulation
 794 # code needs to be provided, too.
 795 #
 796 # And then there's "--enable-targets=all"....
 797 #
 798 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 799
 800 formats="${obj_format}"
 801 emfiles=""
 802 EMULATIONS=""
 803 GAS_UNIQ(emulations)
 804 for em in . $emulations ; do
 805   case $em in
 806     .)  continue ;;
 807     mipsbelf | mipslelf | mipself)
 808         fmt=elf   file=mipself ;;
 809     mipsbecoff | mipslecoff | mipsecoff)
 810         fmt=ecoff file=mipsecoff ;;
 811     *coff)
 812         fmt=coff  file=$em ;;
 813     *aout)
 814         fmt=aout file=$em ;;
 815     *elf)
 816         fmt=elf file=$em ;;
 817   esac
 818   formats="$formats $fmt"
 819   emfiles="$emfiles e-$file.o"
 820   EMULATIONS="$EMULATIONS &$em,"
 821 done
 822 GAS_UNIQ(formats)
 823 GAS_UNIQ(emfiles)
 824 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 825   for fmt in $formats ; do
 826     case $fmt in
 827       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 828       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 829       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 830       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 831       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 832       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 833       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 834       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 835       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 836       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 837     esac
 838     extra_objects="$extra_objects obj-$fmt.o"
 839   done
 840   obj_format=multi
 841 fi
 842 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 843   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 844   # e-mips* has more than one emulation per file, e-i386* has just one at the
 845   # moment.  If only one emulation is specified, then don't define
 846   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 847   case "${obj_format}${emfiles}" in
 848     multi* | *mips*)
 849       extra_objects="$extra_objects $emfiles"
 850       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 851   esac
 852 fi
 853 AC_SUBST(extra_objects)
 854 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 855 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 856                    [Default emulation.])
 857
 858 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 859   yes-*-coff)   need_bfd=yes ;;
 860   no-*-coff)    need_bfd=yes
 861                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 862 esac
 863
 864 reject_dev_configs=yes
 865
 866 case ${reject_dev_configs}-${dev} in
 867   yes-yes) # Oops.
 868     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 869     ;;
 870 esac
 871
 872 AC_SUBST(target_cpu_type)
 873 AC_SUBST(obj_format)
 874 AC_SUBST(te_file)
 875 AC_SUBST(install_tooldir)
 876 AC_SUBST(atof)
 877 dnl AC_SUBST(emulation)
 878
 879 case "${primary_bfd_gas}" in
 880   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 881         need_bfd=yes ;;
 882 esac
 883
 884 # do we need the opcodes library?
 885 case "${need_opcodes}" in
 886 yes)
 887   OPCODES_LIB=../opcodes/libopcodes.la
 888   ;;
 889 esac
 890
 891 case "${need_bfd}" in
 892 yes)
 893   BFDLIB=../bfd/libbfd.la
 894   BFDVER_H=../bfd/bfdver.h
 895   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 896   ;;
 897 esac
 898
 899 AC_SUBST(BFDLIB)
 900 AC_SUBST(OPCODES_LIB)
 901
 902 AC_SUBST(BFDVER_H)
 903 AC_SUBST(ALL_OBJ_DEPS)
 904
 905 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 906 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 907 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 908 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 909 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 910
 911 AC_PROG_CC
 912
 913 AC_PROG_YACC
 914 AM_PROG_LEX
 915
 916 ALL_LINGUAS="fr tr es"
 917 CY_GNU_GETTEXT
 918
 919 AM_MAINTAINER_MODE
 920 AC_EXEEXT
 921
 922 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 923
 924 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 925 # people who are not cross-compiling but are compiling cross-assemblers.
 926 AC_MSG_CHECKING(whether compiling a cross-assembler)
 927 if test "${host}" = "${target}"; then
 928   cross_gas=no
 929 else
 930   cross_gas=yes
 931   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 932 fi
 933 AC_MSG_RESULT($cross_gas)
 934
 935 dnl ansidecl.h will deal with const
 936 dnl AC_CONST
 937 AC_FUNC_ALLOCA
 938 AC_C_INLINE
 939
 940 # VMS doesn't have unlink.
 941 AC_CHECK_FUNCS(unlink remove, break)
 942
 943 # Some systems don't have sbrk().
 944 AC_CHECK_FUNCS(sbrk)
 945
 946 # do we need the math library?
 947 case "${need_libm}" in
 948 yes)
 949   AC_CHECK_LIBM
 950   AC_SUBST(LIBM)
 951   ;;
 952 esac
 953
 954 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 955 # enough, but on some of those systems, the assert macro relies on requoting
 956 # working properly!
 957 GAS_WORKING_ASSERT
 958
 959 # On some systems, the system header files may not declare malloc, realloc,
 960 # and free.  There are places where gas needs these functions to have been
 961 # declared -- such as when taking their addresses.
 962 gas_test_headers="
 963 #ifdef HAVE_MEMORY_H
 964 #include <memory.h>
 965 #endif
 966 #ifdef HAVE_STRING_H
 967 #include <string.h>
 968 #else
 969 #ifdef HAVE_STRINGS_H
 970 #include <strings.h>
 971 #endif
 972 #endif
 973 #ifdef HAVE_STDLIB_H
 974 #include <stdlib.h>
 975 #endif
 976 #ifdef HAVE_UNISTD_H
 977 #include <unistd.h>
 978 #endif
 979 "
 980 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 981 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 982 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 983 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 984 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 985
 986 # Does errno.h declare errno, or do we have to add a separate declaration
 987 # for it?
 988 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 989 #ifdef HAVE_ERRNO_H
 990 #include <errno.h>
 991 #endif
 992 ])
 993
 994 dnl This must come last.
 995
 996 dnl We used to make symlinks to files in the source directory, but now
 997 dnl we just use the right name for .c files, and create .h files in
 998 dnl the build directory which include the right .h file.  Make sure
 999 dnl the old symlinks don't exist, so that a reconfigure in an existing
1000 dnl directory behaves reasonably.
1001
1002 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1003 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1004  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1005  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1006  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1007  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1008  if test "x$cgen_cpu_prefix" != x ; then
1009    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1010  fi
1011
1012  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1013 [target_cpu_type=${target_cpu_type}
1014  cgen_cpu_prefix=${cgen_cpu_prefix}
1015  obj_format=${obj_format}
1016  te_file=${te_file}])