binutils/testsuite/lib/utils-lib.exp

   1 # Copyright 1993, 1994, 1995, 1996, 1997, 2000, 2001, 2003, 2004
   2 # Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 # Please email any bugs, comments, and/or additions to this file to:
  19 # bug-dejagnu@prep.ai.mit.edu
  20
  21 # This file was written by Rob Savoye <rob@cygnus.com>
  22 # and extended by Ian Lance Taylor <ian@cygnus.com>
  23
  24 proc binutil_version { prog } {
  25     if ![is_remote host] {
  26         set path [which $prog]
  27         if {$path == 0} then {
  28             perror "$prog can't be run, file not found."
  29             return ""
  30         }
  31     } else {
  32         set path $prog
  33     }
  34     set state [remote_exec host $prog --version]
  35     set tmp "[lindex $state 1]\n"
  36     # Should find a way to discard constant parts, keep whatever's
  37     # left, so the version string could be almost anything at all...
  38     regexp "\[^\n\]* (cygnus-|)(\[-0-9.a-zA-Z-\]+)\[\r\n\].*" "$tmp" version cyg number
  39     if ![info exists number] then {
  40         return "$path (no version number)\n"
  41     }
  42     return "$path $number\n"
  43 }
  44
  45 #
  46 # default_binutils_run
  47 #       run a program, returning the output
  48 #       sets binutils_run_failed if the program does not exist
  49 #
  50 proc default_binutils_run { prog progargs } {
  51     global binutils_run_failed
  52     global host_triplet
  53
  54     set binutils_run_failed 0
  55
  56     if ![is_remote host] {
  57         if {[which $prog] == 0} then {
  58             perror "$prog does not exist"
  59             set binutils_run_failed 1
  60             return ""
  61         }
  62     }
  63
  64     send_log "$prog $progargs\n"
  65     verbose "$prog $progargs"
  66
  67     # Gotta quote dollar-signs because they get mangled by the
  68     # shell otherwise.
  69     regsub -all "\\$" "$progargs" "\\$" progargs
  70
  71     set state [remote_exec host $prog $progargs]
  72     set exec_output [prune_warnings [lindex $state 1]]
  73     if {![string match "" $exec_output]} then {
  74         send_log "$exec_output\n"
  75         verbose "$exec_output"
  76     } else {
  77         if { [lindex $state 0] != 0 } {
  78             set exec_output "$prog exited with status [lindex $state 0]"
  79             send_log "$exec_output\n"
  80             verbose "$exec_output"
  81         }
  82     }
  83     return $exec_output
  84 }
  85
  86 #
  87 # default_binutils_assemble
  88 #       assemble a file
  89 #
  90 proc default_binutils_assemble { source object } {
  91     global srcdir
  92     global host_triplet
  93
  94     # The HPPA assembler syntax is a little different than most, to make
  95     # the test source file assemble we need to run it through sed.
  96     #
  97     # This is a hack in that it won't scale well if other targets need
  98     # similar transformations to assemble.  We'll generalize the hack
  99     # if/when other targets need similar handling.
 100     if { [istarget "hppa*-*-*"] && ![istarget "*-*-linux*" ] } then {
 101         set sed_file $srcdir/config/hppa.sed
 102         send_log "sed -f $sed_file < $source > asm.s\n"
 103         verbose "sed -f $sed_file < $source > asm.s"
 104         catch "exec sed -f $sed_file < $source > asm.s"
 105         set source asm.s
 106     }
 107
 108     set exec_output [target_assemble $source $object ""]
 109     set exec_output [prune_warnings $exec_output]
 110
 111     if [string match "" $exec_output] {
 112         return 1
 113     } else {
 114         send_log "$exec_output\n"
 115         verbose "$exec_output"
 116         perror "$source: assembly failed"
 117         return 0
 118     }
 119 }
 120
 121 #
 122 # is_elf_format
 123 #       true if the object format is known to be ELF
 124 #
 125 proc is_elf_format {} {
 126     if { ![istarget *-*-sysv4*] \
 127          && ![istarget *-*-unixware*] \
 128          && ![istarget *-*-elf*] \
 129          && ![istarget *-*-eabi*] \
 130          && ![istarget hppa*64*-*-hpux*] \
 131          && ![istarget ia64-*-hpux*] \
 132          && ![istarget *-*-linux*] \
 133          && ![istarget *-*-irix5*] \
 134          && ![istarget *-*-irix6*] \
 135          && ![istarget *-*-netbsd*] \
 136          && ![istarget *-*-solaris2*] } {
 137         return 0
 138     }
 139
 140     if { [istarget *-*-linux*aout*] \
 141          || [istarget *-*-linux*oldld*] } {
 142         return 0
 143     }
 144
 145     if { ![istarget *-*-netbsdelf*] \
 146          && ([istarget *-*-netbsd*aout*] \
 147              || [istarget *-*-netbsdpe*] \
 148              || [istarget arm*-*-netbsd*] \
 149              || [istarget sparc-*-netbsd*] \
 150              || [istarget i*86-*-netbsd*] \
 151              || [istarget m68*-*-netbsd*] \
 152              || [istarget vax-*-netbsd*] \
 153              || [istarget ns32k-*-netbsd*]) } {
 154         return 0
 155     }
 156     return 1
 157 }
 158
 159 #
 160 # exe_ext
 161 #       Returns target executable extension, if any.
 162 #
 163 proc exe_ext {} {
 164     if { [istarget *-*-mingw32] || [istarget *-*-cygwin*] } {
 165         return ".exe"
 166     } else {
 167         return ""
 168     }
 169 }
 170
 171 # Copied and modified from gas.
 172
 173 # run_dump_test FILE (optional:) EXTRA_OPTIONS
 174 #
 175 # Assemble a .s file, then run some utility on it and check the output.
 176 #
 177 # There should be an assembly language file named FILE.s in the test
 178 # suite directory, and a pattern file called FILE.d.  `run_dump_test'
 179 # will assemble FILE.s, run some tool like `objdump', `objcopy', or
 180 # `nm' on the .o file to produce textual output, and then analyze that
 181 # with regexps.  The FILE.d file specifies what program to run, and
 182 # what to expect in its output.
 183 #
 184 # The FILE.d file begins with zero or more option lines, which specify
 185 # flags to pass to the assembler, the program to run to dump the
 186 # assembler's output, and the options it wants.  The option lines have
 187 # the syntax:
 188 #
 189 #         # OPTION: VALUE
 190 #
 191 # OPTION is the name of some option, like "name" or "objdump", and
 192 # VALUE is OPTION's value.  The valid options are described below.
 193 # Whitespace is ignored everywhere, except within VALUE.  The option
 194 # list ends with the first line that doesn't match the above syntax.
 195 # However, a line within the options that begins with a #, but doesn't
 196 # have a recognizable option name followed by a colon, is considered a
 197 # comment and entirely ignored.
 198 #
 199 # The optional EXTRA_OPTIONS argument to `run_dump_test' is a list of
 200 # two-element lists.  The first element of each is an option name, and
 201 # the second additional arguments to be added on to the end of the
 202 # option list as given in FILE.d.  (If omitted, no additional options
 203 # are added.)
 204 #
 205 # The interesting options are:
 206 #
 207 #   name: TEST-NAME
 208 #       The name of this test, passed to DejaGNU's `pass' and `fail'
 209 #       commands.  If omitted, this defaults to FILE, the root of the
 210 #       .s and .d files' names.
 211 #
 212 #   as: FLAGS
 213 #       When assembling FILE.s, pass FLAGS to the assembler.
 214 #
 215 #   PROG: PROGRAM-NAME
 216 #       The name of the program to run to analyze the .o file produced
 217 #       by the assembler.  This can be omitted; run_dump_test will guess
 218 #       which program to run by seeing which of the flags options below
 219 #       is present.
 220 #
 221 #   objdump: FLAGS
 222 #   nm: FLAGS
 223 #   objcopy: FLAGS
 224 #       Use the specified program to analyze the .o file, and pass it
 225 #       FLAGS, in addition to the .o file name.  Note that they are run
 226 #       with LC_ALL=C in the environment to give consistent sorting
 227 #       of symbols.
 228 #
 229 #   source: SOURCE
 230 #       Assemble the file SOURCE.s.  If omitted, this defaults to FILE.s.
 231 #       This is useful if several .d files want to share a .s file.
 232 #
 233 #   target: GLOBS...
 234 #       Run this test only on a specified list of targets.  More precisely,
 235 #       each glob in the space-separated list is passed to "istarget"; if
 236 #       it evaluates true for any of them, the test will be run, otherwise
 237 #       it will be marked unsupported.
 238 #
 239 #   not-target: GLOBS...
 240 #       Do not run this test on a specified list of targets.  Again,
 241 #       the each glob in the space-separated list is passed to
 242 #       "istarget", and the test is run if it evaluates *false* for
 243 #       *all* of them.  Otherwise it will be marked unsupported.
 244 #
 245 #   skip: GLOBS...
 246 #   not-skip: GLOBS...
 247 #       These are exactly the same as "not-target" and "target",
 248 #       respectively, except that they do nothing at all if the check
 249 #       fails.  They should only be used in groups, to construct a single
 250 #       test which is run on all targets but with variant options or
 251 #       expected output on some targets.  (For example, see
 252 #       gas/arm/inst.d and gas/arm/wince_inst.d.)
 253 #
 254 #   error: REGEX
 255 #       An error with message matching REGEX must be emitted for the test
 256 #       to pass.  The PROG, objdump, nm and objcopy options have no
 257 #       meaning and need not supplied if this is present.
 258 #
 259 #   warning: REGEX
 260 #       Expect a gas warning matching REGEX.  It is an error to issue
 261 #       both "error" and "warning".
 262 #
 263 #   stderr: FILE
 264 #       FILE contains regexp lines to be matched against the diagnostic
 265 #       output of the assembler.  This does not preclude the use of
 266 #       PROG, nm, objdump, or objcopy.
 267 #
 268 #   error-output: FILE
 269 #       Means the same as 'stderr', but also indicates that the assembler
 270 #       is expected to exit unsuccessfully (therefore PROG, objdump, nm,
 271 #       and objcopy have no meaning and should not be supplied).
 272 #
 273 # Each option may occur at most once.
 274 #
 275 # After the option lines come regexp lines.  `run_dump_test' calls
 276 # `regexp_diff' to compare the output of the dumping tool against the
 277 # regexps in FILE.d.  `regexp_diff' is defined later in this file; see
 278 # further comments there.
 279
 280 proc run_dump_test { name {extra_options {}} } {
 281     global subdir srcdir
 282     global OBJDUMP NM OBJCOPY READELF
 283     global OBJDUMPFLAGS NMFLAGS OBJCOPYFLAGS READELFFLAGS
 284     global host_triplet
 285     global env
 286     global copyfile
 287     global tempfile
 288
 289     if [string match "*/*" $name] {
 290         set file $name
 291         set name [file tail $name]
 292     } else {
 293         set file "$srcdir/$subdir/$name"
 294     }
 295     set opt_array [slurp_options "${file}.d"]
 296     if { $opt_array == -1 } {
 297         perror "error reading options from $file.d"
 298         unresolved $subdir/$name
 299         return
 300     }
 301     set opts(addr2line) {}
 302     set opts(ar) {}
 303     set opts(nm) {}
 304     set opts(objcopy) {}
 305     set opts(objdump) {}
 306     set opts(strip) {}
 307     set opts(ranlib) {}
 308     set opts(readelf) {}
 309     set opts(size) {}
 310     set opts(strings) {}
 311     set opts(name) {}
 312     set opts(PROG) {}
 313     set opts(DUMPPROG) {}
 314     set opts(source) {}
 315     set opts(target) {}
 316     set opts(not-target) {}
 317     set opts(skip) {}
 318     set opts(not-skip) {}
 319
 320     foreach i $opt_array {
 321         set opt_name [lindex $i 0]
 322         set opt_val [lindex $i 1]
 323         if ![info exists opts($opt_name)] {
 324             perror "unknown option $opt_name in file $file.d"
 325             unresolved $subdir/$name
 326             return
 327         }
 328         if [string length $opts($opt_name)] {
 329             perror "option $opt_name multiply set in $file.d"
 330             unresolved $subdir/$name
 331             return
 332         }
 333         set opts($opt_name) $opt_val
 334     }
 335
 336     foreach i $extra_options {
 337         set opt_name [lindex $i 0]
 338         set opt_val [lindex $i 1]
 339         if ![info exists opts($opt_name)] {
 340             perror "unknown option $opt_name given in extra_opts"
 341             unresolved $subdir/$name
 342             return
 343         }
 344         # add extra option to end of existing option, adding space
 345         # if necessary.
 346         if [string length $opts($opt_name)] {
 347             append opts($opt_name) " "
 348         }
 349         append opts($opt_name) $opt_val
 350     }
 351
 352     if { $opts(name) == "" } {
 353         set testname "$subdir/$name"
 354     } else {
 355         set testname $opts(name)
 356     }
 357     verbose "Testing $testname"
 358
 359     if {$opts(PROG) == ""} {
 360         perror "program isn't set in $file.d"
 361         unresolved $testname
 362         return
 363     }
 364
 365     switch -- $opts(PROG) {
 366         ar      { set program ar }
 367         objcopy { set program objcopy }
 368         ranlib  { set program ranlib }
 369         strip   { set program strip }
 370         strings { set program strings }
 371         default {
 372             perror "unrecognized program option $opts(PROG) in $file.d"
 373             unresolved $testname
 374             return }
 375     }
 376
 377     set dumpprogram ""
 378     if { $opts(DUMPPROG) != "" } {
 379         switch -- $opts(DUMPPROG) {
 380             addr2line   { set dumpprogram addr2line }
 381             nm          { set dumpprogram nm }
 382             objdump     { set dumpprogram objdump }
 383             readelf     { set dumpprogram readelf }
 384             size        { set dumpprogram size }
 385             default     {
 386                 perror "unrecognized dump program option $opts(DUMPPROG) in $file.d"
 387                 unresolved $testname
 388                 return }
 389         }
 390     } else {
 391         # Guess which program to run, by seeing which option was specified.
 392         foreach p {objdump nm readelf} {
 393             if {$opts($p) != ""} {
 394                 if {$dumpprogram != ""} {
 395                     perror "ambiguous dump program in $file.d"
 396                     unresolved $testname
 397                     return
 398                 } else {
 399                     set dumpprogram $p
 400                 }
 401             }
 402         }
 403     }
 404
 405     # Handle skipping the test on specified targets.
 406     # You can have both skip/not-skip and target/not-target, but you can't
 407     # have both skip and not-skip, or target and not-target, in the same file.
 408     if { $opts(skip) != "" } then {
 409         if { $opts(not-skip) != "" } then {
 410             perror "$testname: mixing skip and not-skip directives is invalid"
 411             unresolved $testname
 412             return
 413         }
 414         foreach glob $opts(skip) {
 415             if {[istarget $glob]} { return }
 416         }
 417     }
 418     if { $opts(not-skip) != "" } then {
 419         set skip 1
 420         foreach glob $opts(not-skip) {
 421             if {[istarget $glob]} {
 422                 set skip 0
 423                 break
 424             }
 425         }
 426         if {$skip} { return }
 427     }
 428     if { $opts(target) != "" } then {
 429         if { $opts(not-target) != "" } then {
 430             perror "$testname: mixing target and not-target directives is invalid"
 431             unresolved $testname
 432             return
 433         }
 434         set skip 1
 435         foreach glob $opts(target) {
 436             if {[istarget $glob]} {
 437                 set skip 0
 438                 break
 439             }
 440         }
 441         if {$skip} {
 442             unsupported $testname
 443             return
 444         }
 445     }
 446     if { $opts(not-target) != "" } then {
 447         foreach glob $opts(not-target) {
 448             if {[istarget $glob]} {
 449                 unsupported $testname
 450                 return
 451             }
 452         }
 453     }
 454
 455     if { $opts(source) == "" } {
 456         set srcfile ${file}.s
 457     } else {
 458         set srcfile $srcdir/$subdir/$opts(source)
 459     }
 460
 461     set exec_output [binutils_assemble ${srcfile} tmpdir/bintest.o]
 462     if [string match "" $exec_output] then {
 463         send_log "$exec_output\n"
 464         verbose "$exec_output"
 465         fail $testname
 466         return
 467     }
 468
 469     set progopts1 $opts($program)
 470     eval set progopts \$[string toupper $program]FLAGS
 471     eval set binary \$[string toupper $program]
 472
 473     set exec_output [binutils_run $binary "$progopts $progopts1 $tempfile ${copyfile}.o"]
 474     if ![string match "" $exec_output] {
 475         send_log "$exec_output\n"
 476         verbose "$exec_output"
 477         fail $testname
 478         return
 479     }
 480
 481     set progopts1 $opts($dumpprogram)
 482     eval set progopts \$[string toupper $dumpprogram]FLAGS
 483     eval set binary \$[string toupper $dumpprogram]
 484
 485     if { [which $binary] == 0 } {
 486         untested $testname
 487         return
 488     }
 489
 490     verbose "running $binary $progopts $progopts1" 3
 491
 492     set cmd "$binary $progopts $progopts1 ${copyfile}.o > tmpdir/dump.out"
 493
 494     # Ensure consistent sorting of symbols
 495     if {[info exists env(LC_ALL)]} {
 496         set old_lc_all $env(LC_ALL)
 497     }
 498     set env(LC_ALL) "C"
 499     send_log "$cmd\n"
 500     catch "exec $cmd" comp_output
 501     if {[info exists old_lc_all]} {
 502         set env(LC_ALL) $old_lc_all
 503     } else {
 504         unset env(LC_ALL)
 505     }
 506     set comp_output [prune_warnings $comp_output]
 507     if ![string match "" $comp_output] then {
 508         send_log "$comp_output\n"
 509         fail $testname
 510         return
 511     }
 512
 513     verbose_eval {[file_contents "tmpdir/dump.out"]} 3
 514     if { [regexp_diff "tmpdir/dump.out" "${file}.d"] } then {
 515         fail $testname
 516         verbose "output is [file_contents "tmpdir/dump.out"]" 2
 517         return
 518     }
 519
 520     pass $testname
 521 }
 522
 523 proc slurp_options { file } {
 524     if [catch { set f [open $file r] } x] {
 525         #perror "couldn't open `$file': $x"
 526         perror "$x"
 527         return -1
 528     }
 529     set opt_array {}
 530     # whitespace expression
 531     set ws  {[  ]*}
 532     set nws {[^         ]*}
 533     # whitespace is ignored anywhere except within the options list;
 534     # option names are alphabetic plus dash
 535     set pat "^#${ws}(\[a-zA-Z-\]*)$ws:${ws}(.*)$ws\$"
 536     while { [gets $f line] != -1 } {
 537         set line [string trim $line]
 538         # Whitespace here is space-tab.
 539         if [regexp $pat $line xxx opt_name opt_val] {
 540             # match!
 541             lappend opt_array [list $opt_name $opt_val]
 542         } elseif {![regexp "^#" $line ]} {
 543             break
 544         }
 545     }
 546     close $f
 547     return $opt_array
 548 }
 549
 550 # regexp_diff, based on simple_diff taken from ld test suite
 551 #       compares two files line-by-line
 552 #       file1 contains strings, file2 contains regexps and #-comments
 553 #       blank lines are ignored in either file
 554 #       returns non-zero if differences exist
 555 #
 556 proc regexp_diff { file_1 file_2 } {
 557
 558     set eof -1
 559     set end_1 0
 560     set end_2 0
 561     set differences 0
 562     set diff_pass 0
 563
 564     if [file exists $file_1] then {
 565         set file_a [open $file_1 r]
 566     } else {
 567         perror "$file_1 doesn't exist"
 568         return 1
 569     }
 570
 571     if [file exists $file_2] then {
 572         set file_b [open $file_2 r]
 573     } else {
 574         perror "$file_2 doesn't exist"
 575         close $file_a
 576         return 1
 577     }
 578
 579     verbose " Regexp-diff'ing: $file_1 $file_2" 2
 580
 581     while { 1 } {
 582         set line_a ""
 583         set line_b ""
 584         while { [string length $line_a] == 0 } {
 585             if { [gets $file_a line_a] == $eof } {
 586                 set end_1 1
 587                 break
 588             }
 589         }
 590         while { [string length $line_b] == 0 || [string match "#*" $line_b] } {
 591             if [ string match "#pass" $line_b ] {
 592                 set end_2 1
 593                 set diff_pass 1
 594                 break
 595             } elseif [ string match "#..." $line_b ] {
 596                 if { [gets $file_b line_b] == $eof } {
 597                     set end_2 1
 598                     set diff_pass 1
 599                     break
 600                 }
 601                 verbose "looking for \"^$line_b$\"" 3
 602                 while { ![regexp "^$line_b$" "$line_a"] } {
 603                     verbose "skipping    \"$line_a\"" 3
 604                     if { [gets $file_a line_a] == $eof } {
 605                         set end_1 1
 606                         break
 607                     }
 608                 }
 609                 break
 610             }
 611             if { [gets $file_b line_b] == $eof } {
 612                 set end_2 1
 613                 break
 614             }
 615         }
 616
 617         if { $diff_pass } {
 618             break
 619         } elseif { $end_1 && $end_2 } {
 620             break
 621         } elseif { $end_1 } {
 622             send_log "extra regexps in $file_2 starting with \"^$line_b$\"\nEOF from $file_1\n"
 623             verbose "extra regexps in $file_2 starting with \"^$line_b$\"\nEOF from $file_1" 3
 624             set differences 1
 625             break
 626         } elseif { $end_2 } {
 627             send_log "extra lines in $file_1 starting with \"^$line_a$\"\nEOF from $file_2\n"
 628             verbose "extra lines in $file_1 starting with \"^$line_a$\"\nEOF from $file_2\n" 3
 629             set differences 1
 630             break
 631         } else {
 632             verbose "regexp \"^$line_b$\"\nline   \"$line_a\"" 3
 633             if ![regexp "^$line_b$" "$line_a"] {
 634                 send_log "regexp_diff match failure\n"
 635                 send_log "regexp \"^$line_b$\"\nline   \"$line_a\"\n"
 636                 verbose "regexp_diff match failure\n" 3
 637                 set differences 1
 638             }
 639         }
 640     }
 641
 642     if { $differences == 0 && !$diff_pass && [eof $file_a] != [eof $file_b] } {
 643         send_log "$file_1 and $file_2 are different lengths\n"
 644         verbose "$file_1 and $file_2 are different lengths" 3
 645         set differences 1
 646     }
 647
 648     close $file_a
 649     close $file_b
 650
 651     return $differences
 652 }
 653
 654 proc file_contents { filename } {
 655     set file [open $filename r]
 656     set contents [read $file]
 657     close $file
 658     return $contents
 659 }
 660
 661 proc verbose_eval { expr { level 1 } } {
 662     global verbose
 663     if $verbose>$level then { eval verbose "$expr" $level }
 664 }