t/SeqFeature/LocationFactory.t

   1 # -*-Perl-*- Test Harness script for Bioperl
   2 # $Id$
   3
   4 use strict;
   5
   6 BEGIN {
   7     use Bio::Root::Test;
   8
   9     test_begin(-tests => 325);
  10
  11     use_ok('Bio::Factory::FTLocationFactory');
  12 }
  13
  14 my $simple_impl = "Bio::Location::Simple";
  15 my $fuzzy_impl  = "Bio::Location::Fuzzy";
  16 my $split_impl  = "Bio::Location::Split";
  17
  18 # Holds strings and results. The latter is an array of expected class name,
  19 # min/max start position and position type, min/max end position and position
  20 # type, location type, the number of locations, and the strand.
  21 #
  22 my %testcases = (
  23     # note: the following are directly taken from
  24     # http://www.insdc.org/documents/feature_table.html#3.4.3
  25     "467"
  26         => [$simple_impl, 467, 467, "EXACT",
  27                           467, 467, "EXACT",
  28                           "EXACT", 1, 1],
  29     "340..565"
  30         => [$simple_impl, 340, 340, "EXACT",
  31                           565, 565, "EXACT",
  32                           "EXACT", 1, 1],
  33     "<345..500"
  34         => [$fuzzy_impl, undef, 345, "BEFORE",
  35                          500,   500, "EXACT",
  36                          "EXACT", 1, 1],
  37     "<1..888"
  38         => [$fuzzy_impl, undef, 1,   "BEFORE",
  39                          888,   888, "EXACT",
  40                          "EXACT", 1, 1],
  41     "1..>888"
  42         => [$fuzzy_impl, 1,   1,     "EXACT",
  43                          888, undef, "AFTER",
  44                          "EXACT", 1, 1],
  45     "(102.110)"
  46         => [$fuzzy_impl, 102, 102, "EXACT",
  47                          110, 110, "EXACT",
  48                          "WITHIN", 1, 1],
  49     "(23.45)..600"
  50         => [$fuzzy_impl, 23,  45,  "WITHIN",
  51                          600, 600, "EXACT",
  52                          "EXACT", 1, 1],
  53     "(122.133)..(204.221)"
  54         => [$fuzzy_impl, 122, 133, "WITHIN",
  55                          204, 221, "WITHIN",
  56                          "EXACT", 1, 1],
  57     "123^124"
  58         => [$simple_impl, 123, 123, "EXACT",
  59                           124, 124, "EXACT",
  60                           "IN-BETWEEN", 1, 1],
  61     "145^177"
  62         => [$fuzzy_impl, 145, 145, "EXACT",
  63                          177, 177, "EXACT",
  64                          "IN-BETWEEN", 1, 1],
  65     "join(12..78,134..202)"
  66         => [$split_impl, 12,  12,  "EXACT",
  67                          202, 202, "EXACT",
  68                          "EXACT", 2, 1],
  69     "complement(join(2691..4571,4918..5163))"
  70         => [$split_impl, 2691, 2691, "EXACT",
  71                          5163, 5163, "EXACT",
  72                          "EXACT", 2, -1],
  73     # Partial frameshifted gene at the end of a contig
  74     "complement(join(94468..94578,94578..>94889))"
  75         => [$split_impl, 94468, 94468, "EXACT",
  76                          94889, undef, "AFTER",
  77                          "EXACT", 2, -1],
  78     "complement(34..(122.126))"
  79         => [$fuzzy_impl, 34,  34,  "EXACT",
  80                          122, 126, "WITHIN",
  81                          "EXACT", 1, -1],
  82     "J00194:100..202"
  83         => [$simple_impl, 100, 100, "EXACT",
  84                           202, 202, "EXACT",
  85                           "EXACT", 1, 1],
  86     "join(1..100,J00194.1:100..202)"
  87         => [$split_impl, 1,   1,   "EXACT",
  88                          100, 100, "EXACT",
  89                          "EXACT", 2, 1],
  90
  91     # this variant is not really allowed by the FT definition
  92     # document but we want to be able to cope with it
  93     "J00194:(100..202)"
  94         => [$simple_impl, 100, 100, "EXACT",
  95                           202, 202, "EXACT",
  96                           "EXACT", 1, 1],
  97     "((122.133)..(204.221))"
  98         => [$fuzzy_impl, 122, 133, "WITHIN",
  99                          204, 221, "WITHIN",
 100                          "EXACT", 1, 1],
 101     "join(AY016290.1:108..185,AY016291.1:1546..1599)"
 102         => [$split_impl, 108, 108, "EXACT",
 103                          185, 185, "EXACT",
 104                          "EXACT", 2, 1],
 105
 106     # UNCERTAIN locations and positions (Swissprot)
 107     "?2465..2774"
 108         => [$fuzzy_impl, 2465, 2465, "UNCERTAIN",
 109                          2774, 2774, "EXACT",
 110                          "EXACT", 1, 1],
 111     "22..?64"
 112         => [$fuzzy_impl, 22, 22, "EXACT",
 113                          64, 64, "UNCERTAIN",
 114                          "EXACT", 1, 1],
 115     "?22..?64"
 116         => [$fuzzy_impl, 22, 22, "UNCERTAIN",
 117                          64, 64, "UNCERTAIN",
 118                          "EXACT", 1, 1],
 119     "?..>393"
 120         => [$fuzzy_impl, undef, undef, "UNCERTAIN",
 121                          393,   undef, "AFTER",
 122                          "UNCERTAIN", 1, 1],
 123     "<1..?"
 124         => [$fuzzy_impl, undef, 1,     "BEFORE",
 125                          undef, undef, "UNCERTAIN",
 126                          "UNCERTAIN", 1, 1],
 127     "?..536"
 128         => [$fuzzy_impl, undef, undef, "UNCERTAIN",
 129                          536,   536,   "EXACT",
 130                          "UNCERTAIN", 1, 1],
 131     "1..?"
 132         => [$fuzzy_impl, 1,     1,     "EXACT",
 133                          undef, undef, "UNCERTAIN",
 134                          "UNCERTAIN", 1, 1],
 135     "?..?"
 136         => [$fuzzy_impl, undef, undef, "UNCERTAIN",
 137                          undef, undef, "UNCERTAIN",
 138                          "UNCERTAIN", 1, 1],
 139     "?1..12"
 140         => [$fuzzy_impl, 1,  1,  "UNCERTAIN",
 141                          12, 12, "EXACT",
 142                          "EXACT", 1, 1]
 143 );
 144
 145 my $locfac = Bio::Factory::FTLocationFactory->new();
 146 isa_ok($locfac,'Bio::Factory::LocationFactoryI');
 147
 148 # sorting is to keep the order constant from one run to the next
 149 foreach my $locstr (keys %testcases) {
 150     my $loc = $locfac->from_string($locstr);
 151     if($locstr eq "join(AY016290.1:108..185,AY016291.1:1546..1599)") {
 152         $loc->seq_id("AY016295.1");
 153     }
 154     if($locstr eq "join(1..100,J00194.1:100..202)") {
 155         $loc->seq_id("unknown");
 156     }
 157     my @res = @{$testcases{$locstr}};
 158     is(ref($loc), $res[0], $res[0]);
 159     is($loc->min_start(), $res[1]);
 160     is($loc->max_start(), $res[2]);
 161     is($loc->start_pos_type(), $res[3]);
 162     is($loc->min_end(), $res[4]);
 163     is($loc->max_end(), $res[5]);
 164     is($loc->end_pos_type(), $res[6]);
 165     is($loc->location_type(), $res[7]);
 166     my @locs = $loc->each_Location();
 167     is(@locs, $res[8]);
 168     my $ftstr = $loc->to_FTstring();
 169     # this is a somewhat ugly hack, but we want clean output from to_FTstring()
 170     # Umm, then these should really fail, correct?
 171     # Should we be engineering workarounds for tests?
 172     $locstr = "J00194:100..202"      if $locstr eq "J00194:(100..202)";
 173     $locstr = "(122.133)..(204.221)" if $locstr eq "((122.133)..(204.221))";
 174     # now test
 175     is($ftstr, $locstr, "Location String: $locstr");
 176     # test strand production
 177     is($loc->strand(), $res[9]);
 178 }
 179
 180 SKIP: {
 181     skip('nested matches in regex only supported in v5.6.1 and higher', 8) unless $^V gt v5.6.0;
 182
 183     # Tests based on location definition (http://www.insdc.org/documents/feature_table.html#3.4)
 184     my $string1  = 'complement(join(2691..4571,4918..5163))';
 185     my $string2  = 'join(complement(4918..5163),complement(2691..4571))';
 186     my $loc1     = $locfac->from_string($string1);
 187     my $loc2     = $locfac->from_string($string2);
 188     my $loc1_str = $loc1->to_FTstring;
 189     my $loc2_str = $loc2->to_FTstring;
 190     is($loc1_str, $string1, $string1);
 191     is($loc2_str, $string1, $string2);
 192     is($loc1_str, $loc2_str, 'equivalent remote location strings');
 193
 194     # Test for equivalent reverse strand locations adding one remote component
 195     $string1  = 'complement(join(TEST0001.1:2691..4571,4918..5163))';
 196     $string2  = 'join(complement(4918..5163),complement(TEST0001.1:2691..4571))';
 197     $loc1     = $locfac->from_string($string1);
 198     $loc2     = $locfac->from_string($string2);
 199     $loc1_str = $loc1->to_FTstring;
 200     $loc2_str = $loc2->to_FTstring;
 201     is($loc1_str, $string1, $string1);
 202     is($loc2_str, $string1, $string2);
 203     is($loc1_str, $loc2_str, 'equivalent remote location strings');
 204
 205     # Test for equivalent reverse strand locations adding two remote components
 206     $string1  = 'complement(join(TEST0001.1:2691..4571,TEST0008.1:4918..5163))';
 207     $string2  = 'join(complement(TEST0008.1:4918..5163),complement(TEST0001.1:2691..4571))';
 208     $loc1     = $locfac->from_string($string1);
 209     $loc2     = $locfac->from_string($string2);
 210     $loc1_str = $loc1->to_FTstring;
 211     $loc2_str = $loc2->to_FTstring;
 212     is($loc1_str, $string1, $string1);
 213     is($loc2_str, $string1, $string2);
 214     is($loc1_str, $loc2_str, 'equivalent remote location strings');
 215
 216     # bug #1674, #1765, 2101
 217     # EMBL-like (BAC19856.3 protein)
 218     # join(20464..20694,21548..22763,join(complement(314652..314672),complement(232596..232990),complement(231520..231669)))
 219     # GenBank-like
 220     # join(20464..20694,21548..22763,complement(join(231520..231669,232596..232990,314652..314672)))
 221     # Note that
 222     # join(1000..2000,join(3000..4000,join(5000..6000,7000..8000)),9000..10000)
 223     # is the same as
 224     # join(1000..2000,3000..4000,5000..6000,7000..8000,9000..10000)
 225
 226     my @expected = (# intentionally testing same expected string twice
 227                     # as I am providing two different encodings
 228                     # that should mean the same thing
 229     'join(11025..11049,complement(join(315036..315294,251354..251412,241499..241580,239890..240081)))',
 230     'join(11025..11049,complement(join(315036..315294,251354..251412,241499..241580,239890..240081)))',
 231     # ditto
 232     'join(20464..20694,21548..22763,complement(join(231520..231669,232596..232990,314652..314672)))',
 233     'join(20464..20694,21548..22763,complement(join(231520..231669,232596..232990,314652..314672)))',
 234     # this is just seen once
 235     'join(1000..2000,3000..4000,5000..6000,7000..8000,9000..10000)',
 236     'order(S67862.1:72..75,join(S67863.1:1..788,1..19))'
 237    );
 238
 239     for my $locstr (
 240         'join(11025..11049,join(complement(239890..240081),complement(241499..241580),complement(251354..251412),complement(315036..315294)))',
 241         'join(11025..11049,complement(join(315036..315294,251354..251412,241499..241580,239890..240081)))',
 242         'join(20464..20694,21548..22763,complement(join(231520..231669,232596..232990,314652..314672)))',
 243         'join(20464..20694,21548..22763,join(complement(314652..314672),complement(232596..232990),complement(231520..231669)))',
 244         'join(1000..2000,join(3000..4000,join(5000..6000,7000..8000)),9000..10000)',
 245         'order(S67862.1:72..75,join(S67863.1:1..788,1..19))'
 246        ) {
 247         my $loc = $locfac->from_string($locstr);
 248         my $ftstr = $loc->to_FTstring();
 249         is($ftstr, shift @expected, $locstr);
 250     }
 251 }