build-aux/m4/ax_check_preproc_flag.m4

   1 # ===========================================================================
   2 #   http://www.gnu.org/software/autoconf-archive/ax_check_preproc_flag.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_CHECK_PREPROC_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   Check whether the given FLAG works with the current language's
  12 #   preprocessor or gives an error.  (Warnings, however, are ignored)
  13 #
  14 #   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
  15 #   success/failure.
  16 #
  17 #   If EXTRA-FLAGS is defined, it is added to the preprocessor's default
  18 #   flags when the check is done.  The check is thus made with the flags:
  19 #   "CPPFLAGS EXTRA-FLAGS FLAG".  This can for example be used to force the
  20 #   preprocessor to issue an error when a bad flag is given.
  21 #
  22 #   INPUT gives an alternative input source to AC_PREPROC_IFELSE.
  23 #
  24 #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
  25 #   macro in sync with AX_CHECK_{COMPILE,LINK}_FLAG.
  26 #
  27 # LICENSE
  28 #
  29 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  30 #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
  31 #
  32 #   This program is free software: you can redistribute it and/or modify it
  33 #   under the terms of the GNU General Public License as published by the
  34 #   Free Software Foundation, either version 3 of the License, or (at your
  35 #   option) any later version.
  36 #
  37 #   This program is distributed in the hope that it will be useful, but
  38 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  39 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  40 #   Public License for more details.
  41 #
  42 #   You should have received a copy of the GNU General Public License along
  43 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  44 #
  45 #   As a special exception, the respective Autoconf Macro's copyright owner
  46 #   gives unlimited permission to copy, distribute and modify the configure
  47 #   scripts that are the output of Autoconf when processing the Macro. You
  48 #   need not follow the terms of the GNU General Public License when using
  49 #   or distributing such scripts, even though portions of the text of the
  50 #   Macro appear in them. The GNU General Public License (GPL) does govern
  51 #   all other use of the material that constitutes the Autoconf Macro.
  52 #
  53 #   This special exception to the GPL applies to versions of the Autoconf
  54 #   Macro released by the Autoconf Archive. When you make and distribute a
  55 #   modified version of the Autoconf Macro, you may extend this special
  56 #   exception to the GPL to apply to your modified version as well.
  57
  58 #serial 4
  59
  60 AC_DEFUN([AX_CHECK_PREPROC_FLAG],
  61 [AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
  62 AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]cppflags_$4_$1])dnl
  63 AC_CACHE_CHECK([whether _AC_LANG preprocessor accepts $1], CACHEVAR, [
  64   ax_check_save_flags=$CPPFLAGS
  65   CPPFLAGS="$CPPFLAGS $4 $1"
  66   AC_PREPROC_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
  67     [AS_VAR_SET(CACHEVAR,[yes])],
  68     [AS_VAR_SET(CACHEVAR,[no])])
  69   CPPFLAGS=$ax_check_save_flags])
  70 AS_VAR_IF(CACHEVAR,yes,
  71   [m4_default([$2], :)],
  72   [m4_default([$3], :)])
  73 AS_VAR_POPDEF([CACHEVAR])dnl
  74 ])dnl AX_CHECK_PREPROC_FLAGS