tests/Boo.Lang.Useful.Tests/CommandLine/AbstractCommandLineTestFixture.boo

   1 #region license
   2 // Copyright (c) 2004, Rodrigo B. de Oliveira (rbo@acm.org)
   3 // All rights reserved.
   4 //
   5 // Redistribution and use in source and binary forms, with or without modification,
   6 // are permitted provided that the following conditions are met:
   7 //
   8 //     * Redistributions of source code must retain the above copyright notice,
   9 //     this list of conditions and the following disclaimer.
  10 //     * Redistributions in binary form must reproduce the above copyright notice,
  11 //     this list of conditions and the following disclaimer in the documentation
  12 //     and/or other materials provided with the distribution.
  13 //     * Neither the name of Rodrigo B. de Oliveira nor the names of its
  14 //     contributors may be used to endorse or promote products derived from this
  15 //     software without specific prior written permission.
  16 //
  17 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
  18 // ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  19 // WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  20 // DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE
  21 // FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22 // DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  23 // SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
  24 // CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  25 // OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 // THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 #endregion
  28
  29 namespace Boo.Lang.Useful.CommandLine.Tests
  30
  31 import System
  32 import Useful.CommandLine
  33 import NUnit.Framework
  34
  35 class BooCommandLine(AbstractCommandLine):
  36
  37         [Option("boo.BooCommandLine.target", ShortForm: "t", LongForm: "target")]
  38         public Target as string
  39
  40         [Option("boo.BooCommandLine.output", ShortForm: "o", LongForm: "output")]
  41         public Output as string
  42
  43         [getter(Arguments)]
  44         _args = []
  45
  46         [getter(References)]
  47         _references = []
  48
  49         [Option("boo.BooCommandLine.reference", ShortForm: "r", MaxOccurs: int.MaxValue)]
  50         def OnReference([required] reference as string):
  51                 _references.Add(reference)
  52
  53         [Argument("boo.BooCommandLine.argument")]
  54         def OnArgument([required] value as string):
  55                 _args.Add(value)
  56
  57         [Option("boo.BooCommandLine.resource", LongForm: "res", MaxOccurs: int.MaxValue)]
  58         public Resources = []
  59
  60         [Option("boo.BooCommandLine.debug")] # long form deduced from the field name
  61         public Debug = false
  62
  63         def constructor(argv as (string)):
  64                 Parse(argv)
  65
  66 class AnotherCommandLine(AbstractCommandLine):
  67
  68         [Argument("boo.AnotherCommandLine.argument")]
  69         public Arguments = []
  70
  71         def constructor(argv as (string)):
  72                 Parse(argv)
  73
  74 class JiraCommandLine(AbstractCommandLine):
  75
  76         [Option("jira.login", ShortForm: "l", LongForm: "jira-login", MinOccurs: 1, MaxOccurs: 1)]
  77         public JiraLogin as string
  78
  79         def constructor(argv as (string)):
  80                 Parse(argv)
  81
  82 [TestFixture]
  83 class AbstractCommandLineTestFixture:
  84
  85         [Test]
  86         def TestParse():
  87                 argv = (
  88                         "-t:exe",
  89                         "foo.boo",
  90                         "-output:bin/foo.exe",
  91                         "bar.boo",
  92                         "-res:res1",
  93                         "-res:res2,id2",
  94                         "-debug",
  95                         "-r:Foo.dll",
  96                         "-r:Bar.dll",
  97                 )
  98
  99                 cmdLine = BooCommandLine(argv)
 100
 101                 Assert.AreEqual("exe", cmdLine.Target)
 102                 Assert.AreEqual("bin/foo.exe", cmdLine.Output)
 103                 Assert.AreEqual(["foo.boo", "bar.boo"], cmdLine.Arguments)
 104                 Assert.AreEqual(["res1", "res2,id2"], cmdLine.Resources)
 105                 Assert.AreEqual(["Foo.dll", "Bar.dll"], cmdLine.References)
 106                 assert cmdLine.Debug
 107
 108         [Test]
 109         def TestBooleanParse():
 110
 111                 argv = ("-debug-",)
 112                 assert not BooCommandLine(argv).Debug
 113
 114                 argv = ("-debug+",)
 115                 assert BooCommandLine(argv).Debug
 116
 117         [Test]
 118         def TestArgumentToListField():
 119
 120                 argv = ("arg1", "arg2")
 121                 cmdLine = AnotherCommandLine(argv)
 122
 123                 Assert.AreEqual(["arg1", "arg2"], cmdLine.Arguments)
 124
 125         [Test]
 126         def TestOptionWithDashes():
 127                 argv = ("-jira-login:foo",)
 128                 cmdLine = JiraCommandLine(argv)
 129                 Assert.AreEqual("foo", cmdLine.JiraLogin)