games-rpg/freedroidrpg/freedroidrpg-9999.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 LUA_COMPAT=( lua5-3 )
   7 PYTHON_COMPAT=( python3_{10..13} )
   8
   9 inherit autotools gnome2-utils lua-single python-any-r1 xdg git-r3
  10
  11 DESCRIPTION="Modification of the classical Freedroid engine into an RPG"
  12 HOMEPAGE="https://www.freedroid.org"
  13 SRC_URI=""
  14 EGIT_REPO_URI="https://gitlab.com/freedroid/freedroid-src.git"
  15
  16 LICENSE="GPL-2+"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="debug devtools nls opengl profile sanitize +sound"
  20 REQUIRED_USE="${LUA_REQUIRED_USE}"
  21
  22 RDEPEND="
  23         ${LUA_DEPS}
  24         media-libs/libpng:=
  25         media-libs/libsdl[opengl?,sound?,video]
  26         >=media-libs/sdl-gfx-2.0.21:=
  27         media-libs/sdl-image[jpeg,png]
  28         sys-libs/zlib:=
  29         devtools? ( media-libs/sdl-ttf )
  30         nls? ( virtual/libintl )
  31         opengl? (
  32                 media-libs/glew:0=
  33                 virtual/opengl
  34         )
  35         sound? (
  36                 media-libs/libogg
  37                 media-libs/libvorbis
  38                 media-libs/sdl-mixer[vorbis]
  39         )"
  40 DEPEND="${RDEPEND}"
  41 BDEPEND="
  42         ${PYTHON_DEPS}
  43         virtual/pkgconfig
  44         nls? ( sys-devel/gettext )
  45         sanitize? ( || ( sys-devel/gcc[sanitize] sys-devel/clang-runtime[sanitize] ) )"
  46
  47 S="${WORKDIR}/${PN}-${PV}"
  48
  49 pkg_setup() {
  50         lua-single_pkg_setup
  51         python-any-r1_pkg_setup
  52 }
  53
  54 src_prepare() {
  55         default
  56
  57         python_fix_shebang src/gen_savestruct.py
  58         rm data/sound/speak.py || die # unused, prevent installing
  59
  60         eautoreconf
  61 }
  62
  63 src_configure() {
  64         local econfargs=(
  65                 $(use_enable debug backtrace)
  66                 $(use_enable debug)
  67                 $(use_enable devtools dev-tools)
  68                 $(use_enable nls)
  69                 $(use_enable opengl)
  70                 $(use_enable profile rtprof)
  71                 $(use_enable sound)
  72                 $(use_with debug extra-warnings)
  73                 $(use_enable sanitize sanitize-address)
  74         )
  75         econf "${econfargs[@]}"
  76 }
  77
  78 pkg_postinst() {
  79         xdg_pkg_postinst
  80
  81         if [[ ${REPLACING_VERSIONS} ]]; then
  82                 local min="1.0_rc1"
  83                 if ver_test ${REPLACING_VERSIONS} -lt ${min}; then
  84                         elog "${P} is not compatible with save games before ${min}."
  85                         elog "Please start a new character."
  86                 fi
  87         fi
  88 }