net-libs/liboping/liboping-9999.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=7
   6
   7 inherit autotools git-r3 fcaps
   8
   9 DESCRIPTION="C library and ncurses based program to generate ICMP echo requests and ping multiple hosts at once"
  10 HOMEPAGE="http://noping.cc/"
  11 EGIT_REPO_URI="https://github.com/octo/liboping"
  12
  13 LICENSE="LGPL-2.1 GPL-2"
  14 SLOT="0"
  15 KEYWORDS=""
  16 IUSE="perl"
  17
  18 DEPEND="
  19         sys-libs/ncurses
  20         perl? ( dev-lang/perl )
  21 "
  22 RDEPEND=${DEPEND}
  23
  24 PATCHES=( "${FILESDIR}/${PN}-1.6.2-nouidmagic.patch" )
  25
  26 src_prepare() {
  27         default
  28         eautoreconf
  29 }
  30
  31 src_configure() {
  32         econf \
  33                 $(use_with perl perl-bindings INSTALLDIRS=vendor) \
  34                 --disable-static
  35 }
  36
  37 src_install() {
  38         default
  39         find "${D}" -name '*.la'  -delete || die
  40 }
  41
  42 pkg_postinst() {
  43         fcaps cap_net_raw \
  44                 usr/bin/oping \
  45                 usr/bin/noping
  46 }