support/misc/toolchainfile.cmake.in

   1 #
   2 # Automatically generated file; DO NOT EDIT.
   3 # CMake toolchain file for Buildroot
   4 #
   5
   6 # In order to allow the toolchain to be relocated, we calculate the
   7 # HOST_DIR based on this file's location: $(HOST_DIR)/usr/share/buildroot
   8 # and store it in RELOCATED_HOST_DIR.
   9 # All the other variables that need to refer to HOST_DIR will use the
  10 # RELOCATED_HOST_DIR variable.
  11 string(REPLACE "/usr/share/buildroot" "" RELOCATED_HOST_DIR ${CMAKE_CURRENT_LIST_DIR})
  12
  13 # Point cmake to the location where we have our custom modules,
  14 # so that it can find our custom platform description.
  15 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
  16
  17 set(CMAKE_SYSTEM_NAME Buildroot)
  18 set(CMAKE_SYSTEM_PROCESSOR @@CMAKE_SYSTEM_PROCESSOR@@)
  19
  20 # Set the {C,CXX}FLAGS appended by CMake depending on the build type
  21 # defined by Buildroot. CMake defaults these variables with -g and/or
  22 # -O options, and they are appended at the end of the argument list,
  23 # so the Buildroot options are overridden. Therefore these variables
  24 # have to be cleared, so that the options passed in CMAKE_C_FLAGS do
  25 # apply.
  26 #
  27 # Note:
  28 #   if the project forces some of these flag variables, Buildroot is
  29 #   screwed up and there is nothing Buildroot can do about that :(
  30 set(CMAKE_C_FLAGS_DEBUG "" CACHE STRING "Debug CFLAGS")
  31 set(CMAKE_CXX_FLAGS_DEBUG "" CACHE STRING "Debug CXXFLAGS")
  32 set(CMAKE_C_FLAGS_RELEASE " -DNDEBUG" CACHE STRING "Release CFLAGS")
  33 set(CMAKE_CXX_FLAGS_RELEASE " -DNDEBUG" CACHE STRING "Release CXXFLAGS")
  34
  35 # Build type from the Buildroot configuration
  36 set(CMAKE_BUILD_TYPE @@CMAKE_BUILD_TYPE@@ CACHE STRING "Buildroot build configuration")
  37
  38 # Buildroot defaults flags.
  39 # If you are using this toolchainfile.cmake file outside of Buildroot and
  40 # want to customize the compiler/linker flags, then:
  41 # * set them all on the cmake command line, e.g.:
  42 #     cmake -DCMAKE_C_FLAGS="@@TARGET_CFLAGS@@ -Dsome_custom_flag" ...
  43 # * and make sure the project's CMake code extends them like this if needed:
  44 #     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Dsome_definitions")
  45 set(CMAKE_C_FLAGS "@@TARGET_CFLAGS@@" CACHE STRING "Buildroot CFLAGS")
  46 set(CMAKE_CXX_FLAGS "@@TARGET_CXXFLAGS@@" CACHE STRING "Buildroot CXXFLAGS")
  47 set(CMAKE_EXE_LINKER_FLAGS "@@TARGET_LDFLAGS@@" CACHE STRING "Buildroot LDFLAGS for executables")
  48
  49 set(CMAKE_INSTALL_SO_NO_EXE 0)
  50
  51 set(CMAKE_PROGRAM_PATH "${RELOCATED_HOST_DIR}/usr/bin")
  52 set(CMAKE_SYSROOT "${RELOCATED_HOST_DIR}/@@STAGING_SUBDIR@@")
  53 set(CMAKE_FIND_ROOT_PATH "${RELOCATED_HOST_DIR}/@@STAGING_SUBDIR@@")
  54 set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
  55 set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE ONLY)
  56 set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  57 set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  58 set(ENV{PKG_CONFIG_SYSROOT_DIR} "${RELOCATED_HOST_DIR}/@@STAGING_SUBDIR@@")
  59
  60 # This toolchain file can be used both inside and outside Buildroot.
  61 set(CMAKE_C_COMPILER "${RELOCATED_HOST_DIR}/@@TARGET_CC@@")
  62 set(CMAKE_CXX_COMPILER "${RELOCATED_HOST_DIR}/@@TARGET_CXX@@")
  63 if(@@TOOLCHAIN_HAS_FORTRAN@@)
  64   set(CMAKE_Fortran_FLAGS_DEBUG "" CACHE STRING "Debug Fortran FLAGS")
  65   set(CMAKE_Fortran_FLAGS_RELEASE " -DNDEBUG" CACHE STRING "Release Fortran FLAGS")
  66   set(CMAKE_Fortran_FLAGS "@@TARGET_FCFLAGS@@" CACHE STRING "Buildroot FCFLAGS")
  67   set(CMAKE_Fortran_COMPILER "${RELOCATED_HOST_DIR}/@@TARGET_FC@@")
  68 endif()