Cabal-syntax/src/Distribution/Utils/ShortText.hs

   1 {-# LANGUAGE CPP #-}
   2 {-# LANGUAGE DeriveDataTypeable #-}
   3 {-# LANGUAGE DeriveGeneric #-}
   4
   5 -- | Compact representation of short 'Strings'
   6 --
   7 -- This module is designed to be import qualified
   8 --
   9 -- @
  10 -- import Distribution.Utils.ShortText (ShortText)
  11 -- import qualified Distribution.Utils.ShortText as ShortText
  12 -- @
  13 module Distribution.Utils.ShortText
  14   ( -- * 'ShortText' type
  15     ShortText
  16   , toShortText
  17   , fromShortText
  18   , unsafeFromUTF8BS
  19
  20     -- * Operations
  21   , null
  22   , length
  23
  24     -- * internal utilities
  25   , decodeStringUtf8
  26   , encodeStringUtf8
  27   ) where
  28
  29 import Distribution.Compat.Prelude hiding (length, null)
  30 import Prelude ()
  31
  32 import Distribution.Utils.String (decodeStringUtf8, encodeStringUtf8)
  33 import Distribution.Utils.Structured (Structured (..), nominalStructure)
  34
  35 #if defined(MIN_VERSION_bytestring)
  36 # if MIN_VERSION_bytestring(0,10,4)
  37 # define HAVE_SHORTBYTESTRING 1
  38 # endif
  39 #endif
  40
  41 -- Hack for GHC bootstrapping
  42 --
  43 -- Currently (as of GHC 8.1), GHC bootstraps Cabal by building
  44 -- binary and Cabal in one giant ghc --make command.  This
  45 -- means no MIN_VERSION_binary macro is available.
  46 --
  47 -- We could try to cleverly figure something out in this case,
  48 -- but there is a better plan: just use the unoptimized version
  49 -- of the Binary instance.  We're not going to use it for anything
  50 -- real in any case.
  51 --
  52 -- WARNING: Don't use MIN_VERSION_binary to smooth over a BC-break!
  53 --
  54 #ifndef MIN_VERSION_binary
  55 #define MIN_VERSION_binary(x, y, z) 0
  56 #endif
  57
  58 import qualified Data.ByteString as BS
  59 import qualified Data.List as List
  60
  61 #if HAVE_SHORTBYTESTRING
  62 import qualified Data.ByteString.Short as BS.Short
  63 #else
  64 import Distribution.Utils.Generic (fromUTF8BS)
  65 #endif
  66
  67 -- | Construct 'ShortText' from 'String'
  68 toShortText :: String -> ShortText
  69
  70 -- | Convert 'ShortText' to 'String'
  71 fromShortText :: ShortText -> String
  72
  73 -- | Convert from UTF-8 encoded strict 'ByteString'.
  74 --
  75 -- @since 3.2.0.0
  76 unsafeFromUTF8BS :: BS.ByteString -> ShortText
  77
  78 -- | Text whether 'ShortText' is empty.
  79 --
  80 -- @since 3.2.0.0
  81 null :: ShortText -> Bool
  82
  83 -- | Compact representation of short 'Strings'
  84 --
  85 -- The data is stored internally as UTF8 in an
  86 -- 'BS.Short.ShortByteString' when compiled against @bytestring >=
  87 -- 0.10.4@, and otherwise the fallback is to use plain old non-compat
  88 -- '[Char]'.
  89 --
  90 -- Note: This type is for internal uses (such as e.g. 'PackageName')
  91 -- and shall not be exposed in Cabal's API
  92 --
  93 -- @since 2.0.0.2
  94 #if HAVE_SHORTBYTESTRING
  95 newtype ShortText = ST { unST :: BS.Short.ShortByteString }
  96                   deriving (Eq,Ord,Generic,Data,Typeable)
  97
  98 # if MIN_VERSION_binary(0,8,1)
  99 instance Binary ShortText where
 100     put = put . unST
 101     get = fmap ST get
 102 # else
 103 instance Binary ShortText where
 104     put = put . BS.Short.fromShort . unST
 105     get = fmap (ST . BS.Short.toShort) get
 106 # endif
 107
 108
 109 toShortText = ST . BS.Short.pack . encodeStringUtf8
 110
 111 fromShortText = decodeStringUtf8 . BS.Short.unpack . unST
 112
 113 unsafeFromUTF8BS = ST . BS.Short.toShort
 114
 115 null = BS.Short.null . unST
 116 #else
 117 newtype ShortText = ST { unST :: String }
 118                   deriving (Eq,Ord,Generic,Data,Typeable)
 119
 120 instance Binary ShortText where
 121     put = put . encodeStringUtf8 . unST
 122     get = fmap (ST . decodeStringUtf8) get
 123
 124 toShortText = ST
 125
 126 fromShortText = unST
 127
 128 unsafeFromUTF8BS = ST . fromUTF8BS
 129
 130 null = List.null . unST
 131 #endif
 132
 133 instance Structured ShortText where structure = nominalStructure
 134
 135 instance NFData ShortText where
 136   rnf = rnf . unST
 137
 138 instance Show ShortText where
 139   show = show . fromShortText
 140
 141 instance Read ShortText where
 142   readsPrec p = map (first toShortText) . readsPrec p
 143
 144 instance Semigroup ShortText where
 145   ST a <> ST b = ST (mappend a b)
 146
 147 instance Monoid ShortText where
 148   mempty = ST mempty
 149   mappend = (<>)
 150
 151 instance IsString ShortText where
 152   fromString = toShortText
 153
 154 -- | /O(n)/. Length in characters. /Slow/ as converts to string.
 155 --
 156 -- @since 3.2.0.0
 157 length :: ShortText -> Int
 158 length = List.length . fromShortText
 159
 160 -- Note: avoid using it, we use it @cabal check@ implementation, where it's ok.