acinclude.m4

   1 dnl -*- mode: autoconf -*-
   2
   3 # serial 1
   4
   5 dnl Usage:
   6 dnl   GTK_DOC_CHECK([minimum-gtk-doc-version])
   7 AC_DEFUN([GTK_DOC_CHECK],
   8 [
   9   AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
  10   AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
  11   dnl for overriding the documentation installation directory
  12   AC_ARG_WITH(html-dir,
  13     AC_HELP_STRING([--with-html-dir=PATH], [path to installed docs]),,
  14     [with_html_dir='${datadir}/gtk-doc/html'])
  15   HTML_DIR="$with_html_dir"
  16   AC_SUBST(HTML_DIR)
  17
  18   dnl enable/disable documentation building
  19   AC_ARG_ENABLE(gtk-doc,
  20     AC_HELP_STRING([--enable-gtk-doc],
  21                    [use gtk-doc to build documentation [default=no]]),,
  22     enable_gtk_doc=no)
  23
  24   have_gtk_doc=no
  25   if test x$enable_gtk_doc = xyes; then
  26     if test -z "$PKG_CONFIG"; then
  27       AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  28     fi
  29     if test "$PKG_CONFIG" != "no" && $PKG_CONFIG --exists gtk-doc; then
  30       have_gtk_doc=yes
  31     fi
  32
  33   dnl do we want to do a version check?
  34 ifelse([$1],[],,
  35     [gtk_doc_min_version=$1
  36     if test "$have_gtk_doc" = yes; then
  37       AC_MSG_CHECKING([gtk-doc version >= $gtk_doc_min_version])
  38       if $PKG_CONFIG --atleast-version $gtk_doc_min_version gtk-doc; then
  39         AC_MSG_RESULT(yes)
  40       else
  41         AC_MSG_RESULT(no)
  42         have_gtk_doc=no
  43       fi
  44     fi
  45 ])
  46     if test "$have_gtk_doc" != yes; then
  47       enable_gtk_doc=no
  48     fi
  49   fi
  50
  51   AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
  52   AM_CONDITIONAL(GTK_DOC_USE_LIBTOOL, test -n "$LIBTOOL")
  53 ])
  54
  55 # AX_C_FLOAT_WORDS_BIGENDIAN ([ACTION-IF-TRUE], [ACTION-IF-FALSE],
  56 #                             [ACTION-IF-UNKNOWN])
  57 #
  58 # Checks the ordering of words within a multi-word float. This check
  59 # is necessary because on some systems (e.g. certain ARM systems), the
  60 # float word ordering can be different from the byte ordering. In a
  61 # multi-word float context, "big-endian" implies that the word containing
  62 # the sign bit is found in the memory location with the lowest address.
  63 # This implemenation was inspired by the AC_C_BIGENDIAN macro in autoconf.
  64 # -------------------------------------------------------------------------
  65 AC_DEFUN([AX_C_FLOAT_WORDS_BIGENDIAN],
  66   [AC_CACHE_CHECK(whether float word ordering is bigendian,
  67                   ax_cv_c_float_words_bigendian, [
  68
  69 # The endianess is detected by first compiling C code that contains a special
  70 # double float value, then grepping the resulting object file for certain
  71 # strings of ascii values. The double is specially crafted to have a
  72 # binary representation that corresponds with a simple string. In this
  73 # implementation, the string "noonsees" was selected because the individual
  74 # word values ("noon" and "sees") are palindromes, thus making this test
  75 # byte-order agnostic. If grep finds the string "noonsees" in the object
  76 # file, the target platform stores float words in big-endian order. If grep
  77 # finds "seesnoon", float words are in little-endian order. If neither value
  78 # is found, the user is instructed to specify the ordering.
  79
  80 ax_cv_c_float_words_bigendian=unknown
  81 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  82
  83 double d = 90904234967036810337470478905505011476211692735615632014797120844053488865816695273723469097858056257517020191247487429516932130503560650002327564517570778480236724525140520121371739201496540132640109977779420565776568942592.0;
  84
  85 ]])], [
  86
  87 if strings - conftest.$ac_objext | grep noonsees >/dev/null ; then
  88   ax_cv_c_float_words_bigendian=yes
  89 fi
  90 if strings - conftest.$ac_objext | grep seesnoon >/dev/null ; then
  91   if test "$ax_cv_c_float_words_bigendian" = unknown; then
  92     ax_cv_c_float_words_bigendian=no
  93   else
  94     ax_cv_c_float_words_bigendian=unknown
  95   fi
  96 fi
  97
  98 ])])
  99
 100 case $ax_cv_c_float_words_bigendian in
 101   yes)
 102     m4_default([$1],
 103       [AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
 104                  [Define to 1 if your system stores words within floats
 105                   with the most significant word first])]) ;;
 106   no)
 107     $2 ;;
 108   *)
 109     m4_default([$3],
 110       [AC_MSG_ERROR([
 111
 112 Unknown float word ordering. You need to manually preset
 113 ax_cv_c_float_words_bigendian=no (or yes) according to your system.
 114
 115     ])]) ;;
 116 esac
 117
 118 ])# AX_C_FLOAT_WORDS_BIGENDIAN