prj/cam/src/portal/ptsurf.asm

   1 ; $Header: r:/t2repos/thief2/src/portal/ptsurf.asm,v 1.15 1998/04/06 12:43:14 MAT Exp $
   2 ;
   3 ; PORTAL Texture Mappers
   4 ;
   5 ; ptmap.asm
   6 ;   support functions
   7
   8
   9 .486
  10         .nolist
  11
  12         include macros.inc
  13         include lg.inc
  14         include fix.inc
  15         include thunks.inc
  16
  17         .list
  18
  19         assume  cs:_TEXT, ds:_DATA
  20
  21         extd _grd_light_table
  22
  23 _DATA   segment dword public USE32 'DATA'
  24
  25         align   4
  26
  27 texture_row dd 0
  28 output_row  dd 0
  29 light_row   dd 0
  30 didy        dd 0
  31 didxdy      dd 0
  32 temp_light1 dd 0
  33 temp_light2 dd 0
  34 tempy       dd 0
  35
  36
  37 ; import
  38 externdef __portal_surface_texture_row: dword
  39 externdef __portal_surface_output_row: dword
  40 externdef __portal_surface_lightmap_row: dword
  41 externdef __portal_surface_texture: dword
  42 externdef __portal_surface_output: dword
  43 externdef __portal_surface_lightmap: dword
  44
  45 _DATA   ends
  46
  47
  48 _TEXT   segment para public USE32 'CODE'
  49
  50
  51 ; eax i
  52 ; ebx light table
  53 ; ecx bytes being processed
  54 ; edx bytes being processed
  55 ; esi source
  56 ; edi dest
  57 ; ebp didx
  58 pt_buildspan_8:
  59         mov  ch,ah
  60         add  eax,ebp
  61
  62         mov  cl,[esi]
  63         mov  dh,ah
  64
  65         mov  dl,[esi+1]
  66         add  eax,ebp
  67
  68         mov  cl,[ebx+ecx]
  69         nop
  70
  71         mov  dl,[ebx+edx]
  72         mov  [edi],cl
  73
  74         mov  ch,ah
  75         add  eax,ebp
  76
  77         mov  cl,[esi+2]
  78         mov  dh,ah
  79
  80         mov  [edi+1],dl
  81         mov  dl,[esi+3]
  82
  83         mov  cl,[ebx+ecx]
  84         add  eax,ebp
  85
  86         mov  [edi+2],cl
  87         mov  ch,ah
  88
  89         add  eax,ebp
  90         mov  dl,[ebx+edx]
  91
  92         mov  cl,[esi+4]
  93         mov  dh,ah
  94
  95         mov  [edi+3],dl
  96         mov  dl,[esi+5]
  97
  98         mov  cl,[ebx+ecx]
  99         add  eax,ebp
 100
 101         mov  dl,[ebx+edx]
 102         mov  [edi+4],cl
 103
 104         mov  ch,ah
 105         add  eax,ebp
 106
 107         mov  cl,[esi+6]
 108         mov  dh,ah
 109
 110         mov  [edi+5],dl
 111         mov  dl,[esi+7]
 112
 113         mov  cl,[ebx+ecx]
 114         add  eax,ebp
 115
 116         mov  [edi+6],cl
 117         mov  dl,[ebx+edx]
 118
 119         mov  [edi+7],dl
 120         ret
 121
 122
 123
 124
 125 pt_buildspan_8_x:
 126         mov  ecx,eax
 127         add  eax,ebp
 128         shr  ecx,8
 129
 130         mov  cl,[esi]
 131         mov  edx,eax
 132         shr  edx,8
 133
 134         mov  dl,[esi+1]
 135         add  eax,ebp
 136
 137         mov  cl,[ebx+ecx]
 138         nop
 139
 140         mov  dl,[ebx+edx]
 141         mov  [edi],cl
 142
 143         mov  ecx,eax
 144         add  eax,ebp
 145         shr  ecx,8
 146
 147         mov  cl,[esi+2]
 148         mov  edx,eax
 149         shr  edx,8
 150
 151         mov  [edi+1],dl
 152         mov  dl,[esi+3]
 153
 154         mov  cl,[ebx+ecx]
 155         add  eax,ebp
 156
 157         mov  [edi+2],cl
 158         mov  ecx,eax
 159         shr  ecx,8
 160
 161         add  eax,ebp
 162         mov  dl,[ebx+edx]
 163
 164         mov  cl,[esi+4]
 165         mov  edx,eax
 166         shr  edx,8
 167
 168         mov  [edi+3],dl
 169         mov  dl,[esi+5]
 170
 171         mov  cl,[ebx+ecx]
 172         add  eax,ebp
 173
 174         mov  dl,[ebx+edx]
 175         mov  [edi+4],cl
 176
 177         mov  ecx,eax
 178         shr  ecx,8
 179         add  eax,ebp
 180
 181         mov  cl,[esi+6]
 182         mov  edx,eax
 183         shr  edx,8
 184
 185         mov  [edi+5],dl
 186         mov  dl,[esi+7]
 187
 188         mov  cl,[ebx+ecx]
 189         add  eax,ebp
 190
 191         mov  [edi+6],cl
 192         mov  dl,[ebx+edx]
 193
 194         mov  [edi+7],dl
 195         ret
 196
 197   ;   ESI   =  texture source
 198   ;   EDI   =  output location
 199   ;   EDX   =  lightmap source
 200
 201   ;   EAX   =  texture row
 202   ;   EBX   =  output row
 203   ;   ECX   =  lightmap row
 204 _FUNCDEF_ASM pt_surfbuild_16
 205         push  ebp
 206         push  esi
 207
 208         push  eax
 209         push  ebx
 210
 211         push  ecx
 212         push  edx
 213
 214         push  edi
 215         mov   eax, [__portal_surface_texture_row]
 216
 217         mov   ebx, [__portal_surface_output_row]
 218         mov   ebp, [__portal_surface_lightmap_row]
 219
 220         mov   edx, [__portal_surface_lightmap]
 221         sub   eax, 8
 222
 223         mov   esi, [__portal_surface_texture]
 224         sub   ebx,8
 225
 226         mov   texture_row, eax
 227         mov   output_row, ebx
 228
 229         mov   bl,[edx]
 230         mov   cl,[edx + ebp + 1]
 231
 232         mov   bh, [edx + 1]
 233         mov   ch, [edx + ebp]
 234
 235         and   ebx, 0f0f0h       ; mask off all but upper 4 bits of light levels
 236         and   ecx, 0f0f0h
 237
 238         mov   edi, [__portal_surface_output]
 239         cmp   ebx, ecx
 240
 241         jne   pt_surfbuild_gouraud_16
 242
 243         cmp   cl, ch
 244
 245         je    pt_surfbuild_uniform_16
 246
 247 pt_surfbuild_gouraud_16:
 248         xor   eax,eax
 249         xor   ebx,ebx
 250
 251         mov   al, [edx]
 252         xor   ecx, ecx
 253
 254         mov   bl, [edx+1]
 255         mov   cl, [edx+ebp]
 256
 257         sub   ebx,eax       ; ebx == di(0)dx * 16
 258         mov   dl,[edx+ebp+1]
 259
 260         shl   eax,4         ; eax == i(0)*16
 261         and   edx,0ffh
 262
 263         sub   edx,ecx       ; edx == di(16)dx * 16
 264
 265         shl   ecx,4         ; ecx == i(16)*16
 266         sub   edx,ebx       ; edx == di(0)dxdy * 256
 267
 268         shl   ebx,4         ; ebx == di(0)dx * 64
 269         sub   ecx,eax       ; ecx == di(0)dy * 256
 270
 271         shl   eax,4         ; eax == i(0)*256
 272         mov   didy,ecx
 273
 274         xor   ecx,ecx
 275         mov   didxdy,edx
 276
 277         mov   ebp,ebx
 278         mov   ebx,_grd_light_table
 279
 280         xor   edx,edx
 281         mov   ecx, 16
 282
 283         ; eax =  0..15 * 256*16
 284         ; eax derived from number from 0..255, so
 285         ; eax = 0..255 * 256
 286
 287 pt_surf16_looptop:
 288         push  eax
 289         push  ecx
 290
 291         shr   eax, 4
 292         mov   edx, ebp
 293
 294         shr   edx, 28           ; round negative didx towards 0
 295         push  ebp
 296
 297         mov   cl,[edi]          ; cache prefetch
 298         add   ebp, edx
 299
 300         sar   ebp, 4
 301         call  pt_buildspan_8
 302
 303         add   esi, 8
 304         add   edi, 8
 305
 306         mov   cl,[edi]          ; cache prefetch
 307         call  pt_buildspan_8
 308
 309         add   esi,texture_row
 310         add   edi,output_row
 311
 312         ; wait for 2-cycle instructions
 313
 314         pop   ebp
 315         pop   ecx
 316         pop   eax
 317
 318         add   eax,didy
 319         add   ebp,didxdy
 320
 321         ; wait for 2-cycle instructions
 322
 323         dec   ecx
 324         jnz   pt_surf16_looptop
 325
 326         jmp   pt_surfbuild_done_16
 327
 328 pt_surfbuild_uniform_16:
 329         shr   ebx, 4
 330         mov   ebp, _grd_light_table
 331
 332         mov   eax, ebx
 333         mov   ecx, ebx
 334
 335         mov   edx, ebx
 336         mov   texture_row, 16
 337
 338 pt_surfbuild_uniform_16_loop:
 339         mov   al, [edi] ; prefetch
 340         nop
 341
 342         ; first set of 4 texels
 343         mov al, [esi]
 344         mov bl, [esi + 4]
 345
 346         mov cl, [esi + 8]
 347         mov dl, [esi + 12]
 348
 349         mov al, [eax + ebp]
 350         mov bl, [ebx + ebp]
 351
 352         mov cl, [ecx + ebp]
 353         mov dl, [edx + ebp]
 354
 355         mov [edi], al
 356         mov [edi + 4], bl
 357
 358         mov [edi + 8], cl
 359         mov [edi + 12], dl
 360
 361         ; second set of 4 texels
 362         mov al, [esi + 1]
 363         mov bl, [esi + 5]
 364
 365         mov cl, [esi + 9]
 366         mov dl, [esi + 13]
 367
 368         mov al, [eax + ebp]
 369         mov bl, [ebx + ebp]
 370
 371         mov cl, [ecx + ebp]
 372         mov dl, [edx + ebp]
 373
 374         mov [edi + 1], al
 375         mov [edi + 5], bl
 376
 377         mov [edi + 9], cl
 378         mov [edi + 13], dl
 379
 380         ; third set of 4 texels
 381         mov al, [esi + 2]
 382         mov bl, [esi + 6]
 383
 384         mov cl, [esi + 10]
 385         mov dl, [esi + 14]
 386
 387         mov al, [eax + ebp]
 388         mov bl, [ebx + ebp]
 389
 390         mov cl, [ecx + ebp]
 391         mov dl, [edx + ebp]
 392
 393         mov [edi + 2], al
 394         mov [edi + 6], bl
 395
 396         mov [edi + 10], cl
 397         mov [edi + 14], dl
 398
 399         ; fourth set of 4 texels
 400         mov al, [esi + 3]
 401         mov bl, [esi + 7]
 402
 403         mov cl, [esi + 11]
 404         mov dl, [esi + 15]
 405
 406         mov al, [eax + ebp]
 407         mov bl, [ebx + ebp]
 408
 409         mov cl, [ecx + ebp]
 410         mov dl, [edx + ebp]
 411
 412         mov [edi + 3], al
 413         mov [edi + 7], bl
 414
 415         mov [edi + 11], cl
 416         mov [edi + 15], dl
 417
 418         add esi, [__portal_surface_texture_row]
 419         add edi, __portal_surface_output_row
 420
 421         dec texture_row
 422
 423         jnz pt_surfbuild_uniform_16_loop
 424
 425 pt_surfbuild_done_16:
 426         pop   edi
 427         pop   edx
 428         pop   ecx
 429         pop   ebx
 430         pop   eax
 431         pop   esi
 432         pop   ebp
 433         ret
 434
 435
 436
 437
 438 _FUNCDEF_ASM pt_surfbuild_8
 439         push  ebp
 440         push  esi
 441
 442         push  eax
 443         push  ebx
 444
 445         push  ecx
 446         push  edx
 447
 448         push  edi
 449         mov   eax, [__portal_surface_texture_row]
 450
 451         mov   ebx, [__portal_surface_output_row]
 452         mov   ebp, [__portal_surface_lightmap_row]
 453
 454         mov   edx, [__portal_surface_lightmap]
 455         mov   texture_row,eax
 456
 457         mov   esi, [__portal_surface_texture]
 458         mov   output_row, ebx
 459
 460         mov   bl, [edx]
 461         mov   cl, [edx + ebp + 1]
 462
 463         mov   bh, [edx + ebp]
 464         mov   ch, [edx + 1]
 465
 466         and   ebx, 0f0f0h
 467         and   ecx, 0f0f0h
 468
 469         mov   edi, [__portal_surface_output]
 470         cmp   ebx, ecx
 471
 472         jne   pt_surfbuild_gouraud_8
 473
 474         cmp   cl, ch
 475
 476         je    pt_surfbuild_uniform_8
 477
 478 pt_surfbuild_gouraud_8:
 479         xor   eax,eax
 480         xor   ebx,ebx
 481
 482         mov   al, [edx]
 483         xor   ecx, ecx
 484
 485         mov   bl, [edx+1]
 486         mov   cl, [edx+ebp]
 487
 488         sub   ebx, eax      ; ebx == di(0)dx * 16
 489         mov   dl, [edx+ebp+1]
 490
 491         shl   eax, 3        ; eax == i(0)*8
 492         and   edx, 0ffh
 493
 494         sub   edx,ecx       ; edx == di(16)dx * 16
 495
 496         shl   ecx,3         ; ecx == i(16)*16
 497         sub   edx,ebx       ; edx == di(0)dxdy * 256
 498
 499         shl   ebx,3         ; ebx == di(0)dx * 64
 500         sub   ecx,eax       ; ecx == di(0)dy * 256
 501
 502         shl   eax,3         ; eax == i(0)*256
 503         mov   didy,ecx
 504
 505         xor   ecx,ecx
 506         mov   didxdy,edx
 507
 508         mov   ebp,ebx
 509         mov   ebx,_grd_light_table
 510
 511         xor   edx,edx
 512         mov   ecx,8
 513
 514 pt_surf8_looptop:
 515         push  eax
 516         push  ecx
 517
 518         shr   eax, 2
 519         mov   edx, ebp
 520
 521         shr   edx, 30           ; round negative didx towards 0
 522         push  ebp
 523
 524         mov   cl,[edi]          ; cache prefetch
 525         add   ebp, edx
 526
 527         sar   ebp, 2
 528         call  pt_buildspan_8
 529
 530         add   esi,texture_row
 531         add   edi,output_row
 532
 533         ; wait for 2-cycle instructions
 534
 535         pop   ebp
 536         pop   ecx
 537         pop   eax
 538
 539         add   eax,didy
 540         add   ebp,didxdy
 541
 542         ; wait for 2-cycle instructions
 543
 544         dec   ecx
 545         jnz   pt_surf8_looptop
 546
 547         jmp   pt_surfbuild_done_8
 548
 549 pt_surfbuild_uniform_8:
 550         shr   ebx, 4
 551         mov   ebp, [_grd_light_table]
 552
 553         mov   eax, ebx
 554         mov   ecx, ebx
 555
 556         mov   edx, ebx
 557         mov   texture_row, 8
 558
 559 pt_surfbuild_uniform_8_loop:
 560         mov   al, [edi] ; prefetch
 561         nop
 562
 563         ; first set of 4 texels
 564         mov al, [esi]
 565         mov bl, [esi + 4]
 566
 567         mov cl, [esi + 2]
 568         mov dl, [esi + 6]
 569
 570         mov al, [eax + ebp]
 571         mov bl, [ebx + ebp]
 572
 573         mov cl, [ecx + ebp]
 574         mov dl, [edx + ebp]
 575
 576         mov [edi], al
 577         mov [edi + 4], bl
 578
 579         mov [edi + 2], cl
 580         mov [edi + 6], dl
 581
 582         ; second set of 4 texels
 583         mov al, [esi + 1]
 584         mov bl, [esi + 5]
 585
 586         mov cl, [esi + 3]
 587         mov dl, [esi + 7]
 588
 589         mov al, [eax + ebp]
 590         mov bl, [ebx + ebp]
 591
 592         mov cl, [ecx + ebp]
 593         mov dl, [edx + ebp]
 594
 595         mov [edi + 1], al
 596         mov [edi + 5], bl
 597
 598         mov [edi + 3], cl
 599         mov [edi + 7], dl
 600
 601         add esi, [__portal_surface_texture_row]
 602         add edi, [__portal_surface_output_row]
 603
 604         dec texture_row
 605         jnz pt_surfbuild_uniform_8_loop
 606
 607 pt_surfbuild_done_8:
 608         pop   edi
 609         pop   edx
 610         pop   ecx
 611         pop   ebx
 612         pop   eax
 613         pop   esi
 614         pop   ebp
 615         ret
 616
 617
 618 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 619 ;
 620 ; pt_surfbuild_4
 621 ;
 622 _FUNCDEF_ASM pt_surfbuild_4
 623         push  edx
 624         push  edi
 625
 626         push  eax
 627         push  esi
 628
 629         push  ecx
 630         push  ebx
 631
 632         push  ebp
 633         mov   edi, [__portal_surface_output]
 634
 635         mov   ebp, [__portal_surface_lightmap_row]
 636         mov   al, [edi]         ;  prefetch first row
 637
 638         mov   esi, [__portal_surface_texture]
 639         mov   edx, [__portal_surface_lightmap]
 640
 641 ; setup has four light levels--            a---b
 642 ; we want our results x16                  |   |
 643 ; for our light table lookups              c---d
 644
 645         xor   eax, eax
 646         xor   ecx, ecx
 647
 648         mov   al, [edx]
 649         mov   cl, [edx + ebp]
 650
 651         mov   bl, [edx + 1]
 652         mov   dl, [edx + ebp + 1]
 653
 654         and   ebx, 0ffh
 655         and   edx, 0ffh
 656
 657         sub   edx, ecx
 658         mov   ebp, ebx
 659
 660         sub   ecx, eax
 661         sub   ebp, eax
 662
 663         shl   ebp, 2            ; initial didx = (-4a + 4b) / 16
 664         add   edx, eax
 665
 666         shl   ecx, 2            ; didy = (-4a + 4c) / 16
 667         sub   edx, ebx          ; didxdy = (a - b - c + d) / 16
 668
 669         shl   eax, 4            ; i0 = (16a) / 16
 670         mov   [didy], ecx
 671
 672         mov   [didxdy], edx
 673         mov   dl, [edi + 0999999h];  prefetch second row
 674 row_4_self_mod_1:
 675
 676 ; eax   left edge intensity
 677 ; ebx   first point being processed
 678 ; ecx   second point being processed
 679 ; edx   output bytes
 680 ; esi   source texture
 681 ; edi   surface being built + misc.
 682 ; ebp   didx
 683
 684         lea   ebx, [eax + 2 * ebp]
 685         lea   ecx, [eax + 2 * ebp]
 686
 687         mov   bl, [esi + 2]     ; We process the right-hand texels first
 688         add   ecx, ebp          ; so we can shift them into upper 16 of edx.
 689
 690         mov   cl, [esi + 3]
 691         mov   edi, [didxdy]
 692
 693         mov   dl, [ebx + 0999999h]; self-modifying reference to light table
 694 gouraud_4_self_mod_1:
 695         mov   ebx, eax
 696
 697         mov   dh, [ecx + 0999999h]
 698 gouraud_4_self_mod_2:
 699         lea   ecx, [eax + ebp]
 700
 701         shl   edx, 16
 702         mov   bl, [esi]
 703
 704         mov   cl, [esi + 1]
 705         add   ebp, edi          ; didx += didxdy
 706
 707         mov   dl, [ebx + 0999999h]
 708 gouraud_4_self_mod_3:
 709         mov   edi, [__portal_surface_output]
 710
 711         mov   dh, [ecx + 0999999h]
 712 gouraud_4_self_mod_4:
 713         mov   ebx, [didy]
 714
 715         mov   ecx, [__portal_surface_texture_row]
 716         add   eax, ebx          ; left edge i += didy
 717
 718         mov   [edi], edx
 719         add   esi, ecx          ; texture pointer += texture row
 720
 721         mov   dl, [edi + 0999999h]   ;  prefetch third row
 722 row_4_self_mod_2:
 723         nop
 724
 725 ; second row
 726         lea   ebx, [eax + 2 * ebp]
 727         lea   ecx, [eax + 2 * ebp]
 728
 729         mov   bl, [esi + 2]     ; We process the second pair of texels first
 730         add   ecx, ebp          ; so we can shift them into upper 16 of edx.
 731
 732         mov   cl, [esi + 3]
 733         mov   edi, [didxdy]
 734
 735         mov   dl, [ebx + 0999999h]; self-modifying reference to light table
 736 gouraud_4_self_mod_5:
 737         mov   ebx, eax
 738
 739         mov   dh, [ecx + 0999999h]
 740 gouraud_4_self_mod_6:
 741         lea   ecx, [eax + ebp]
 742
 743         shl   edx, 16
 744         mov   bl, [esi]
 745
 746         mov   cl, [esi + 1]
 747         add   ebp, edi          ; didx += didxdy
 748
 749         mov   dl, [ebx + 0999999h]
 750 gouraud_4_self_mod_7:
 751         mov   edi, [__portal_surface_output]
 752
 753         mov   dh, [ecx + 0999999h]
 754 gouraud_4_self_mod_8:
 755         mov   ebx, [didy]
 756
 757         mov   ecx, [__portal_surface_texture_row]
 758         add   eax, ebx          ; left edge i += didy
 759
 760         mov   [edi + 0999999h], edx
 761 row_4_self_mod_3:
 762         add   esi, ecx          ; texture pointer += texture row
 763
 764         mov   dl, [edi + 0999999h];  prefetch fourth row
 765 row_4_self_mod_4:
 766         nop
 767
 768 ; third row
 769         lea   ebx, [eax + 2 * ebp]
 770         lea   ecx, [eax + 2 * ebp]
 771
 772         mov   bl, [esi + 2]     ; We process the second pair of texels first
 773         add   ecx, ebp          ; so we can shift them into upper 16 of edx.
 774
 775         mov   cl, [esi + 3]
 776         mov   edi, [didxdy]
 777
 778         mov   dl, [ebx + 0999999h]; self-modifying reference to light table
 779 gouraud_4_self_mod_9:
 780         mov   ebx, eax
 781
 782         mov   dh, [ecx + 0999999h]
 783 gouraud_4_self_mod_10:
 784         lea   ecx, [eax + ebp]
 785
 786         shl   edx, 16
 787         mov   bl, [esi]
 788
 789         mov   cl, [esi + 1]
 790         add   ebp, edi          ; didx += didxdy
 791
 792         mov   dl, [ebx + 0999999h]
 793 gouraud_4_self_mod_11:
 794         mov   edi, [__portal_surface_output]
 795
 796         mov   dh, [ecx + 0999999h]
 797 gouraud_4_self_mod_12:
 798         mov   ebx, [didy]
 799
 800         mov   ecx, [__portal_surface_texture_row]
 801         add   eax, ebx          ; left edge i += didy
 802
 803         mov   [edi + 0999999h], edx
 804 row_4_self_mod_5:
 805         add   esi, ecx          ; texture pointer += texture row
 806
 807 ; fourth row
 808         lea   ebx, [eax + 2 * ebp]
 809         lea   ecx, [eax + 2 * ebp]
 810
 811         mov   bl, [esi + 2]     ; We process the second pair of texels first
 812         add   ecx, ebp          ; so we can shift them into upper 16 of edx.
 813
 814         mov   cl, [esi + 3]
 815         nop
 816
 817         mov   dl, [ebx + 0999999h]; self-modifying reference to light table
 818 gouraud_4_self_mod_13:
 819         mov   ebx, eax
 820
 821         mov   dh, [ecx + 0999999h]
 822 gouraud_4_self_mod_14:
 823         lea   ecx, [eax + ebp]
 824
 825         shl   edx, 16
 826         mov   bl, [esi]
 827
 828         mov   cl, [esi + 1]
 829         pop   ebp
 830
 831         mov   dl, [ebx + 0999999h]
 832 gouraud_4_self_mod_15:
 833         pop   ebx
 834
 835         mov   dh, [ecx + 0999999h]
 836 gouraud_4_self_mod_16:
 837         pop   ecx
 838
 839         pop   esi
 840         pop   eax
 841
 842         mov   [edi + 0999999h], edx
 843 row_4_self_mod_6:
 844
 845         pop   edi
 846         pop   edx
 847         ret
 848
 849
 850 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 851 ;
 852 ; pt_surfbuild_2
 853 ;
 854 _FUNCDEF_ASM pt_surfbuild_2
 855
 856         push  eax
 857         push  ebx
 858
 859         push  ecx
 860         push  edx
 861
 862         push  esi
 863         push  edi
 864
 865         xor   ecx, ecx
 866         xor   edx, edx
 867
 868         ; We'll build one pixel/light combo in ecx and one in edx.
 869         ; While the light for the upper-left pixel is raw data, the
 870         ; light for the upper-right is the average of two values.
 871         mov   edi, [_grd_light_table]
 872         mov   esi, [__portal_surface_lightmap]
 873
 874         mov   ebx, [__portal_surface_texture]
 875         mov   al, [edi]          ; prefetch
 876
 877         mov   cl, [esi]
 878         mov   dl, [esi + 1]
 879
 880         add   edx, ecx
 881         mov [temp_light1], ecx  ; We'll be averaging these light values
 882
 883         ; We move our light bytes into ch and dh with bit shifts to
 884         ; get them down to 4 bits each.
 885         shl   ecx, 4
 886         mov [temp_light2], edx  ; with others for the lower pixels.
 887
 888         shl   edx, 3            ; average of two lightmap points
 889         mov   cl, [ebx]
 890
 891         mov   dl, [ebx + 1]
 892         mov   cl, [edi + ecx]   ; clut upper-left
 893
 894         mov   eax, [__portal_surface_output]
 895         mov   dl, [edi + edx]   ; clut upper-right
 896
 897         mov   [eax], cl
 898         mov   [eax + 1], dl
 899
 900         add   esi, [__portal_surface_lightmap_row]
 901
 902         ; The light for the lower two pixels is a little more involved
 903         ; since they are both averages.
 904         xor   ecx, ecx
 905         xor   edx, edx
 906
 907         mov   cl, [esi]
 908         mov   dl, [esi + 1]
 909
 910         add   edx, [temp_light2]; average of two right-hand lights
 911         add   ebx, [__portal_surface_texture_row]
 912
 913         add   edx, ecx          ; lower-right light * 4
 914         add   eax, [__portal_surface_output_row]
 915
 916         add   ecx, [temp_light1]; lower-left light * 2
 917
 918         shl   edx, 2            ; average of four lightmap points
 919
 920         shl   ecx, 3            ; average of two lightmap points
 921
 922         mov   cl, [ebx]         ; get texture points
 923         mov   dl, [ebx + 1]
 924
 925         mov   cl, [edi + ecx]   ; clut upper-left
 926         mov   dl, [edi + edx]   ; clut upper-right
 927
 928         mov   [eax], cl
 929         mov   [eax + 1], dl
 930
 931         pop   edi
 932         pop   esi
 933         pop   edx
 934         pop   ecx
 935         pop   ebx
 936         pop   eax
 937
 938         ret
 939
 940
 941 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 942 ;
 943 ; pt_surfbuild_1
 944 ;
 945 ; We prefetch here since this is called on seqential bytes.
 946 ;
 947 _FUNCDEF_ASM pt_surfbuild_1
 948         push  eax
 949         push  edx
 950
 951         push  ebx
 952         push  ecx
 953
 954         mov   eax, [__portal_surface_lightmap]
 955         mov   ebx, [__portal_surface_output]
 956
 957         xor   edx, edx
 958         mov   ecx, [__portal_surface_texture]
 959
 960         mov   dh, [eax]         ; high byte is light level
 961         mov   al, [ebx]         ; prefetch
 962
 963         shr   dh, 4             ; 16 levels of shading
 964         mov   eax, [_grd_light_table]
 965
 966         mov   dl, [ecx]         ; low byte is texture data
 967
 968         mov   al, [eax + edx]   ; translate light
 969         pop   ecx
 970
 971         mov   [ebx], al
 972         pop   ebx
 973
 974         pop   edx
 975         pop   eax
 976
 977         ret
 978
 979
 980 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 981 ;
 982 ; voif pt_surfbuild_setup (void)
 983 ;
 984 ; These set up some self-modifying offsets.  Actually, only one of
 985 ; them does.
 986
 987 _FUNCDEF_ASM pt_surfbuild_setup_1
 988         ret
 989
 990 _FUNCDEF_ASM pt_surfbuild_setup_2
 991         ret
 992
 993 _FUNCDEF_ASM pt_surfbuild_setup_4
 994         push   eax
 995         push   edx
 996
 997         mov    eax, [_grd_light_table]
 998         mov    edx, dword ptr ds:[gouraud_4_self_mod_1 - 4]
 999
1000         cmp    eax, edx
1001         je     pt_surfbuild_setup_4_light_done
1002
1003         mov    dword ptr ds:gouraud_4_self_mod_1  - 4, eax
1004         mov    dword ptr ds:gouraud_4_self_mod_2  - 4, eax
1005         mov    dword ptr ds:gouraud_4_self_mod_3  - 4, eax
1006         mov    dword ptr ds:gouraud_4_self_mod_4  - 4, eax
1007         mov    dword ptr ds:gouraud_4_self_mod_5  - 4, eax
1008         mov    dword ptr ds:gouraud_4_self_mod_6  - 4, eax
1009         mov    dword ptr ds:gouraud_4_self_mod_7  - 4, eax
1010         mov    dword ptr ds:gouraud_4_self_mod_8  - 4, eax
1011         mov    dword ptr ds:gouraud_4_self_mod_9  - 4, eax
1012         mov    dword ptr ds:gouraud_4_self_mod_10 - 4, eax
1013         mov    dword ptr ds:gouraud_4_self_mod_11 - 4, eax
1014         mov    dword ptr ds:gouraud_4_self_mod_12 - 4, eax
1015         mov    dword ptr ds:gouraud_4_self_mod_13 - 4, eax
1016         mov    dword ptr ds:gouraud_4_self_mod_14 - 4, eax
1017         mov    dword ptr ds:gouraud_4_self_mod_15 - 4, eax
1018         mov    dword ptr ds:gouraud_4_self_mod_16 - 4, eax
1019
1020 pt_surfbuild_setup_4_light_done:
1021         mov   eax, __portal_surface_output_row
1022         mov   edx, dword ptr ds:[gouraud_4_self_mod_1 - 4]
1023
1024         cmp    eax, edx
1025         je     pt_surfbuild_setup_4_row_done
1026
1027         mov    dword ptr ds:row_4_self_mod_1 - 4, eax
1028         mov    dword ptr ds:row_4_self_mod_3 - 4, eax
1029
1030         lea    edx, [eax + eax * 2]     ; row * 3
1031         add    eax, eax                 ; row * 2
1032
1033         mov    dword ptr ds:row_4_self_mod_4 - 4, edx
1034         mov    dword ptr ds:row_4_self_mod_6 - 4, edx
1035
1036         mov    dword ptr ds:row_4_self_mod_2 - 4, eax
1037         mov    dword ptr ds:row_4_self_mod_5 - 4, eax
1038
1039 pt_surfbuild_setup_4_row_done:
1040         pop   edx
1041         pop   eax
1042
1043         ret
1044
1045
1046 _FUNCDEF_ASM pt_surfbuild_setup_8
1047         ret
1048
1049 _FUNCDEF_ASM pt_surfbuild_setup_16
1050         ret
1051
1052
1053
1054 ;pt_buildspan_8_pal:
1055 ;        mov  cl,ah
1056 ;        add  eax,ebp
1057 ;
1058 ;        mov  ch,ah
1059 ;        add  eax,ebp
1060 ;
1061 ;        mov  dl,ah
1062 ;        add  eax,ebp
1063 ;
1064 ;        mov  dh,ah
1065 ;        add  eax,ebp
1066 ;
1067 ;        shl  edx,16
1068 ;        and  ecx,0ffffh
1069 ;
1070 ;        or   edx,ecx
1071 ;        mov  ecx,[esi]
1072 ;
1073 ;        add  edx,ecx
1074 ;        mov  cl,ah
1075 ;
1076 ;        mov  [edi],edx
1077 ;        add  eax,ebp
1078 ;
1079 ;        mov  ch,ah
1080 ;        add  eax,ebp
1081 ;
1082 ;        mov  dl,ah
1083 ;        add  eax,ebp
1084 ;
1085 ;        mov  dh,ah
1086 ;        add  eax,ebp
1087 ;
1088 ;        shl  edx,16
1089 ;        and  ecx,0ffffh
1090 ;
1091 ;        or   edx,ecx
1092 ;        mov  ecx,[esi]
1093 ;
1094 ;        add  edx,ecx
1095 ;
1096 ;        mov  [edi+4],edx
1097 ;        ret
1098 ;
1099 ;  ;   ESI   =  texture source
1100 ;  ;   EDI   =  output location
1101 ;  ;   EDX   =  lightmap source
1102 ;
1103 ;  ;   EAX   =  texture row
1104 ;  ;   EBX   =  output row
1105 ;  ;   ECX   =  lightmap row
1106 ;pt_surfbuild_16_pal:
1107 ;        push  ebp
1108 ;        sub   eax,8
1109 ;
1110 ;        mov   texture_row,eax
1111 ;        sub   ebx,8
1112 ;
1113 ;        mov   output_row,ebx
1114 ;        mov   ebp,ecx
1115 ;
1116 ;        xor   eax,eax
1117 ;        xor   ebx,ebx
1118 ;
1119 ;        mov   al,[edx]
1120 ;        xor   ecx,ecx
1121 ;
1122 ;        mov   bl,[edx+1]
1123 ;        mov   cl,[edx+ebp]
1124 ;
1125 ;        sub   ebx,eax       ; ebx == di(0)dx * 16
1126 ;        mov   dl,[edx+ebp+1]
1127 ;
1128 ;        shl   eax,4         ; eax == i(0)*16
1129 ;        and   edx,0ffh
1130 ;
1131 ;        sub   edx,ecx       ; edx == di(16)dx * 16
1132 ;
1133 ;        shl   ecx,4         ; ecx == i(16)*16
1134 ;        sub   edx,ebx       ; edx == di(0)dxdy * 256
1135 ;
1136 ;        shl   ebx,4         ; ebx == di(0)dx * 64
1137 ;        sub   ecx,eax       ; ecx == di(0)dy * 256
1138 ;
1139 ;        shl   eax,4         ; eax == i(0)*256
1140 ;        mov   didy,ecx
1141 ;
1142 ;        shr   edx,4
1143 ;        xor   ecx,ecx
1144 ;
1145 ;        shr   ebx,4
1146 ;        mov   didxdy,edx
1147 ;
1148 ;        mov   ebp,ebx
1149 ;        mov   ebx,_grd_light_table
1150 ;
1151 ;        xor   edx,edx
1152 ;        mov   ecx,16
1153 ;
1154 ;pt_surf16_looptop_pal:
1155 ;        push  eax
1156 ;        push  ecx
1157 ;
1158 ;        shr   eax,5
1159 ;        mov   cl,[edi]
1160 ;        shr   ebp,1
1161 ;        call  pt_buildspan_8_pal
1162 ;
1163 ;        add   esi,8
1164 ;        add   edi,8
1165 ;
1166 ;        mov   cl,[edi]
1167 ;        call  pt_buildspan_8_pal
1168 ;
1169 ;        add   esi,texture_row
1170 ;        add   edi,output_row
1171 ;
1172 ;        ; wait for 2-cycle instructions
1173 ;
1174 ;        pop   ecx
1175 ;        pop   eax
1176 ;
1177 ;        add   eax,didy
1178 ;        add   ebp,didxdy
1179 ;
1180 ;        ; wait for 2-cycle instructions
1181 ;
1182 ;        dec   ecx
1183 ;        jnz   pt_surf16_looptop_pal
1184 ;
1185 ;        pop   ebp
1186 ;        ret
1187 ;
1188 ;pt_surfbuild_8_pal:
1189 ;        push  ebp
1190 ;        mov   texture_row,eax
1191 ;
1192 ;        mov   output_row,ebx
1193 ;        mov   ebp,ecx
1194 ;
1195 ;        xor   eax,eax
1196 ;        xor   ebx,ebx
1197 ;
1198 ;        mov   al,[edx]
1199 ;        xor   ecx,ecx
1200 ;
1201 ;        mov   bl,[edx+1]
1202 ;        mov   cl,[edx+ebp]
1203 ;
1204 ;        sub   ebx,eax       ; ebx == di(0)dx * 16
1205 ;        mov   dl,[edx+ebp+1]
1206 ;
1207 ;        shl   eax,3         ; eax == i(0)*16
1208 ;        and   edx,0ffh
1209 ;
1210 ;        sub   edx,ecx       ; edx == di(16)dx * 16
1211 ;
1212 ;        shl   ecx,3         ; ecx == i(16)*16
1213 ;        sub   edx,ebx       ; edx == di(0)dxdy * 256
1214 ;
1215 ;        shl   ebx,3         ; ebx == di(0)dx * 64
1216 ;        sub   ecx,eax       ; ecx == di(0)dy * 256
1217 ;
1218 ;        shl   eax,3         ; eax == i(0)*256
1219 ;        mov   didy,ecx
1220 ;
1221 ;        shr   edx,2
1222 ;        xor   ecx,ecx
1223 ;
1224 ;        shr   ebx,2
1225 ;        mov   didxdy,edx
1226 ;
1227 ;        mov   ebp,ebx
1228 ;        mov   ebx,_grd_light_table
1229 ;
1230 ;        xor   edx,edx
1231 ;        mov   ecx,8
1232 ;
1233 ;pt_surf8_looptop_pal:
1234 ;        push  eax
1235 ;        push  ecx
1236 ;
1237 ;        shr   eax,3
1238 ;        mov   cl,[edi]
1239 ;        shr   ebp,1
1240 ;        call  pt_buildspan_8_pal
1241 ;
1242 ;        add   esi,texture_row
1243 ;        add   edi,output_row
1244 ;
1245 ;        ; wait for 2-cycle instructions
1246 ;
1247 ;        pop   ecx
1248 ;        pop   eax
1249 ;
1250 ;        add   eax,didy
1251 ;        add   ebp,didxdy
1252 ;
1253 ;        ; wait for 2-cycle instructions
1254 ;
1255 ;        dec   ecx
1256 ;        jnz   pt_surf8_looptop_pal
1257 ;
1258 ;        pop   ebp
1259 ;        ret
1260
1261 _TEXT   ends
1262
1263 END