prj/tech/libsrc/g2/ptfloat.asm

   1 ; $Header: x:/prj/tech/libsrc/g2/RCS/ptfloat.asm 1.1 1997/09/23 12:41:38 KEVIN Exp $
   2 ;
   3 ; PORTAL Texture Mappers
   4 ;
   5 ; ptfloat.asm
   6 ;
   7 ; Floating point routines to compute (u,v) and (du,dv)
   8 ; from (a,b,c) and (c*da - a*dc, c*db - b*dc)
   9
  10 .486
  11         .nolist
  12
  13         include macros.inc
  14         include lg.inc
  15         include fix.inc
  16
  17         .list
  18
  19         assume  cs:_TEXT, ds:_DATA
  20
  21 _DATA   segment para public USE32 'DATA'
  22
  23         align   8
  24
  25 _g2pt_u_offset          dq 0
  26 _g2pt_v_offset          dq 0
  27 _g2pt_two_to_52_power   dd 059900000h
  28
  29 extq _g2pt_gda
  30 extq _g2pt_gdb
  31 extq _g2pt_gdc
  32 extq _g2pt_fdc
  33 extq _g2pt_u_step_data
  34 extq _g2pt_v_step_data
  35 extq _g2pt_one
  36 extq _g2pt_float_buf
  37 extq _g2pt_float_buf2
  38 extq _g2pt_u_offset
  39 extq _g2pt_v_offset
  40
  41 extd _g2pt_two_to_52_power
  42 extd _g2pt_int_table
  43
  44 _DATA   ends
  45
  46
  47 _TEXT   segment para public USE32 'CODE'
  48
  49 extn g2tmap_float_uv_start_part_one
  50 extn g2tmap_float_uv_start_part_two
  51 extn g2tmap_float_uv_start_part_two_b
  52 extn g2tmap_float_uv_start_part_two_c
  53 extn g2tmap_float_uv_start
  54 extn g2tmap_float_uv_iterate
  55 extn g2tmap_float_uv_iterate_n
  56 extn g2tmap_float_uv_cleanup
  57
  58 ;
  59 ;
  60 ;   Compute U&V values using overlapped floating point ops
  61 ;
  62 ;
  63
  64 ;
  65 ;   compute a single u,v value directly (no waiting),
  66 ;   and setup for next iterative step based on a passed-in
  67 ;   step size for c
  68
  69 g2tmap_float_uv_start_part_one:
  70          fld     _g2pt_two_to_52_power
  71
  72          fld     qword ptr [eax]
  73
  74          fld     qword ptr 8[eax]
  75
  76          fld     qword ptr 16[eax]    ;   c b a hack
  77
  78          fld     _g2pt_one     ;  1 c b a hack
  79
  80          fld     st(1)    ;  c 1 c b a hack
  81          fxch    st(2)    ;  c 1 c b a hack
  82
  83          fdiv             ;  z c b a hack
  84          fxch    st(3)    ;  a c b z hack
  85
  86          ret
  87
  88 ; pass in eax == integer to multiply dc by
  89 g2tmap_float_uv_start_part_two:
  90
  91     ; while waiting for the divide, prefetch
  92          cmp     eax,_g2pt_int_table[eax*4]       ; fetch it
  93          lea     eax,_g2pt_int_table[eax*4]       ; preaddress
  94
  95          fmul    st,st(3) ; 1    u c b z hack
  96          fxch    st(1)    ;      c (1)u b z hack
  97
  98          fld     st(0)    ; 2    c c (1)u b z hack
  99          fxch    st(3)    ;      b c (1)u c z hack
 100
 101          fmulp   st(4),st ; 3    c (1)u c (3)v hack
 102
 103          fld     _g2pt_fdc     ;
 104
 105          fmul    dword ptr [eax]  ; number of steps
 106
 107          fadd             ;  4   (4)c' (1)u c (3)v hack
 108          fxch    st(1)    ;      (1)u (4)c' c (3)v hack
 109
 110          fadd    _g2pt_u_offset ; 5   (5)iu (4)c' c (3)v hack
 111          fxch    st(3)    ;      (3)v (4)c' c (5)iu hack
 112
 113          fadd    _g2pt_v_offset ; 6   (6)iv (4)c' c (5)iu hack
 114          fxch    st(1)    ;      (4)c' (6)iv c (5)iu hack
 115
 116          fmul    st(2),st ; 7    (4)c' (6)iv (7)c*c' (5)iu hack
 117          fxch    st(1)    ;      (6)iv (4)c' (7)c*c' (5)iu hack
 118
 119          fld     _g2pt_one     ; 8    1 (6)iv (4)c' (7)c*c' (5)iu hack
 120          fxch    st(4)    ;      (5)iu (6)iv (4)c' (7)c*c' 1 hack
 121
 122          fstp    _g2pt_float_buf ; 9   (6)iv c' (7)c*c' 1 hack
 123
 124          fstp    _g2pt_float_buf2 ; 11  c' (7)c*c' 1 hack
 125
 126          fxch    st(2)      ;     1 (7)c*c' c' hack
 127
 128          fdivr              ;     zz c' hack
 129          ret
 130
 131 g2tmap_float_uv_start:
 132          call    g2tmap_float_uv_start_part_one
 133          lea     eax,_g2pt_gdc
 134          call    g2tmap_float_uv_start_part_two
 135          ret
 136
 137 ; compute final u,v values,
 138 ;  and start next computation going
 139
 140 g2tmap_float_uv_iterate:
 141         fld     st(0)    ;  zz zz c hack
 142         fxch    st(2)    ;  c zz zz hack
 143
 144         fld     st(0)    ;  c c zz zz hack
 145         fxch    st(2)    ;  zz c c zz hack
 146
 147         fmul    _g2pt_u_step_data ; du c c zz hack
 148         fxch    st(1)    ;  c du c zz hack
 149
 150         fadd    _g2pt_gdc     ;  c' du c zz hack
 151         fxch    st(3)    ;  zz du c c' hack
 152
 153         fmul    _g2pt_v_step_data ; dv du c c' hack
 154         fxch    st(1)    ;  du dv c c' hack
 155
 156         fadd    st,st(4) ;  idu dv c c' hack
 157         fxch    st(2)    ;  c dv idu c' hack
 158
 159         fmul    st,st(3) ;  c*c' dv idu c' hack
 160         fxch    st(1)    ;  dv c*c' idu c' hack
 161
 162         fadd    st,st(4) ;  idv c*c' idu c' hack
 163         fxch    st(2)    ;  idu c*c' idv c' hack
 164
 165         fstp    _g2pt_float_buf ; c*c' idv c' hack
 166
 167         fld     _g2pt_one     ;  1 c*c' idv c hack
 168         fxch    st(2)    ;  idv c*c' 1 c hack
 169
 170         fstp    _g2pt_float_buf2 ; c*c' 1 c' hack
 171
 172         fdiv             ;  zz c hack
 173
 174         ret
 175
 176 g2tmap_float_uv_iterate_n:
 177         fld     st(0)    ;  zz zz c hack
 178         fxch    st(2)    ;  c zz zz hack
 179
 180         fld     st(0)    ;  c c zz zz hack
 181         fxch    st(2)    ;  zz c c zz hack
 182
 183         fmul    _g2pt_u_step_data ; du c c zz hack
 184         fxch    st(1)    ;  c du c zz hack
 185
 186         fld     _g2pt_fdc
 187
 188         fmul    dword ptr _g2pt_int_table[eax*4]
 189
 190         fadd             ;  c' du c zz hack
 191         fxch    st(3)    ;  zz du c c' hack
 192
 193         fmul    _g2pt_v_step_data ; dv du c c' hack
 194         fxch    st(1)    ;  du dv c c' hack
 195
 196         fadd    st,st(4) ;  idu dv c c' hack
 197         fxch    st(2)    ;  c dv idu c' hack
 198
 199         fmul    st,st(3) ;  c*c' dv idu c' hack
 200         fxch    st(1)    ;  dv c*c' idu c' hack
 201
 202         fadd    st,st(4) ;  idv c*c' idu c' hack
 203         fxch    st(2)    ;  idu c*c' idv c' hack
 204
 205         fstp    _g2pt_float_buf ; c*c' idv c' hack
 206
 207         fld     _g2pt_one     ;  1 c*c' idv c hack
 208         fxch    st(2)    ;  idv c*c' 1 c hack
 209
 210         fstp    _g2pt_float_buf2 ; c*c' 1 c' hack
 211
 212         fdiv             ;  zz c hack
 213
 214         ret
 215
 216 ; clean up the stack
 217 ;  is this really necessary given the circular stack?
 218 g2tmap_float_uv_cleanup:
 219          fstp     _g2pt_float_buf
 220          fstp     _g2pt_float_buf
 221          fstp     _g2pt_float_buf
 222          ret
 223
 224 _TEXT   ends
 225
 226 END