prj/tech/libsrc/g2/ptlinear.asm

   1 ; $Header: x:/prj/tech/libsrc/g2/RCS/ptlinear.asm 1.2 1998/03/23 14:56:29 KEVIN Exp $
   2 ;
   3 ; PORTAL Texture Mappers
   4 ;
   5 ; ptlinear.asm
   6 ;
   7 ; linear outer (per 8 pixel) loops
   8
   9
  10 .486
  11         .nolist
  12
  13         include macros.inc
  14         include lg.inc
  15         include fix.inc
  16         include thunks.inc
  17
  18         .list
  19
  20         assume  cs:_TEXT, ds:_DATA
  21
  22         extd  _g2pt_tmap_mask
  23         extd  _g2pt_tmap_ptr
  24         extd  _g2pt_buffer
  25         extd  _g2pt_lit_buffer
  26
  27         extd  _g2pt_light
  28         extd  _g2pt_dlight
  29
  30         extd   _g2pt_func_n
  31         extd   _g2pt_func_8
  32
  33         extd   _g2pt_dest
  34
  35 _DATA   segment dword public USE32 'DATA'
  36
  37         align   4
  38
  39 dlight_8 dd 0
  40
  41 pixel_count dd 0
  42 scanline_count dd 0
  43
  44 dest_save dd 0
  45 count_save dd 0
  46 pixel_save dd 0
  47
  48 save_ebp dd 0
  49 save_edx dd 0
  50
  51 _DATA   ends
  52
  53
  54 _TEXT   segment para public USE32 'CODE'
  55
  56 ;extn    g2ptmap_run_
  57 ;extn    g2ptmap_flat_run_
  58 ;extn    g2ptmap_lit_run_
  59 ;extn    g2ptmap_setup_uv
  60 extn    g2ptmap_setup_duv
  61 extn    g2ptmap_setup_uvduv
  62 extn    g2pt_compute_light_n
  63 extn    g2pt_compute_light_8
  64
  65 ;  g2ptmap_AFFINE_DUV
  66 ;     eax = DU
  67 ;     edx = DV
  68
  69   _FUNCDEF g2ptmap_affine_duv,2
  70       mov   save_edx,eax
  71       mov   save_ebp,edx
  72
  73       ret
  74
  75
  76 ;     edx = DU
  77 ;     ecx = DV
  78
  79 ;  g2ptmap_RUN
  80 ;
  81 ;  old parms:
  82 ;     esi = count
  83 ;     eax = V
  84 ;     ebx = U
  85 ;     edi = dest
  86 ;
  87 ;  new parms:
  88 ;     eax = dest
  89 ;     edx = count
  90 ;     ebx = U
  91 ;     ecx = V
  92
  93   _FUNCDEF g2ptmap_run,4
  94         push    ebp
  95         push    esi
  96         push    edi
  97
  98         mov     pixel_count,edx
  99
 100         mov     edi,eax
 101         mov     eax,ecx
 102
 103         mov     edx,save_edx
 104         mov     ebp,save_ebp
 105
 106         mov     esi,ebx
 107         mov     ecx,pixel_count
 108
 109 ; check if whole thing is short
 110
 111         cmp     ecx,16
 112         jg      pr_handle_long_case
 113
 114         call    [_g2pt_func_n]
 115
 116         pop     edi
 117         pop     esi
 118         pop     ebp
 119
 120         ret
 121
 122 pr_handle_long_case:
 123
 124 ; now pick up a leading run of 1-7 pixels
 125 ; the length is equal to 8-(edi&7), except
 126 ; we want 0 if edi&7 is 0.  This is just
 127 ; (-edi)&7
 128
 129         mov     ecx,edi
 130
 131         neg     ecx
 132
 133         and     ecx,7
 134         jz      pr_no_leading_run
 135
 136 ; stuff length of leading run
 137
 138         sub     pixel_count,ecx     ; SLOW!
 139         call    [_g2pt_func_n]
 140
 141 pr_no_leading_run:
 142
 143         mov     ecx,pixel_count
 144         mov     _g2pt_dest,edi
 145
 146         shr     ecx,3
 147
 148 pr_pixel_8_loop:
 149         push    ecx
 150         call    [_g2pt_func_8]
 151
 152         pop     ecx
 153         mov     _g2pt_dest,edi
 154
 155         mov     edx,save_edx
 156         mov     ebp,save_ebp
 157
 158         dec     ecx
 159         jnz     pr_pixel_8_loop
 160
 161         mov     ecx,pixel_count
 162
 163         and     ecx,7
 164         jz      pr_no_trailing_run
 165
 166         call    [_g2pt_func_n]
 167
 168 pr_no_trailing_run:
 169         pop     edi
 170         pop     esi
 171         pop     ebp
 172
 173         ret
 174
 175
 176 ;
 177 ;  g2ptmap_LIT_RUN
 178 ;
 179 ;    This has two entry points,
 180 ;    one for C and one for assembly.
 181 ;
 182 ; This is broken under MSVC, cause it
 183 ; takes 6 parameters.  Can we not change
 184 ; this calling convention, like CDECL it
 185 ; or pass in a structure pointer or something
 186 ; or even write a separate entry point
 187 ; for MSVC and ifdef it?
 188 ; BROKEN BROKEN BROKEN
 189 ;
 190 ;  old parms:
 191 ;     edi: dest
 192 ;     esi: count
 193 ;     ebx: u
 194 ;     eax: v
 195 ;     edx: du
 196 ;     ecx: dv
 197 ;
 198 ;  new parms:
 199 ;     eax = dest
 200 ;     edx = count
 201 ;     ebx = U
 202 ;     ecx = V
 203
 204
 205    _FUNCDEF g2ptmap_lit_run,4
 206         push    ebp
 207         push    esi
 208         push    edi
 209         mov     pixel_count,edx
 210
 211         mov     edi,eax
 212         mov     eax,ecx
 213
 214         mov     esi,ebx
 215         mov     ecx,pixel_count
 216
 217         cmp     ecx,16
 218         jg      pl_handle_long_case
 219
 220         call    g2pt_compute_light_n
 221
 222         mov     edx,save_edx     ; du,dv
 223         mov     ebp,save_ebp
 224
 225         call    [_g2pt_func_n]
 226
 227         pop     edi
 228         pop     esi
 229         pop     ebp
 230         ret
 231
 232 pl_handle_long_case:
 233
 234 ; now pick up a leading run of 1-7 pixels
 235 ; the length is equal to 8-(edi&7), except
 236 ; we want 0 if edi&7 is 0.  This is just
 237 ; (-edi)&7
 238
 239         mov     ecx,edi
 240
 241         neg     ecx
 242
 243         and     ecx,7
 244         jz      pl_no_leading_run
 245
 246 ; stuff length of leading run
 247
 248         sub     pixel_count,ecx     ; SLOW!
 249         call    g2pt_compute_light_n
 250
 251         mov     edx,save_edx
 252         mov     ebp,save_ebp
 253
 254         call    [_g2pt_func_n]
 255
 256 pl_no_leading_run:
 257
 258         mov     ecx,_g2pt_dlight
 259
 260         shl     ecx,3
 261
 262         mov     dlight_8,ecx
 263         mov     ecx,pixel_count
 264
 265         shr     ecx,3
 266
 267 pl_pixel_8_loop:
 268         mov     count_save,ecx
 269         call    g2pt_compute_light_8
 270
 271         mov     edx,save_edx
 272         mov     ebp,save_ebp
 273
 274         mov     _g2pt_dest,edi
 275         call    [_g2pt_func_8]
 276
 277         mov     ecx,count_save
 278
 279         dec     ecx
 280         jnz     pl_pixel_8_loop
 281
 282 cleanup:
 283         mov     ecx,pixel_count
 284
 285         and     ecx,7
 286         jz      pl_no_trailing_run
 287
 288         call    g2pt_compute_light_n
 289
 290         mov     edx,save_edx
 291         mov     ebp,save_ebp
 292
 293         call    [_g2pt_func_n]
 294
 295 pl_no_trailing_run:
 296         pop     edi
 297         pop     esi
 298         pop     ebp
 299         ret
 300
 301 _TEXT   ends
 302
 303 END