a_star.pl

   1 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
   2 % Author:       Tom Schrijvers
   3 % Email:        Tom.Schrijvers@cs.kuleuven.ac.be
   4 % Copyright:    K.U.Leuven 2004
   5 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
   6 :- module(a_star,
   7         [
   8                 a_star/4
   9         ]).
  10
  11 :- use_module(library(lists)).
  12
  13 :- use_module(binomialheap).
  14
  15 :- use_module(find).
  16
  17 :- use_module(hprolog).
  18
  19 a_star(DataIn,FinalData,ExpandData,DataOut) :-
  20         a_star_node(DataIn,0,InitialNode),
  21         empty_q(NewQueue),
  22         insert_q(NewQueue,InitialNode,Queue),
  23         a_star_aux(Queue,FinalData,ExpandData,EndNode),
  24         a_star_node(DataOut,_,EndNode).
  25
  26 a_star_aux(Queue,FinalData,ExpandData,EndNode) :-
  27         delete_min_q(Queue,Queue1,Node),
  28         ( final_node(FinalData,Node) ->
  29                 Node = EndNode
  30         ;
  31                 expand_node(ExpandData,Node,Nodes),
  32                 insert_list_q(Nodes,Queue1,NQueue),
  33                 a_star_aux(NQueue,FinalData,ExpandData,EndNode)
  34         ).
  35
  36 final_node(D^Call,Node) :-
  37         a_star_node(Data,_,Node),
  38         term_variables(Call,Vars),
  39         chr_delete(Vars,D,DVars),
  40         copy_term(D^Call-DVars,Data^NCall-DVars),
  41         call(NCall).
  42
  43 expand_node(D^Ds^C^Call,Node,Nodes) :-
  44         a_star_node(Data,Score,Node),
  45         term_variables(Call,Vars),
  46         chr_delete(Vars,D,DVars0),
  47         chr_delete(DVars0,Ds,DVars1),
  48         chr_delete(DVars1,C,DVars),
  49         copy_term(D^Ds^C^Call-DVars,Data^EData^Cost^NCall-DVars),
  50         term_variables(Node,NVars,DVars),
  51         find_with_var_identity(ENode,NVars,(NCall,EScore is Cost + Score,a_star:a_star_node(EData,EScore,ENode)),Nodes).
  52
  53 a_star_node(Data,Score,Data-Score).