BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This is the root build file for GN. GN will start processing by loading this
   6 # file, and recursively load all dependencies until all dependencies are either
   7 # resolved or known not to exist (which will cause the build to fail). So if
   8 # you add a new build file, there must be some path of dependencies from this
   9 # file to your new one or GN won't know about it.
  10
  11 import("//build/config/ui.gni")
  12 if (is_android) {
  13   import("//build/config/android/config.gni")
  14 }
  15
  16 declare_args() {
  17   # A list of extra dependencies to add to the root target. This allows a
  18   # checkout to add additional targets without explicitly changing any checked-
  19   # in files.
  20   root_extra_deps = []
  21 }
  22
  23 # In GN, a "group" is a dummy target that just lists other targets.
  24 group("root") {
  25   # This should not be linked into production and depends on test targets.
  26   testonly = true
  27
  28   # Note that some dependencies are commented out. These are things that are
  29   # currently written but not hooked up to the build yet. They may need to be
  30   # completed or possibly just tested and then re-enabled.
  31   deps = [
  32     "//apps",
  33     "//ash",
  34     "//cc",
  35     "//cc/blink",
  36     "//chrome/browser",
  37     "//chrome/browser/devtools",
  38     "//chrome/common",
  39     "//chrome/plugin",
  40     "//chrome/renderer",
  41     "//chrome/test",
  42     "//chrome/tools",
  43     "//chrome/utility",
  44     "//components:all_components",
  45     "//content",
  46     "//content/shell:content_shell",
  47     "//content/test:test_support",
  48     "//crypto",
  49     "//device/battery",
  50     "//device/bluetooth",
  51     "//device/nfc",
  52     "//device/vibration",
  53     "//extensions/browser",
  54     "//extensions/common",
  55     "//extensions/common/api",
  56     "//extensions/renderer",
  57     "//gin",
  58     "//gpu",
  59     "//google_apis",
  60     "//google_apis/gcm",
  61     "//ipc",
  62     "//ipc/mojo",
  63     "//jingle:notifier",
  64     "//media",
  65     "//media/blink",
  66     "//media/cast",
  67     "//media/mojo",
  68     "//mojo",
  69     "//net",
  70     "//pdf",
  71     "//ppapi:ppapi_c",
  72     "//printing",
  73     "//remoting/client/plugin",
  74     "//sandbox",
  75     "//sdch",
  76     "//skia",
  77     "//storage/browser",
  78     "//sql",
  79     "//sync",
  80     "//third_party/WebKit/public:all_blink",
  81     "//third_party/angle:translator",
  82     "//third_party/brotli",
  83     "//third_party/cacheinvalidation",
  84     "//third_party/cld",
  85     "//third_party/cld_2",
  86     "//third_party/ffmpeg",
  87     "//third_party/flac",
  88     "//third_party/harfbuzz-ng",
  89     "//third_party/hunspell",
  90     "//third_party/iccjpeg",
  91     "//third_party/icu",
  92     "//third_party/leveldatabase",
  93     "//third_party/libphonenumber",
  94     "//third_party/libjingle",
  95     "//third_party/libpng",
  96     "//third_party/libsrtp",
  97     "//third_party/libusb",
  98     "//third_party/libwebm",
  99     "//third_party/libwebp",
 100     "//third_party/libxslt",
 101     "//third_party/libvpx",
 102     "//third_party/libyuv",
 103     "//third_party/lzma_sdk",
 104     "//third_party/mesa",
 105     "//third_party/opus",
 106     "//third_party/ots",
 107     "//third_party/protobuf:protobuf_lite",
 108     "//third_party/qcms",
 109     "//third_party/re2",
 110     "//third_party/smhasher:cityhash",
 111     "//third_party/smhasher:murmurhash3",
 112     "//third_party/smhasher:pmurhash",
 113     "//third_party/snappy",
 114     "//third_party/speex",
 115     "//third_party/usrsctp",
 116     "//third_party/widevine/cdm:version_h",
 117     "//third_party/webrtc",
 118     "//third_party/zlib",
 119     "//third_party:jpeg",
 120     "//tools/gn",
 121     "//tools/imagediff($host_toolchain)",
 122     "//ui/accessibility",
 123     "//ui/app_list",
 124     "//ui/aura",
 125     "//ui/base",
 126     "//ui/display",
 127     "//ui/events",
 128     "//ui/gfx",
 129     "//ui/gl",
 130     "//ui/keyboard",
 131     "//ui/native_theme",
 132     "//ui/resources",
 133     "//ui/snapshot",
 134     "//ui/strings",
 135     "//ui/surface",
 136     "//ui/views",
 137     "//ui/views/controls/webview",
 138     "//ui/web_dialogs",
 139     "//url",
 140     "//v8:v8",
 141   ]
 142   deps += root_extra_deps
 143
 144   if (!is_win) {
 145     deps += [ "//breakpad:symupload" ]
 146   }
 147
 148   if (is_linux) {
 149     deps += [
 150       "//dbus",
 151       "//third_party/fontconfig",
 152       "//third_party/freetype2",
 153     ]
 154   }
 155
 156   if (use_x11) {
 157     deps += [ "//tools/xdisplaycheck" ]
 158   }
 159
 160   if (use_aura) {
 161     deps += [ "//ui/wm" ]
 162   }
 163
 164   if (is_win) {
 165     deps += [ "//ui/metro_viewer" ]
 166   }
 167
 168   if (is_win || is_mac || is_chromeos) {
 169     # RLZ works on these platforms.
 170     deps += [ "//rlz:rlz_lib" ]
 171   }
 172
 173   if (cpu_arch == "x86" || cpu_arch == "x64") {
 174     # YASM is x86/x64 only.
 175     deps += [ "//third_party/yasm($host_toolchain)" ]
 176   }
 177
 178   if (is_android) {
 179     deps += [
 180       "//base/android/linker:chromium_android_linker",
 181       "//build/android/gyp/test:hello_world",
 182       "//build/android/rezip",
 183       "//third_party/openmax_dl/dl",
 184       "//content/shell/android:content_shell_apk",
 185       "//chrome/android:chrome_shell_apk",
 186       "//chrome/test/chromedriver/test/webview_shell:chromedriver_webview_shell_apk",
 187       "//ui/android:ui_java",
 188       "//third_party/android_tools:android_gcm_java",
 189       "//third_party/android_tools:uiautomator_java",
 190       "//third_party/android_tools:android_support_v13_java",
 191       "//third_party/android_tools:android_support_v7_appcompat_java",
 192       "//third_party/android_tools:android_support_v7_mediarouter_java",
 193       "//third_party/mockito:mockito_java",
 194     ]
 195
 196     if (has_chrome_android_internal) {
 197       deps += [ "//clank" ]
 198     }
 199
 200     # TODO(GYP): Move the targets in the rest of this block that still
 201     # need to be made to work in the GN build to the bottom of the file
 202     # so that all the remaining work is located in one place in the file.
 203     # This block should contain only the targets that aren't actually
 204     # needed on Android.
 205
 206     deps -= [
 207       "//apps",  # Needs testing.
 208       "//chrome/browser",
 209       "//chrome/browser/devtools",
 210       "//chrome/common",
 211       "//chrome/plugin",
 212       "//chrome/renderer",
 213       "//chrome/test",
 214       "//chrome/tools",
 215       "//chrome/utility",
 216       "//content/shell:content_shell",
 217       "//extensions/browser",
 218       "//extensions/common",
 219       "//extensions/common/api",
 220       "//extensions/renderer",
 221       "//pdf",  # Not compiled on Android in GYP yet, either.
 222       "//ppapi:ppapi_c",
 223       "//third_party/libusb",
 224       "//ui/keyboard",  # Blocked on content.
 225
 226       # Seems to not be compiled on Android. Otherwise it will need a config.h.
 227       "//third_party/libxslt",
 228
 229       # Not relevant to Android.
 230       "//ash",
 231       "//tools/gn",
 232       "//ui/aura",
 233       "//ui/display",
 234       "//ui/views",
 235       "//ui/views/controls/webview",
 236
 237       # Fails on Android for unknown reasons.
 238       "//third_party/flac",
 239       "//breakpad:symupload",
 240
 241       # Not tested on Android yet:
 242       "//google_apis/gcm",
 243       "//remoting/client/plugin",
 244       "//storage/browser",
 245       "//third_party/cld_2",
 246       "//third_party/ffmpeg",
 247       "//ui/app_list",
 248       "//ui/web_dialogs",
 249     ]
 250   }
 251
 252   if (use_ozone) {
 253     deps += [
 254       "//ui/ozone",
 255       "//ui/ozone/demo",
 256     ]
 257   }
 258
 259   # Non-mobile builds.
 260   if (!is_android && !is_ios) {
 261     deps += [
 262       "//device/usb",
 263       "//third_party/pdfium/samples",
 264     ]
 265   }
 266
 267   #
 268   # TODO(GYP): Make everything below this work in the GN build.
 269   #
 270
 271   if (is_mac) {
 272     # TODO(dpranke): These are as-yet untriaged but need at least the above.
 273     deps -= [
 274       "//apps",
 275       "//ash",
 276       "//chrome/browser",
 277       "//chrome/browser/devtools",
 278       "//chrome/common",
 279       "//chrome/plugin",
 280       "//chrome/renderer",
 281       "//chrome/test",
 282       "//chrome/utility",
 283       "//components:all_components",
 284       "//content/shell:content_shell",
 285       "//extensions/browser",
 286       "//extensions/common",
 287       "//extensions/common/api",
 288       "//extensions/renderer",
 289       "//remoting/client/plugin",
 290       "//third_party/usrsctp",
 291       "//ui/app_list",
 292       "//ui/aura",
 293       "//ui/keyboard",
 294       "//ui/views",
 295       "//ui/views/controls/webview",
 296       "//ui/web_dialogs",
 297     ]
 298   }
 299
 300   if (is_win) {
 301     deps -= [
 302       "//apps",
 303       "//ash",
 304       "//chrome/browser",
 305       "//chrome/browser/devtools",
 306       "//chrome/common",
 307       "//chrome/plugin",
 308       "//chrome/renderer",
 309       "//chrome/test",
 310       "//chrome/utility",
 311       "//components:all_components",
 312       "//cc",
 313       "//cc/blink",
 314       "//content",
 315       "//content/shell:content_shell",
 316       "//content/test:test_support",
 317       "//device/bluetooth",
 318       "//extensions/browser",
 319       "//extensions/common",
 320       "//extensions/common/api",
 321       "//extensions/renderer",
 322       "//gpu",
 323       "//google_apis",
 324       "//google_apis/gcm",
 325       "//jingle:notifier",
 326       "//media",
 327       "//media/blink",
 328       "//media/cast",
 329       "//media/mojo",
 330       "//mojo",
 331       "//pdf",
 332       "//ppapi:ppapi_c",
 333       "//printing",
 334       "//remoting/client/plugin",
 335       "//sandbox",
 336       "//storage/browser",
 337       "//sync",
 338       "//third_party/WebKit/public:all_blink",
 339       "//third_party/angle:translator",
 340       "//third_party/ffmpeg",
 341       "//third_party/leveldatabase",
 342       "//third_party/libjingle",
 343       "//third_party/usrsctp",
 344       "//third_party/webrtc",
 345       "//ui/accessibility",
 346       "//ui/app_list",
 347       "//ui/aura",
 348       "//ui/base",
 349       "//ui/display",
 350       "//ui/events",
 351       "//ui/gfx",
 352       "//ui/gl",
 353       "//ui/keyboard",
 354       "//ui/native_theme",
 355       "//ui/snapshot",
 356       "//ui/surface",
 357       "//ui/views",
 358       "//ui/views/controls/webview",
 359       "//ui/web_dialogs",
 360       "//ui/wm",
 361     ]
 362   }
 363 }