device/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/rules.gni")  # For generate_jni().
  10 }
  11
  12 if (is_mac) {
  13   import("//build/config/mac/mac_sdk.gni")
  14 }
  15
  16 is_linux_without_udev = is_linux && !use_udev
  17 is_linux_without_dbus = is_linux && !use_dbus
  18
  19 test("device_unittests") {
  20   sources = [
  21     "battery/battery_status_manager_win_unittest.cc",
  22     "battery/battery_status_service_unittest.cc",
  23     "bluetooth/bluetooth_adapter_android_unittest.cc",
  24     "bluetooth/bluetooth_adapter_mac_unittest.mm",
  25     "bluetooth/bluetooth_adapter_profile_chromeos_unittest.cc",
  26     "bluetooth/bluetooth_adapter_unittest.cc",
  27     "bluetooth/bluetooth_adapter_win_unittest.cc",
  28     "bluetooth/bluetooth_advertisement_chromeos_unittest.cc",
  29     "bluetooth/bluetooth_audio_sink_chromeos_unittest.cc",
  30     "bluetooth/bluetooth_chromeos_unittest.cc",
  31     "bluetooth/bluetooth_device_unittest.cc",
  32     "bluetooth/bluetooth_device_win_unittest.cc",
  33     "bluetooth/bluetooth_discovery_filter_unittest.cc",
  34     "bluetooth/bluetooth_gatt_chromeos_unittest.cc",
  35     "bluetooth/bluetooth_low_energy_win_unittest.cc",
  36     "bluetooth/bluetooth_service_record_win_unittest.cc",
  37     "bluetooth/bluetooth_socket_chromeos_unittest.cc",
  38     "bluetooth/bluetooth_task_manager_win_unittest.cc",
  39     "bluetooth/bluetooth_uuid_unittest.cc",
  40     "bluetooth/test/test_bluetooth_adapter_observer.cc",
  41     "bluetooth/test/test_bluetooth_adapter_observer.h",
  42     "nfc/nfc_chromeos_unittest.cc",
  43     "nfc/nfc_ndef_record_unittest.cc",
  44     "test/run_all_unittests.cc",
  45   ]
  46
  47   deps = [
  48     "//base/test:test_support",
  49     "//device/battery",
  50     "//device/battery:mojo_bindings",
  51     "//device/bluetooth",
  52     "//device/nfc",
  53     "//mojo/environment:chromium",
  54     "//net",
  55     "//testing/gmock",
  56     "//testing/gtest",
  57     "//third_party/mojo/src/mojo/edk/system",
  58     "//third_party/mojo/src/mojo/public/cpp/bindings",
  59     "//url",
  60   ]
  61
  62   if (!is_linux_without_dbus && !is_chromeos) {
  63     sources += [ "battery/battery_status_manager_linux_unittest.cc" ]
  64   }
  65
  66   # HID and Serial:
  67   # Android doesn't compile.
  68   # Linux, requires udev.
  69   if (!is_linux_without_udev && !is_android) {
  70     sources += [
  71       "hid/hid_connection_unittest.cc",
  72       "hid/hid_device_filter_unittest.cc",
  73       "hid/hid_report_descriptor_unittest.cc",
  74       "hid/input_service_linux_unittest.cc",
  75       "hid/test_report_descriptors.cc",
  76       "hid/test_report_descriptors.h",
  77       "serial/data_sink_unittest.cc",
  78       "serial/data_source_unittest.cc",
  79       "serial/serial_connection_unittest.cc",
  80       "serial/serial_service_unittest.cc",
  81     ]
  82     deps += [
  83       "//device/hid",
  84       "//device/serial",
  85       "//device/serial:test_support",
  86     ]
  87   }
  88
  89   if (use_udev) {
  90     sources += [ "udev_linux/udev_unittest.cc" ]
  91     deps += [ "//device/udev_linux" ]
  92   }
  93
  94   # USB does not compile on mobile platforms.
  95   if (!is_android && !is_ios) {
  96     sources += [
  97       "devices_app/usb/device_impl_unittest.cc",
  98       "devices_app/usb/device_manager_impl_unittest.cc",
  99       "test/usb_test_gadget_impl.cc",
 100       "usb/usb_context_unittest.cc",
 101       "usb/usb_device_filter_unittest.cc",
 102       "usb/usb_device_handle_unittest.cc",
 103       "usb/usb_ids_unittest.cc",
 104       "usb/usb_service_unittest.cc",
 105     ]
 106     deps += [
 107       "//device/core",
 108       "//device/devices_app:lib",
 109       "//device/devices_app/usb/public/cpp",
 110       "//device/devices_app/usb/public/interfaces",
 111       "//device/usb",
 112       "//device/usb:mocks",
 113       "//third_party/libusb",
 114     ]
 115   }
 116
 117   if (is_android) {
 118     deps += [ ":bluetooth_test_jni_headers" ]
 119     apk_deps = [ ":bluetooth_test_java" ]
 120   }
 121
 122   if (is_chromeos) {
 123     configs += [ "//build/config/linux:dbus" ]
 124
 125     deps += [
 126       "//chromeos",
 127       "//chromeos:test_support",
 128       "//chromeos:test_support_without_gmock",
 129       "//dbus",
 130     ]
 131   }
 132
 133   if (is_posix && !is_android && !is_mac) {
 134     libs = [ "rt" ]
 135   }
 136
 137   if (is_mac) {
 138     libs = [ "IOBluetooth.framework" ]
 139
 140     # In the OSX 10.10 SDK, CoreBluetooth became a top level framework.
 141     # Previously, it was nested in IOBluetooth. In order for Chrome to run on
 142     # OSes older than OSX 10.10, the top level CoreBluetooth framework must be
 143     # weakly linked.
 144     if (mac_sdk_version == "10.10") {
 145       ldflags = [ "-weak_framework CoreBluetooth" ]
 146     }
 147   }
 148 }
 149
 150 if (is_android) {
 151   bluetooth_java_sources_needing_jni = [ "bluetooth/test/android/java/src/org/chromium/device/bluetooth/FakeBluetoothAdapter.java" ]
 152
 153   generate_jni("bluetooth_test_jni_headers") {
 154     sources = bluetooth_java_sources_needing_jni
 155     jni_package = "bluetooth"
 156   }
 157
 158   android_library("bluetooth_test_java") {
 159     java_files = bluetooth_java_sources_needing_jni
 160     deps = [
 161       "//base:base_java",
 162       "//device/bluetooth:java",
 163     ]
 164   }
 165 }