ui/message_center/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8
   9 component("message_center") {
  10   deps = [
  11     "//base",
  12     "//base:i18n",
  13     "//base/third_party/dynamic_annotations",
  14     "//skia",
  15     "//ui/accessibility",
  16     "//ui/base",
  17     "//ui/events",
  18     "//ui/gfx",
  19     "//ui/gfx/geometry",
  20     "//ui/native_theme",
  21     "//ui/resources",
  22     "//ui/strings",
  23     "//url",
  24   ]
  25
  26   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  27   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  28
  29   defines = [ "MESSAGE_CENTER_IMPLEMENTATION" ]
  30
  31   if (enable_notifications && !is_android) {
  32     sources = [
  33       "cocoa/notification_controller.h",
  34       "cocoa/notification_controller.mm",
  35       "cocoa/opaque_views.h",
  36       "cocoa/opaque_views.mm",
  37       "cocoa/popup_collection.h",
  38       "cocoa/popup_collection.mm",
  39       "cocoa/popup_controller.h",
  40       "cocoa/popup_controller.mm",
  41       "cocoa/settings_controller.h",
  42       "cocoa/settings_controller.mm",
  43       "cocoa/settings_entry_view.h",
  44       "cocoa/settings_entry_view.mm",
  45       "cocoa/status_item_view.h",
  46       "cocoa/status_item_view.mm",
  47       "cocoa/tray_controller.h",
  48       "cocoa/tray_controller.mm",
  49       "cocoa/tray_view_controller.h",
  50       "cocoa/tray_view_controller.mm",
  51       "message_center.cc",
  52       "message_center.h",
  53       "message_center_export.h",
  54       "message_center_impl.cc",
  55       "message_center_impl.h",
  56       "message_center_observer.h",
  57       "message_center_style.cc",
  58       "message_center_style.h",
  59       "message_center_switches.cc",
  60       "message_center_switches.h",
  61       "message_center_tray.cc",
  62       "message_center_tray.h",
  63       "message_center_tray_delegate.h",
  64       "message_center_types.h",
  65       "notification.cc",
  66       "notification.h",
  67       "notification_blocker.cc",
  68       "notification_blocker.h",
  69       "notification_delegate.cc",
  70       "notification_delegate.h",
  71       "notification_list.cc",
  72       "notification_list.h",
  73       "notification_types.cc",
  74       "notification_types.h",
  75       "notifier_settings.cc",
  76       "notifier_settings.h",
  77     ]
  78
  79     if (is_win) {
  80       deps += [ "//ui/aura" ]
  81     }
  82
  83     # On Mac, toolkit-views builds still use the Cocoa UI. Keep this in sync
  84     # with message_center_unittests below.
  85     if (toolkit_views && !is_mac) {
  86       sources += [
  87         "views/bounded_label.cc",
  88         "views/bounded_label.h",
  89         "views/constants.h",
  90         "views/desktop_popup_alignment_delegate.cc",
  91         "views/desktop_popup_alignment_delegate.h",
  92         "views/message_center_button_bar.cc",
  93         "views/message_center_button_bar.h",
  94         "views/message_center_controller.h",
  95         "views/message_center_view.cc",
  96         "views/message_center_view.h",
  97         "views/message_popup_collection.cc",
  98         "views/message_popup_collection.h",
  99         "views/message_view.cc",
 100         "views/message_view.h",
 101         "views/message_view_context_menu_controller.cc",
 102         "views/message_view_context_menu_controller.h",
 103         "views/notification_button.cc",
 104         "views/notification_button.h",
 105         "views/notification_view.cc",
 106         "views/notification_view.h",
 107         "views/notifier_settings_view.cc",
 108         "views/notifier_settings_view.h",
 109         "views/padded_button.cc",
 110         "views/padded_button.h",
 111         "views/popup_alignment_delegate.cc",
 112         "views/popup_alignment_delegate.h",
 113         "views/proportional_image_view.cc",
 114         "views/proportional_image_view.h",
 115         "views/toast_contents_view.cc",
 116         "views/toast_contents_view.h",
 117       ]
 118       deps += [
 119         "//ui/events",
 120         "//ui/views",
 121         "//ui/compositor",
 122       ]
 123     }
 124
 125     if (use_ash) {
 126       sources += [
 127         "views/message_bubble_base.cc",
 128         "views/message_bubble_base.h",
 129         "views/message_center_bubble.cc",
 130         "views/message_center_bubble.h",
 131       ]
 132     }
 133   } else {
 134     # Notification service disabled.
 135     sources = [
 136       "dummy_message_center.cc",
 137       "notification_delegate.cc",
 138       "notification_delegate.h",
 139     ]
 140
 141     # Android implements its own notification UI manager instead of deferring to
 142     # the message center (when notifications are enabled). Include a minimal
 143     # set of files required for notifications on Android.
 144     if (is_android) {
 145       sources += [
 146         "notification.cc",
 147         "notification.h",
 148         "notifier_settings.cc",
 149         "notifier_settings.h",
 150       ]
 151     }
 152   }
 153 }
 154
 155 static_library("test_support") {
 156   testonly = true
 157   sources = [
 158     "fake_message_center.cc",
 159     "fake_message_center.h",
 160     "fake_message_center_tray_delegate.cc",
 161     "fake_message_center_tray_delegate.h",
 162     "fake_notifier_settings_provider.cc",
 163     "fake_notifier_settings_provider.h",
 164   ]
 165
 166   public_deps = [
 167     ":message_center",
 168   ]
 169
 170   deps = [
 171     "//base",
 172     "//base/test:test_support",
 173     "//skia",
 174     "//ui/gfx",
 175     "//ui/gfx/geometry",
 176   ]
 177 }
 178
 179 test("message_center_unittests") {
 180   sources = [
 181     "test/run_all_unittests.cc",
 182   ]
 183
 184   deps = [
 185     ":message_center",
 186     ":test_support",
 187     "//base",
 188     "//base/allocator",
 189     "//base/test:test_support",
 190     "//skia",
 191     "//testing/gtest",
 192     "//ui/base",
 193     "//ui/events",
 194     "//ui/gfx",
 195     "//ui/gfx/geometry",
 196     "//ui/gl",
 197     "//ui/resources",
 198     "//ui/resources:ui_test_pak",
 199     "//url",
 200   ]
 201
 202   if (enable_notifications && !is_android) {
 203     sources += [
 204       "cocoa/notification_controller_unittest.mm",
 205       "cocoa/popup_collection_unittest.mm",
 206       "cocoa/popup_controller_unittest.mm",
 207       "cocoa/settings_controller_unittest.mm",
 208       "cocoa/status_item_view_unittest.mm",
 209       "cocoa/tray_controller_unittest.mm",
 210       "cocoa/tray_view_controller_unittest.mm",
 211       "message_center_impl_unittest.cc",
 212       "message_center_tray_unittest.cc",
 213       "notification_delegate_unittest.cc",
 214       "notification_list_unittest.cc",
 215     ]
 216
 217     if (is_mac) {
 218       deps += [ "//ui/gfx:test_support" ]
 219     }
 220
 221     if (toolkit_views && !is_mac) {
 222       sources += [
 223         "views/bounded_label_unittest.cc",
 224         "views/message_center_view_unittest.cc",
 225         "views/message_popup_collection_unittest.cc",
 226         "views/notification_view_unittest.cc",
 227         "views/notifier_settings_view_unittest.cc",
 228       ]
 229       deps += [
 230         # Compositor is needed by message_center_view_unittest.cc and for the
 231         # fonts used by bounded_label_unittest.cc.
 232         "//ui/compositor",
 233         "//ui/views",
 234         "//ui/views:test_support",
 235       ]
 236     }
 237   }  # enable_notifications && !is_android
 238 }