build/config/win/visual_studio_version.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 declare_args() {
   6   # Path to Visual Studio. If empty, the default is used which is to use the
   7   # automatic toolchain in depot_tools. If set, you must also set the
   8   # visual_studio_version and wdk_path.
   9   visual_studio_path = ""
  10
  11   # Version of Visual Studio pointed to by the visual_studio_path.
  12   # Use "2013" for Visual Studio 2013, or "2013e" for the Express version.
  13   visual_studio_version = ""
  14
  15   # Directory of the Windows driver kit. If visual_studio_path is empty, this
  16   # will be auto-filled.
  17   wdk_path = ""
  18
  19   # Full path to the Windows SDK, not including a backslash at the end.
  20   # This value is the default location, override if you have a different
  21   # installation location.
  22   windows_sdk_path = "C:\Program Files (x86)\Windows Kits\8.0"
  23 }
  24
  25 if (visual_studio_path == "") {
  26   toolchain_data =
  27       exec_script("../../vs_toolchain.py", [ "get_toolchain_dir" ], "scope")
  28   visual_studio_path = toolchain_data.vs_path
  29   windows_sdk_path = toolchain_data.sdk_path
  30   visual_studio_version = toolchain_data.vs_version
  31   wdk_path = toolchain_data.wdk_dir
  32 } else {
  33   assert(visual_studio_version != "",
  34          "You must set the visual_studio_version if you set the path")
  35   assert(wdk_path != "",
  36          "You must set the wdk_path if you set the visual studio path")
  37 }
  38
  39 # Set when using the "Express" version of a Visual Studio version we support.
  40 is_visual_studio_express = (visual_studio_version == "2013e")