device/battery/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//mojo/public/tools/bindings/mojom.gni")
   7
   8 component("battery") {
   9   output_name = "device_battery"
  10
  11   sources = [
  12     "battery_export.h",
  13     "battery_monitor_impl.cc",
  14     "battery_monitor_impl.h",
  15     "battery_status_manager_android.cc",
  16     "battery_status_manager_android.h",
  17     "battery_status_manager_chromeos.cc",
  18     "battery_status_manager_default.cc",
  19     "battery_status_manager_linux.cc",
  20     "battery_status_manager_linux.h",
  21     "battery_status_manager_mac.cc",
  22     "battery_status_manager_win.cc",
  23     "battery_status_manager_win.h",
  24     "battery_status_service.cc",
  25     "battery_status_service.h",
  26   ]
  27
  28   defines = [ "DEVICE_BATTERY_IMPLEMENTATION" ]
  29
  30   deps = [
  31     ":mojo_bindings",
  32     "//base",
  33     "//base/third_party/dynamic_annotations",
  34     "//mojo/environment:chromium",
  35     "//mojo/public/cpp/bindings",
  36     "//mojo/edk/system",
  37   ]
  38
  39   if (is_android) {
  40     deps += [ "//device/battery/android:battery_jni_headers" ]
  41     sources += [
  42       "android/battery_jni_registrar.h",
  43       "android/battery_jni_registrar.cc",
  44     ]
  45     sources -= [ "battery_status_manager_default.cc" ]
  46   }
  47
  48   if (is_chromeos) {
  49     configs += [ "//build/config/linux:dbus" ]
  50     deps += [ "//chromeos:power_manager_proto" ]
  51     sources -= [
  52       "battery_status_manager_default.cc",
  53       "battery_status_manager_linux.cc",
  54     ]
  55   }
  56
  57   if (is_desktop_linux) {
  58     if (use_dbus) {
  59       configs += [ "//build/config/linux:dbus" ]
  60       deps += [ "//dbus" ]
  61       sources -= [ "battery_status_manager_default.cc" ]
  62     } else {
  63       sources -= [ "battery_status_manager_linux.cc" ]
  64     }
  65   }
  66
  67   if (is_mac) {
  68     sources -= [ "battery_status_manager_default.cc" ]
  69   }
  70
  71   if (is_win) {
  72     sources -= [ "battery_status_manager_default.cc" ]
  73   }
  74 }
  75
  76 mojom("mojo_bindings") {
  77   sources = [
  78     "battery_monitor.mojom",
  79     "battery_status.mojom",
  80   ]
  81 }