mandoline/services/core_services/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4 #
   5 # core_services should be thought of as a bundle of many of the services which
   6 # we ship with.
   7
   8 import("//build/config/ui.gni")
   9 import("//build/toolchain/toolchain.gni")
  10 import("//mojo/public/mojo_application.gni")
  11
  12 mojo_native_application("core_services") {
  13   deps = [
  14     ":sources",
  15     "//third_party/angle:libEGL",
  16     "//third_party/angle:libGLESv2",
  17   ]
  18   if (is_win) {
  19     copy("copy_files") {
  20       sources = [
  21         "$root_shlib_dir/libEGL.dll",
  22         "$root_shlib_dir/libGLESv2.dll",
  23       ]
  24       outputs = [
  25         "$root_out_dir/core_services/{{source_file_part}}",
  26       ]
  27     }
  28     deps += [ ":copy_files" ]
  29   }
  30
  31   if (!is_android) {
  32     deps += [ "//third_party/icu:icudata" ]
  33     resources = [ "$root_out_dir/icudtl.dat" ]
  34   }
  35 }
  36
  37 source_set("sources") {
  38   sources = [
  39     "application_delegate_factory.h",
  40     "application_delegate_factory_linux.cc",
  41     "core_services_application_delegate.cc",
  42     "main.cc",
  43   ]
  44
  45   deps = [
  46     "//base",
  47     "//components/clipboard:lib",
  48     "//components/filesystem:lib",
  49     "//mandoline/tab:lib",
  50     "//mojo/application/public/cpp",
  51     "//mojo/common:tracing_impl",
  52     "//mojo/message_pump",
  53     "//mojo/services/tracing:lib",
  54     "//third_party/icu",
  55     "//third_party/mojo/src/mojo/public/cpp/bindings",
  56     "//url",
  57   ]
  58
  59   if (!is_android) {
  60     sources += [ "application_delegate_factory_notandroid.cc" ]
  61     deps += [
  62       "//components/resource_provider:lib",
  63       "//components/view_manager:lib",
  64       "//mojo/services/network:lib",
  65     ]
  66   }
  67
  68   if (is_linux) {
  69     deps += [ "//components/font_service:lib" ]
  70   } else {
  71     sources += [ "application_delegate_factory_default.cc" ]
  72   }
  73
  74   if (use_aura) {
  75     deps += [
  76       "//components/view_manager/public/cpp",
  77       "//mandoline/ui/desktop_ui:lib",
  78       "//mandoline/ui/omnibox:lib",
  79     ]
  80     sources += [ "application_delegate_factory_aura.cc" ]
  81   }
  82 }