chrome/common/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//tools/grit/grit_rule.gni")
   6
   7 gypi_values = exec_script(
   8     "//build/gypi_to_gn.py",
   9     [ rebase_path("../chrome_common.gypi") ],
  10     "scope",
  11     [ "../chrome_common.gypi" ])
  12
  13 # GYP version: chrome/chrome_resources.gyp:chrome_resources
  14 #              (generate_common_resources action)
  15 grit("resources") {
  16   source = "common_resources.grd"
  17   output_dir = "$root_gen_dir/chrome"
  18   output_name = "common_resources"
  19   outputs = [
  20     "grit/common_resources.h",
  21     "common_resources.pak",
  22   ]
  23 }
  24
  25 # GYP version: chrome/chrome_resources.gyp:chrome_resources
  26 #              (generate_extensions_api_resources action)
  27 grit("extensions_api_resources") {
  28   source = "extensions_api_resources.grd"
  29   output_dir = "$root_gen_dir/chrome"
  30   outputs = [
  31     "grit/extensions_api_resources.h",
  32     "extensions_api_resources.pak",
  33   ]
  34 }
  35
  36 # GYP version: chrome/chrome_common.gyp:common
  37 static_library("common") {
  38   sources = rebase_path(gypi_values.chrome_common_sources, ".", "//chrome")
  39   defines = []
  40
  41   configs += [ "//build/config/compiler:wexit_time_destructors" ]
  42
  43   deps = [
  44     ":version",
  45     "//base:base",
  46     "//base:i18n",
  47     "//base:prefs",
  48     "//base:base_static",
  49     "//chrome:resources",
  50     "//chrome:strings",
  51     "//chrome/app/theme:theme_resources",
  52     "//chrome/common:constants",
  53     "//chrome/common/net",
  54     "//chrome/common/safe_browsing:proto",
  55     "//chrome/installer/util",
  56     "//components/cloud_devices/common",
  57     "//components/content_settings/core/common",
  58     "//components/json_schema",
  59     "//components/metrics",
  60     "//components/policy:policy_component_common",
  61     "//components/translate/core/common",
  62     "//components/variations",
  63     "//content/public/common",
  64     "//crypto",
  65     "//extensions:extensions_resources",
  66     "//extensions/strings",
  67     "//media/cast:net",
  68     "//net",
  69     "//skia",
  70     "//third_party/icu",
  71     "//third_party/libxml",
  72     "//third_party/sqlite",
  73     "//third_party/zlib:zip",
  74     "//ui/resources:resources",
  75     "//url",
  76   ]
  77
  78   if (is_ios) {
  79     sources += [
  80       # Use this Mac file that was filtered out.
  81       "chrome_version_info_mac.mm",
  82     ]
  83   } else {
  84     # Non-iOS.
  85     deps += [
  86       "//components/visitedlink/common",
  87       "//components/autofill/content/common",
  88       "//components/autofill/core/common",
  89       "//components/password_manager/content/common",
  90       "//components/password_manager/core/common",
  91       "//components/signin/core/common",
  92       "//components/translate/content/common",
  93       "//ipc",
  94       "//third_party/re2",
  95       "//third_party/widevine/cdm:version_h",
  96     ]
  97   }
  98
  99   if (enable_extensions) {
 100     sources += rebase_path(
 101         gypi_values.chrome_common_extensions_sources,
 102         ".", "//chrome")
 103     deps += [
 104       "//device/bluetooth",  # TODO(thestig) Still needed? Not in gyp version.
 105       "//device/usb",
 106       "//chrome/common/extensions/api",
 107       "//extensions/common",
 108       "//extensions/common/api",
 109     ]
 110   }
 111
 112   if (is_win || is_mac) {
 113     sources += rebase_path(
 114         gypi_values.chrome_common_win_mac_sources,
 115         ".", "//chrome")
 116     if (use_openssl) {
 117       sources -= [
 118         "extensions/api/networking_private/networking_private_crypto_nss.cc",
 119       ]
 120       # networking_private_crypto_openssl.cc depends on boringssl.
 121       deps += [
 122         "//third_party/boringssl",
 123       ]
 124     } else {
 125       sources -= [
 126         "extensions/api/networking_private/networking_private_crypto_openssl.cc",
 127       ]
 128     }
 129     deps += [ "//breakpad:client" ]
 130   }
 131   if (is_mac) {
 132     sources += rebase_path(
 133         gypi_values.chrome_common_mac_sources,
 134         ".", "//chrome")
 135   }
 136
 137   if (enable_nacl) {
 138     deps += [
 139       #'<(DEPTH)/components/nacl.gyp:nacl_common',  TODO(GYP)
 140     ]
 141   }
 142
 143   # Printing.
 144   if (printing_mode == 0) {
 145     sources -= [
 146       "print_messages.cc",
 147       "print_messages.h",
 148     ]
 149   } else {
 150     deps += [ "//printing" ]
 151     if (printing_mode == 1) {
 152       # Full printing support.
 153       sources += rebase_path(
 154           gypi_values.chrome_common_service_process_sources,
 155           ".", "//chrome")
 156     }
 157   }
 158
 159   if (enable_service_discovery) {
 160     sources += [
 161       "local_discovery/service_discovery_client.cc",
 162       "local_discovery/service_discovery_client.h",
 163     ]
 164   }
 165   if (enable_mdns) {
 166     sources += [
 167       "local_discovery/service_discovery_client_impl.cc",
 168       "local_discovery/service_discovery_client_impl.h",
 169     ]
 170   }
 171
 172   if (is_android) {
 173     sources -= [
 174       "badge_util.cc",
 175       "chrome_version_info_posix.cc",
 176       "icon_with_badge_image_source.cc",
 177       "media_galleries/metadata_types.h",
 178       "spellcheck_common.cc",
 179     ]
 180   } else {
 181     # Non-Android.
 182     sources += rebase_path(
 183         gypi_values.chrome_common_importer_sources,
 184         ".", "//chrome")
 185   }
 186
 187   if (is_win) {
 188     deps += [ "//third_party/wtl" ]
 189   }
 190
 191   if (enable_mdns) {
 192     sources += [ "local_discovery/local_discovery_messages.h" ]
 193   }
 194
 195   if (is_mac) {
 196     sources -= [
 197       "chrome_version_info_posix.cc",
 198     ]
 199     deps += [
 200       "//third_party/mach_override",
 201       "//third_party/google_toolbox_for_mac",
 202     ]
 203   }
 204
 205   if (enable_remoting) {
 206     deps += [ "//remoting/client/plugin" ]
 207   }
 208   if (enable_plugins) {
 209     sources += [
 210       "pepper_flash.cc",
 211       "pepper_flash.h",
 212       "pepper_permission_util.cc",
 213       "pepper_permission_util.h",
 214     ]
 215     deps += [
 216       "//third_party/adobe/flash:flapper_version_h",
 217     ]
 218   }
 219   if (!enable_webrtc) {
 220     sources -= [ "media/webrtc_logging_messages.h" ]
 221   }
 222   if (enable_configuration_policy) {
 223     deps += [ "//components/policy" ]
 224   }
 225
 226   if (safe_browsing_mode == 1) {
 227     defines += [ "FULL_SAFE_BROWSING" ]
 228     sources += rebase_path(
 229         gypi_values.chrome_common_full_safe_browsing_sources,
 230         ".", "//chrome")
 231   }
 232   if (safe_browsing_mode == 2) {
 233     defines += [ "MOBILE_SAFE_BROWSING" ]
 234   }
 235 }
 236
 237 import("//chrome/version.gni")
 238 process_version("version") {
 239   visibility = [ ":common" ]
 240   source = "chrome_version_info_values.h.version"
 241   output = "$target_gen_dir/chrome_version_info_values.h"
 242 }
 243
 244 # GN version: chrome/common_constants.gyp:common_constants
 245 static_library("constants") {
 246   sources = [
 247     "chrome_constants.cc",
 248     "chrome_constants.h",
 249     "chrome_icon_resources_win.cc",
 250     "chrome_icon_resources_win.h",
 251     "chrome_paths.cc",
 252     "chrome_paths.h",
 253     "chrome_paths_android.cc",
 254     "chrome_paths_internal.h",
 255     "chrome_paths_linux.cc",
 256     "chrome_paths_mac.mm",
 257     "chrome_paths_win.cc",
 258     "chrome_switches.cc",
 259     "chrome_switches.h",
 260     "env_vars.cc",
 261     "env_vars.h",
 262     "net/test_server_locations.cc",
 263     "net/test_server_locations.h",
 264     "pref_font_script_names-inl.h",
 265     "pref_font_webkit_names.h",
 266     "pref_names.cc",
 267     "pref_names.h",
 268     "widevine_cdm_constants.cc",
 269     "widevine_cdm_constants.h",
 270   ]
 271
 272   deps = [
 273     "//base",
 274     "//base/third_party/dynamic_annotations",
 275     "//components/bookmarks/common",
 276     "//third_party/widevine/cdm:version_h",
 277   ]
 278
 279   if (enable_nacl) {
 280     deps += [
 281       #'../components/nacl.gyp:nacl_switches',  TODO(GYP)
 282     ]
 283   }
 284 }
 285
 286 source_set("test_support") {
 287   testonly = true
 288   visibility = [ "//chrome/test:test_support" ]
 289
 290   sources = [
 291     "extensions/extension_test_util.cc",
 292     "extensions/extension_test_util.h",
 293   ]
 294
 295   deps = [
 296     ":common",
 297     "//base",
 298     "//testing/gtest",
 299   ]
 300
 301   if (is_win || is_mac) {
 302     sources += [
 303       "media_galleries/picasa_test_util.cc",
 304       "media_galleries/picasa_test_util.h",
 305       "media_galleries/pmp_test_util.cc",
 306       "media_galleries/pmp_test_util.h",
 307     ]
 308   }
 309
 310 }