sandbox/linux/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//testing/test.gni")
   7
   8 declare_args() {
   9   compile_suid_client = is_linux
  10
  11   compile_credentials = is_linux
  12
  13   # On Android, use plain GTest.
  14   use_base_test_suite = is_linux
  15 }
  16
  17 # We have two principal targets: sandbox and sandbox_linux_unittests
  18 # All other targets are listed as dependencies.
  19 # There is one notable exception: for historical reasons, chrome_sandbox is
  20 # the setuid sandbox and is its own target.
  21
  22 group("sandbox") {
  23   deps = [
  24     ":sandbox_services",
  25   ]
  26
  27   if (compile_suid_client) {
  28     deps += [ ":suid_sandbox_client" ]
  29   }
  30   if (use_seccomp_bpf) {
  31     deps += [
  32       ":seccomp_bpf",
  33       ":seccomp_bpf_helpers",
  34     ]
  35   }
  36 }
  37
  38 source_set("sandbox_linux_test_utils") {
  39   testonly = true
  40   sources = [
  41     "tests/sandbox_test_runner.cc",
  42     "tests/sandbox_test_runner.h",
  43     "tests/sandbox_test_runner_function_pointer.cc",
  44     "tests/sandbox_test_runner_function_pointer.h",
  45     "tests/test_utils.cc",
  46     "tests/test_utils.h",
  47     "tests/unit_tests.cc",
  48     "tests/unit_tests.h",
  49   ]
  50
  51   deps = [
  52     "//testing/gtest",
  53   ]
  54
  55   if (use_seccomp_bpf) {
  56     sources += [
  57       "seccomp-bpf/bpf_tester_compatibility_delegate.h",
  58       "seccomp-bpf/bpf_tests.h",
  59       "seccomp-bpf/sandbox_bpf_test_runner.cc",
  60       "seccomp-bpf/sandbox_bpf_test_runner.h",
  61     ]
  62     deps += [ ":seccomp_bpf" ]
  63   }
  64
  65   if (use_base_test_suite) {
  66     deps += [ "//base/test:test_support" ]
  67     defines = [ "SANDBOX_USES_BASE_TEST_SUITE" ]
  68   }
  69 }
  70
  71 # Sources shared by sandbox_linux_unittests and sandbox_linux_jni_unittests.
  72 source_set("sandbox_linux_unittests_sources") {
  73   testonly = true
  74
  75   sources = [
  76     "services/proc_util_unittest.cc",
  77     "services/resource_limits_unittests.cc",
  78     "services/scoped_process_unittest.cc",
  79     "services/syscall_wrappers_unittest.cc",
  80     "services/thread_helpers_unittests.cc",
  81     "services/yama_unittests.cc",
  82     "syscall_broker/broker_file_permission_unittest.cc",
  83     "syscall_broker/broker_process_unittest.cc",
  84     "tests/main.cc",
  85     "tests/scoped_temporary_file.cc",
  86     "tests/scoped_temporary_file.h",
  87     "tests/scoped_temporary_file_unittest.cc",
  88     "tests/test_utils_unittest.cc",
  89     "tests/unit_tests_unittest.cc",
  90   ]
  91
  92   deps = [
  93     ":sandbox",
  94     ":sandbox_linux_test_utils",
  95     "//base",
  96     "//testing/gtest",
  97   ]
  98
  99   if (use_base_test_suite) {
 100     deps += [ "//base/test:test_support" ]
 101     defines = [ "SANDBOX_USES_BASE_TEST_SUITE" ]
 102   }
 103
 104   if (is_linux) {
 105     # Don't use this on Android.
 106     libs = [ "rt" ]
 107   }
 108
 109   if (compile_suid_client) {
 110     sources += [
 111       "suid/client/setuid_sandbox_client_unittest.cc",
 112       "suid/client/setuid_sandbox_host_unittest.cc",
 113     ]
 114   }
 115   if (use_seccomp_bpf) {
 116     sources += [
 117       "bpf_dsl/bpf_dsl_unittest.cc",
 118       "bpf_dsl/codegen_unittest.cc",
 119       "bpf_dsl/cons_unittest.cc",
 120       "bpf_dsl/errorcode_unittest.cc",
 121       "bpf_dsl/syscall_set_unittest.cc",
 122       "bpf_dsl/test_trap_registry.cc",
 123       "bpf_dsl/test_trap_registry.h",
 124       "bpf_dsl/test_trap_registry_unittest.cc",
 125       "integration_tests/bpf_dsl_seccomp_unittest.cc",
 126       "integration_tests/seccomp_broker_process_unittest.cc",
 127       "seccomp-bpf-helpers/baseline_policy_unittest.cc",
 128       "seccomp-bpf-helpers/syscall_parameters_restrictions_unittests.cc",
 129       "seccomp-bpf/bpf_tests_unittest.cc",
 130       "seccomp-bpf/sandbox_bpf_unittest.cc",
 131       "seccomp-bpf/syscall_unittest.cc",
 132       "seccomp-bpf/trap_unittest.cc",
 133     ]
 134     deps += [ ":bpf_dsl_golden" ]
 135   }
 136   if (compile_credentials) {
 137     sources += [
 138       "integration_tests/namespace_unix_domain_socket_unittest.cc",
 139       "services/credentials_unittest.cc",
 140       "services/namespace_utils_unittest.cc",
 141     ]
 142
 143     if (use_base_test_suite) {
 144       # Tests that use advanced features not available in stock GTest.
 145       sources += [ "services/namespace_sandbox_unittest.cc" ]
 146     }
 147
 148     # For credentials_unittest.cc
 149     configs += [ "//build/config/linux:libcap" ]
 150   }
 151 }
 152
 153 action("bpf_dsl_golden") {
 154   script = "bpf_dsl/golden/generate.py"
 155   inputs = [
 156     "bpf_dsl/golden/i386/ArgSizePolicy.txt",
 157     "bpf_dsl/golden/i386/BasicPolicy.txt",
 158     "bpf_dsl/golden/i386/ElseIfPolicy.txt",
 159     "bpf_dsl/golden/i386/MaskingPolicy.txt",
 160     "bpf_dsl/golden/i386/MoreBooleanLogicPolicy.txt",
 161     "bpf_dsl/golden/i386/NegativeConstantsPolicy.txt",
 162     "bpf_dsl/golden/i386/SwitchPolicy.txt",
 163     "bpf_dsl/golden/x86-64/ArgSizePolicy.txt",
 164     "bpf_dsl/golden/x86-64/BasicPolicy.txt",
 165     "bpf_dsl/golden/x86-64/BooleanLogicPolicy.txt",
 166     "bpf_dsl/golden/x86-64/ElseIfPolicy.txt",
 167     "bpf_dsl/golden/x86-64/MaskingPolicy.txt",
 168     "bpf_dsl/golden/x86-64/MoreBooleanLogicPolicy.txt",
 169     "bpf_dsl/golden/x86-64/NegativeConstantsPolicy.txt",
 170     "bpf_dsl/golden/x86-64/SwitchPolicy.txt",
 171   ]
 172   outputs = [
 173     "$target_gen_dir/bpf_dsl/golden/golden_files.h",
 174   ]
 175   args =
 176       rebase_path(outputs, root_build_dir) + rebase_path(inputs, root_build_dir)
 177 }
 178
 179 # TODO(GYP): Delete this after we've converted everything to GN.
 180 # The _run targets exist only for compatibility w/ GYP.
 181 group("sandbox_linux_unittests_run") {
 182   testonly = true
 183   deps = [
 184     ":sandbox_linux_unittests",
 185   ]
 186 }
 187
 188 # The main sandboxing test target.
 189 test("sandbox_linux_unittests") {
 190   deps = [
 191     ":sandbox_linux_unittests_sources",
 192   ]
 193 }
 194
 195 # This target is the shared library used by Android APK (i.e.
 196 # JNI-friendly) tests.
 197 shared_library("sandbox_linux_jni_unittests") {
 198   testonly = true
 199   deps = [
 200     ":sandbox_linux_unittests_sources",
 201   ]
 202   if (is_android) {
 203     deps += [ "//testing/android/native_test:native_test_native_code" ]
 204   }
 205 }
 206
 207 component("seccomp_bpf") {
 208   sources = [
 209     "bpf_dsl/bpf_dsl.cc",
 210     "bpf_dsl/bpf_dsl.h",
 211     "bpf_dsl/bpf_dsl_forward.h",
 212     "bpf_dsl/bpf_dsl_impl.h",
 213     "bpf_dsl/codegen.cc",
 214     "bpf_dsl/codegen.h",
 215     "bpf_dsl/cons.h",
 216     "bpf_dsl/dump_bpf.cc",
 217     "bpf_dsl/dump_bpf.h",
 218     "bpf_dsl/errorcode.cc",
 219     "bpf_dsl/errorcode.h",
 220     "bpf_dsl/linux_syscall_ranges.h",
 221     "bpf_dsl/policy.cc",
 222     "bpf_dsl/policy.h",
 223     "bpf_dsl/policy_compiler.cc",
 224     "bpf_dsl/policy_compiler.h",
 225     "bpf_dsl/seccomp_macros.h",
 226     "bpf_dsl/syscall_set.cc",
 227     "bpf_dsl/syscall_set.h",
 228     "bpf_dsl/trap_registry.h",
 229     "bpf_dsl/verifier.cc",
 230     "bpf_dsl/verifier.h",
 231     "seccomp-bpf/die.cc",
 232     "seccomp-bpf/die.h",
 233     "seccomp-bpf/sandbox_bpf.cc",
 234     "seccomp-bpf/sandbox_bpf.h",
 235     "seccomp-bpf/syscall.cc",
 236     "seccomp-bpf/syscall.h",
 237     "seccomp-bpf/trap.cc",
 238     "seccomp-bpf/trap.h",
 239   ]
 240   defines = [ "SANDBOX_IMPLEMENTATION" ]
 241
 242   deps = [
 243     ":sandbox_services",
 244     ":sandbox_services_headers",
 245     "//base",
 246   ]
 247 }
 248
 249 component("seccomp_bpf_helpers") {
 250   sources = [
 251     "seccomp-bpf-helpers/baseline_policy.cc",
 252     "seccomp-bpf-helpers/baseline_policy.h",
 253     "seccomp-bpf-helpers/sigsys_handlers.cc",
 254     "seccomp-bpf-helpers/sigsys_handlers.h",
 255     "seccomp-bpf-helpers/syscall_parameters_restrictions.cc",
 256     "seccomp-bpf-helpers/syscall_parameters_restrictions.h",
 257     "seccomp-bpf-helpers/syscall_sets.cc",
 258     "seccomp-bpf-helpers/syscall_sets.h",
 259   ]
 260   defines = [ "SANDBOX_IMPLEMENTATION" ]
 261
 262   deps = [
 263     "//base",
 264     ":sandbox_services",
 265     ":seccomp_bpf",
 266   ]
 267 }
 268
 269 if (is_linux) {
 270   # The setuid sandbox for Linux.
 271   executable("chrome_sandbox") {
 272     sources = [
 273       "suid/common/sandbox.h",
 274       "suid/common/suid_unsafe_environment_variables.h",
 275       "suid/process_util.h",
 276       "suid/process_util_linux.c",
 277       "suid/sandbox.c",
 278     ]
 279
 280     cflags = [
 281       # For ULLONG_MAX
 282       "-std=gnu99",
 283
 284       # These files have a suspicious comparison.
 285       # TODO fix this and re-enable this warning.
 286       "-Wno-sign-compare",
 287     ]
 288   }
 289 }
 290
 291 component("sandbox_services") {
 292   sources = [
 293     "services/init_process_reaper.cc",
 294     "services/init_process_reaper.h",
 295     "services/proc_util.cc",
 296     "services/proc_util.h",
 297     "services/resource_limits.cc",
 298     "services/resource_limits.h",
 299     "services/scoped_process.cc",
 300     "services/scoped_process.h",
 301     "services/syscall_wrappers.cc",
 302     "services/syscall_wrappers.h",
 303     "services/thread_helpers.cc",
 304     "services/thread_helpers.h",
 305     "services/yama.cc",
 306     "services/yama.h",
 307     "syscall_broker/broker_channel.cc",
 308     "syscall_broker/broker_channel.h",
 309     "syscall_broker/broker_client.cc",
 310     "syscall_broker/broker_client.h",
 311     "syscall_broker/broker_common.h",
 312     "syscall_broker/broker_file_permission.cc",
 313     "syscall_broker/broker_file_permission.h",
 314     "syscall_broker/broker_host.cc",
 315     "syscall_broker/broker_host.h",
 316     "syscall_broker/broker_policy.cc",
 317     "syscall_broker/broker_policy.h",
 318     "syscall_broker/broker_process.cc",
 319     "syscall_broker/broker_process.h",
 320   ]
 321
 322   defines = [ "SANDBOX_IMPLEMENTATION" ]
 323
 324   deps = [
 325     "//base",
 326   ]
 327
 328   if (compile_credentials) {
 329     sources += [
 330       "services/credentials.cc",
 331       "services/credentials.h",
 332       "services/namespace_sandbox.cc",
 333       "services/namespace_sandbox.h",
 334       "services/namespace_utils.cc",
 335       "services/namespace_utils.h",
 336     ]
 337
 338     deps += [ ":sandbox_services_headers" ]
 339   }
 340 }
 341
 342 source_set("sandbox_services_headers") {
 343   sources = [
 344     "system_headers/arm64_linux_syscalls.h",
 345     "system_headers/arm64_linux_ucontext.h",
 346     "system_headers/arm_linux_syscalls.h",
 347     "system_headers/arm_linux_ucontext.h",
 348     "system_headers/i386_linux_ucontext.h",
 349     "system_headers/linux_futex.h",
 350     "system_headers/linux_seccomp.h",
 351     "system_headers/linux_signal.h",
 352     "system_headers/linux_syscalls.h",
 353     "system_headers/linux_time.h",
 354     "system_headers/linux_ucontext.h",
 355     "system_headers/x86_32_linux_syscalls.h",
 356     "system_headers/x86_64_linux_syscalls.h",
 357   ]
 358 }
 359
 360 # We make this its own target so that it does not interfere with our tests.
 361 source_set("libc_urandom_override") {
 362   sources = [
 363     "services/libc_urandom_override.cc",
 364     "services/libc_urandom_override.h",
 365   ]
 366   deps = [
 367     "//base",
 368   ]
 369 }
 370
 371 if (compile_suid_client) {
 372   component("suid_sandbox_client") {
 373     sources = [
 374       "suid/client/setuid_sandbox_client.cc",
 375       "suid/client/setuid_sandbox_client.h",
 376       "suid/client/setuid_sandbox_host.cc",
 377       "suid/client/setuid_sandbox_host.h",
 378       "suid/common/sandbox.h",
 379       "suid/common/suid_unsafe_environment_variables.h",
 380     ]
 381     defines = [ "SANDBOX_IMPLEMENTATION" ]
 382
 383     deps = [
 384       ":sandbox_services",
 385       "//base",
 386     ]
 387   }
 388 }
 389
 390 if (is_android) {
 391   # TODO(GYP) enable this. Needs an android_strip wrapper python script.
 392   #action("sandbox_linux_unittests_stripped") {
 393   #  script = "android_stip.py"
 394   #
 395   #  in_file = "$root_out_dir/sandbox_linux_unittests"
 396   #
 397   #  out_file = "$root_out_dir/sandbox_linux_unittests_stripped"
 398   #  outputs = [ out_file ]
 399   #
 400   #  args = [
 401   #    rebase_path(in_file, root_build_dir),
 402   #    "-o", rebase_path(out_file, root_build_dir),
 403   #  ]
 404   #
 405   #  deps = [
 406   #    ":sandbox_linux_unittests",
 407   #  ]
 408   #}
 409   # TODO(GYP) convert this.
 410   #      {
 411   #      'target_name': 'sandbox_linux_jni_unittests_apk',
 412   #      'type': 'none',
 413   #      'variables': {
 414   #        'test_suite_name': 'sandbox_linux_jni_unittests',
 415   #      },
 416   #      'dependencies': [
 417   #        'sandbox_linux_jni_unittests',
 418   #      ],
 419   #      'includes': [ '../../build/apk_test.gypi' ],
 420   #      }
 421 }