chrome/android/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/android/rules.gni")
   7 import("//build/module_args/v8.gni")
   8 import("//chrome/version.gni")
   9 import("//testing/test.gni")
  10 import("//third_party/icu/config.gni")
  11 import("//third_party/protobuf/proto_library.gni")
  12 import("channel.gni")
  13
  14 manifest_package = "org.chromium.chrome"
  15 if (enable_configuration_policy) {
  16   configuration_policy = 1
  17 } else {
  18   configuration_policy = 0
  19 }
  20
  21 jinja_variables = [
  22   "channel=$android_channel",
  23   "manifest_package=$manifest_package",
  24   "configuration_policy=$configuration_policy",
  25 ]
  26
  27 chrome_android_paks_gypi =
  28     exec_script("//build/gypi_to_gn.py",
  29                 [
  30                   rebase_path("//chrome/chrome_android_paks.gypi"),
  31                   "--replace=<(PRODUCT_DIR)=$root_out_dir",
  32                 ],
  33                 "scope",
  34                 [ "//chrome/chrome_android_paks.gypi" ])
  35
  36 locale_pak_resources("chrome_locale_paks") {
  37   sources = chrome_android_paks_gypi.chrome_android_pak_locale_resources
  38
  39   deps = [
  40     "//chrome:packed_resources",
  41   ]
  42 }
  43
  44 # GYP: //chrome/chrome.gyp:chrome_java (resources part)
  45 android_resources("chrome_java_resources") {
  46   resource_dirs = [
  47     "java/res",
  48     "java/res_default",
  49   ]
  50   deps = [
  51     ":chrome_locale_paks",
  52     ":chrome_strings_grd",
  53     "//components/policy:app_restrictions_resources",
  54     "//content/public/android:content_java_resources",
  55     "//chrome/app:java_strings_grd",
  56     "//third_party/android_data_chart:android_data_chart_java_resources",
  57     "//third_party/android_media:android_media_resources",
  58   ]
  59   if (!enable_configuration_policy) {
  60     deps -= [ "//components/policy:app_restrictions_resources" ]
  61   }
  62   custom_package = "org.chromium.chrome"
  63 }
  64
  65 # GYP: //chrome/chrome.gyp:chrome_strings_grd
  66 java_strings_grd("chrome_strings_grd") {
  67   grd_file = "java/strings/android_chrome_strings.grd"
  68   outputs = [
  69     "values-am/android_chrome_strings.xml",
  70     "values-ar/android_chrome_strings.xml",
  71     "values-bg/android_chrome_strings.xml",
  72     "values-ca/android_chrome_strings.xml",
  73     "values-cs/android_chrome_strings.xml",
  74     "values-da/android_chrome_strings.xml",
  75     "values-de/android_chrome_strings.xml",
  76     "values-el/android_chrome_strings.xml",
  77     "values/android_chrome_strings.xml",
  78     "values-en-rGB/android_chrome_strings.xml",
  79     "values-es/android_chrome_strings.xml",
  80     "values-es-rUS/android_chrome_strings.xml",
  81     "values-fa/android_chrome_strings.xml",
  82     "values-fi/android_chrome_strings.xml",
  83     "values-tl/android_chrome_strings.xml",
  84     "values-fr/android_chrome_strings.xml",
  85     "values-hi/android_chrome_strings.xml",
  86     "values-hr/android_chrome_strings.xml",
  87     "values-hu/android_chrome_strings.xml",
  88     "values-in/android_chrome_strings.xml",
  89     "values-it/android_chrome_strings.xml",
  90     "values-iw/android_chrome_strings.xml",
  91     "values-ja/android_chrome_strings.xml",
  92     "values-ko/android_chrome_strings.xml",
  93     "values-lt/android_chrome_strings.xml",
  94     "values-lv/android_chrome_strings.xml",
  95     "values-nl/android_chrome_strings.xml",
  96     "values-nb/android_chrome_strings.xml",
  97     "values-pl/android_chrome_strings.xml",
  98     "values-pt-rBR/android_chrome_strings.xml",
  99     "values-pt-rPT/android_chrome_strings.xml",
 100     "values-ro/android_chrome_strings.xml",
 101     "values-ru/android_chrome_strings.xml",
 102     "values-sk/android_chrome_strings.xml",
 103     "values-sl/android_chrome_strings.xml",
 104     "values-sr/android_chrome_strings.xml",
 105     "values-sv/android_chrome_strings.xml",
 106     "values-sw/android_chrome_strings.xml",
 107     "values-th/android_chrome_strings.xml",
 108     "values-tr/android_chrome_strings.xml",
 109     "values-uk/android_chrome_strings.xml",
 110     "values-vi/android_chrome_strings.xml",
 111     "values-zh-rCN/android_chrome_strings.xml",
 112     "values-zh-rTW/android_chrome_strings.xml",
 113   ]
 114 }
 115
 116 # GYP: //chrome/chrome.gyp:chrome_java
 117 android_library("chrome_java") {
 118   deps = [
 119     ":chrome_java_resources",
 120     ":document_tab_model_info_proto_java",
 121     "//base:base_java",
 122     "//net/android:net_java",
 123     "//components/bookmarks/common/android:bookmarks_java",
 124     "//components/dom_distiller/android:dom_distiller_content_java",
 125     "//components/dom_distiller/android:dom_distiller_core_java",
 126     "//components/gcm_driver/android:gcm_driver_java",
 127     "//components/invalidation/impl:java",
 128     "//components/navigation_interception/android:navigation_interception_java",
 129     "//components/service_tab_launcher:service_tab_launcher_java",
 130     "//components/precache/android:precache_java",
 131     "//components/variations/android:variations_java",
 132     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 133     "//content/public/android:content_java",
 134     "//media/base/android:media_java",
 135     "//printing:printing_java",
 136     "//sync/android:sync_java",
 137     "//third_party/android_data_chart:android_data_chart_java",
 138     "//third_party/android_media:android_media_java",
 139     "//third_party/android_protobuf:protobuf_nano_javalib",
 140     "//third_party/android_swipe_refresh:android_swipe_refresh_java",
 141     "//third_party/android_tools:android_gcm_java",
 142     "//third_party/android_tools:android_support_v13_java",
 143     "//third_party/android_tools:android_support_v7_appcompat_java",
 144     "//third_party/android_tools:android_support_v7_mediarouter_java",
 145     "//third_party/android_tools:android_support_v7_mediarouter_resources",
 146     "//third_party/android_tools:android_support_v7_recyclerview_java",
 147     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 148     "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 149     "//third_party/jsr-305:jsr_305_javalib",
 150     "//media/base/android:media_java",
 151     "//media/midi:midi_java",
 152     "//ui/android:ui_java",
 153     "//ui/android:ui_java_resources",
 154     google_play_services_library,
 155   ]
 156
 157   srcjar_deps = [
 158     ":chrome_android_java_enums_srcjar",
 159     ":chrome_version_srcjar",
 160     ":custom_tabs_service_aidl",
 161     ":resource_id_javagen",
 162     "//chrome:page_info_connection_type_javagen",
 163     "//chrome:content_setting_javagen",
 164     "//chrome:content_settings_type_javagen",
 165     "//components/enhanced_bookmarks:enhanced_bookmarks_java_enums_srcjar",
 166   ]
 167
 168   DEPRECATED_java_in_dir = "java/src"
 169 }
 170
 171 # GYP: //chrome/chrome_browser.gypi:activity_type_ids_java
 172 # GYP: //chrome/chrome_browser.gypi:profile_account_management_metrics_java
 173 # GYP: //chrome/chrome_browser.gypi:profile_sync_service_model_type_selection_java
 174 # GYP: //chrome/chrome_browser.gypi:connection_security_security_levels_java
 175 # GYP: //chrome/chrome_browser.gypi:tab_load_status_java
 176 java_cpp_enum("chrome_android_java_enums_srcjar") {
 177   sources = [
 178     "//chrome/browser/android/activity_type_ids.h",
 179     "//chrome/browser/android/tab_android.h",
 180     "//chrome/browser/profiles/profile_metrics.h",
 181     "//chrome/browser/ssl/connection_security.h",
 182     "//chrome/browser/sync/profile_sync_service_android.cc",
 183   ]
 184   outputs = [
 185     "org/chromium/chrome/browser/ActivityTypeIds.java",
 186     "org/chromium/chrome/browser/TabLoadStatus.java",
 187     "org/chromium/chrome/browser/profiles/ProfileAccountManagementMetrics.java",
 188     "org/chromium/chrome/browser/ssl/ConnectionSecurityLevel.java",
 189     "org/chromium/chrome/browser/sync/ModelTypeSelection.java",
 190   ]
 191 }
 192
 193 # GYP: //chrome/chrome_browser.gypi:document_tab_model_info_proto_java
 194 proto_java_library("document_tab_model_info_proto_java") {
 195   proto_path = "java/src/org/chromium/chrome/browser/tabmodel/document"
 196   sources = [
 197     "$proto_path/document_tab_model_info.proto",
 198   ]
 199 }
 200
 201 # GYP: //chrome/chrome_browser.gypi:resource_id_java
 202 java_cpp_template("resource_id_javagen") {
 203   sources = [
 204     "java/ResourceId.template",
 205   ]
 206   package_name = "org/chromium/chrome/browser"
 207   inputs = [
 208     "../browser/android/resource_id.h",
 209   ]
 210 }
 211
 212 # GYP: //chrome/chrome_shell.gypi:libchromeshell_base
 213 group("chrome_shell_base") {
 214   deps = [
 215     "//chrome/browser/ui",
 216     "//chrome:chrome_android_core",
 217     "//base",
 218     "//base/allocator",
 219     "//content/public/app:both",
 220     "//skia",
 221   ]
 222   # TODO(GYP):
 223   #[ 'order_profiling!=0', {
 224   #'dependencies': [ '../tools/cygprofile/cygprofile.gyp:cygprofile', ],
 225   #}],
 226 }
 227
 228 # GYP: //chrome/chrome_shell.gypi:libchromeshell
 229 shared_library("chrome_shell") {
 230   testonly = true
 231   sources = [
 232     "shell/chrome_main_delegate_chrome_shell_android.cc",
 233     "shell/chrome_main_delegate_chrome_shell_android.h",
 234     "shell/chrome_shell_entry_point.cc",
 235   ]
 236   deps = [
 237     ":chrome_shell_base",
 238   ]
 239 }
 240
 241 # GYP: //chrome/chrome_shell.gypi:libchromesyncshell
 242 shared_library("chrome_sync_shell") {
 243   testonly = true
 244   sources = [
 245     #"shell/chrome_shell_entry_point.cc",
 246     #"sync_shell/chrome_main_delegate_chrome_sync_shell_android.cc",
 247     #"sync_shell/chrome_main_delegate_chrome_sync_shell_android.h",
 248   ]
 249   deps = [
 250     "//sync:test_support_sync_fake_server_android",
 251   ]
 252   data_deps = [ ":chrome_shell_base" ]
 253 }
 254
 255 # GYP: N/A
 256 android_resources("chrome_shell_resources") {
 257   deps = [
 258     ":chrome_java_resources",
 259   ]
 260   testonly = true
 261   resource_dirs = [ "shell/res" ]
 262   custom_package = "org.chromium.chrome.shell"
 263 }
 264
 265 # GYP: N/A
 266 android_library("chrome_shell_java") {
 267   testonly = true
 268   deps = [
 269     ":chrome_java",
 270     ":chrome_java_resources",
 271     ":chrome_shell_resources",
 272     "//base:base_java",
 273     "//content/public/android:content_java",
 274     "//components/dom_distiller/android:dom_distiller_content_java",
 275     "//components/dom_distiller/android:dom_distiller_core_java",
 276     "//components/service_tab_launcher:service_tab_launcher_java",
 277     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 278     "//printing:printing_java",
 279     "//net/android:net_java",
 280     "//sync/android:sync_java",
 281     "//third_party/android_tools:android_support_v13_java",
 282     "//third_party/android_tools:android_support_v7_appcompat_java",
 283     "//ui/android:ui_java",
 284   ]
 285   DEPRECATED_java_in_dir = "shell/java/src"
 286 }
 287
 288 chrome_shell_assets_dir = "$root_build_dir/chrome_shell/assets"
 289
 290 # GYP: N/A
 291 copy_ex("chrome_shell_assets") {
 292   clear_dir = true
 293   dest = chrome_shell_assets_dir
 294   sources = [
 295     "$root_build_dir/chrome_100_percent.pak",
 296     "$root_build_dir/locales/am.pak",
 297     "$root_build_dir/locales/ar.pak",
 298     "$root_build_dir/locales/bg.pak",
 299     "$root_build_dir/locales/ca.pak",
 300     "$root_build_dir/locales/cs.pak",
 301     "$root_build_dir/locales/da.pak",
 302     "$root_build_dir/locales/de.pak",
 303     "$root_build_dir/locales/el.pak",
 304     "$root_build_dir/locales/en-GB.pak",
 305     "$root_build_dir/locales/en-US.pak",
 306     "$root_build_dir/locales/es-419.pak",
 307     "$root_build_dir/locales/es.pak",
 308     "$root_build_dir/locales/fa.pak",
 309     "$root_build_dir/locales/fi.pak",
 310     "$root_build_dir/locales/fil.pak",
 311     "$root_build_dir/locales/fr.pak",
 312     "$root_build_dir/locales/he.pak",
 313     "$root_build_dir/locales/hi.pak",
 314     "$root_build_dir/locales/hr.pak",
 315     "$root_build_dir/locales/hu.pak",
 316     "$root_build_dir/locales/id.pak",
 317     "$root_build_dir/locales/it.pak",
 318     "$root_build_dir/locales/ja.pak",
 319     "$root_build_dir/locales/ko.pak",
 320     "$root_build_dir/locales/lt.pak",
 321     "$root_build_dir/locales/lv.pak",
 322     "$root_build_dir/locales/nb.pak",
 323     "$root_build_dir/locales/nl.pak",
 324     "$root_build_dir/locales/pl.pak",
 325     "$root_build_dir/locales/pt-BR.pak",
 326     "$root_build_dir/locales/pt-PT.pak",
 327     "$root_build_dir/locales/ro.pak",
 328     "$root_build_dir/locales/ru.pak",
 329     "$root_build_dir/locales/sk.pak",
 330     "$root_build_dir/locales/sl.pak",
 331     "$root_build_dir/locales/sr.pak",
 332     "$root_build_dir/locales/sv.pak",
 333     "$root_build_dir/locales/sw.pak",
 334     "$root_build_dir/locales/th.pak",
 335     "$root_build_dir/locales/tr.pak",
 336     "$root_build_dir/locales/uk.pak",
 337     "$root_build_dir/locales/vi.pak",
 338     "$root_build_dir/locales/zh-CN.pak",
 339     "$root_build_dir/locales/zh-TW.pak",
 340     "$root_build_dir/resources.pak",
 341   ]
 342   deps = [
 343     "//chrome:packed_resources",
 344     "//chrome:packed_extra_resources",
 345   ]
 346
 347   if (icu_use_data_file) {
 348     sources += [ "$root_build_dir/icudtl.dat" ]
 349     deps += [ "//third_party/icu:icudata" ]
 350   }
 351   if (v8_use_external_startup_data) {
 352     sources += [
 353       "$root_build_dir/natives_blob.bin",
 354       "$root_build_dir/snapshot_blob.bin",
 355     ]
 356     deps += [ "//v8" ]
 357   }
 358 }
 359
 360 chrome_shell_manifest =
 361     "$target_gen_dir/chrome_shell_manifest/AndroidManifest.xml"
 362
 363 # GYP: //chrome/chrome_shell.gypi:chrome_shell_manifest
 364 jinja_template("chrome_shell_manifest") {
 365   testonly = true
 366   input = "shell/java/AndroidManifest.xml.jinja2"
 367   output = chrome_shell_manifest
 368 }
 369
 370 # TODO(cjhopman): This should actually be done as a build step instead of at gn
 371 # time.
 372 _version_py_path = "//build/util/version.py"
 373 _chrome_version_path = "//chrome/VERSION"
 374 _version_full = exec_script(_version_py_path,
 375                             [
 376                               "-f",
 377                               rebase_path(_chrome_version_path, root_build_dir),
 378                               "-t \"@MAJOR@.@MINOR@.@BUILD@.@PATCH@\"",
 379                             ],
 380                             "value",
 381                             [ _chrome_version_path ])
 382
 383 # GYP: //chrome/chrome_shell.gypi:chrome_shell_apk
 384 android_apk("chrome_shell_apk") {
 385   testonly = true
 386   deps = [
 387     ":chrome_shell",
 388     ":chrome_shell_assets",
 389     ":chrome_shell_java",
 390     ":chrome_shell_manifest",
 391     ":chrome_shell_resources",
 392     "//base:base_java",
 393   ]
 394   apk_name = "ChromeShell"
 395   android_manifest = chrome_shell_manifest
 396   native_libs = [ "libchrome_shell.so" ]
 397   native_lib_version_name = _version_full
 398   asset_location = chrome_shell_assets_dir
 399
 400   #TODO(GYP):
 401   #'variables': {
 402   #'conditions': [
 403   #['component != "shared_library" and target_arch != "arm64" and target_arch != "x64" and profiling_full_stack_frames != 1', {
 404   ## Only enable the chromium linker on regular builds, since the
 405   ## component build crashes on Android 4.4. See b/11379966
 406   #'use_chromium_linker': '1',
 407   #}],
 408   #],
 409   #},
 410 }
 411
 412 chrome_sync_shell_manifest =
 413     "$target_gen_dir/chrome_sync_shell_manifest/AndroidManifest.xml"
 414
 415 # GYP: //chrome/chrome_shell.gypi:chrome_sync_shell_manifest
 416 jinja_template("chrome_sync_shell_manifest") {
 417   testonly = true
 418   input = "sync_shell/java/AndroidManifest.xml.jinja2"
 419   output = chrome_sync_shell_manifest
 420 }
 421
 422 # GYP: //chrome/chrome_shell.gypi:chrome_sync_shell_apk
 423 android_apk("chrome_sync_shell_apk") {
 424   testonly = true
 425   deps = [
 426     ":chrome_shell_resources",
 427     ":chrome_shell_java",
 428     ":chrome_shell_assets",
 429     ":chrome_sync_shell",
 430     ":chrome_sync_shell_manifest",
 431     "//base:base_java",
 432   ]
 433   apk_name = "ChromeSyncShell"
 434   android_manifest = chrome_sync_shell_manifest
 435   native_libs = [ "libchrome_sync_shell.so" ]
 436   asset_location = chrome_shell_assets_dir
 437 }
 438
 439 # GYP: part of //chrome/chrome_tests.gypi:chrome_shell_test_apk
 440 android_library("chrome_javatests") {
 441   testonly = true
 442   DEPRECATED_java_in_dir = "javatests_shell/src"
 443   deps = [
 444     ":chrome_java",
 445     ":chrome_java_resources",
 446     ":chrome_shell_java",
 447     ":chrome_shell_resources",
 448     ":chrome_shell_test_java",
 449     "//base:base_java",
 450     "//base:base_java_test_support",
 451     "//chrome/test/android:chrome_java_test_support",
 452     "//components/bookmarks/common/android:bookmarks_java",
 453     "//components/dom_distiller/android:dom_distiller_core_java",
 454     "//components/invalidation/impl:java",
 455     "//components/invalidation/impl:javatests",
 456     "//components/navigation_interception/android:navigation_interception_java",
 457     "//components/precache/android:precache_java",
 458     "//components/precache/android:precache_javatests",
 459     "//content/public/android:content_java",
 460     "//content/public/test/android:content_java_test_support",
 461     "//net/android:net_java_test_support",
 462     "//printing:printing_java",
 463     "//sync/android:sync_java",
 464     "//sync/android:sync_javatests",
 465     "//sync:sync_java_test_support",
 466     "//third_party/android_protobuf:protobuf_nano_javalib",
 467     "//third_party/android_tools:android_support_v13_java",
 468     "//third_party/android_tools:android_support_v7_appcompat_java",
 469     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 470     "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 471     "//third_party/jsr-305:jsr_305_javalib",
 472     "//ui/android:ui_java",
 473   ]
 474 }
 475
 476 android_library("chrome_shell_test_java") {
 477   testonly = true
 478   deps = [
 479     ":chrome_java",
 480     ":chrome_shell_java",
 481     "//base:base_java",
 482     "//base:base_java_test_support",
 483     "//chrome/test/android:chrome_java_test_support",
 484     "//content/public/android:content_java",
 485     "//content/public/test/android:content_java_test_support",
 486     "//third_party/android_tools:android_support_v13_java",
 487     "//third_party/android_tools:android_support_v7_appcompat_java",
 488     "//ui/android:ui_java",
 489   ]
 490   DEPRECATED_java_in_dir = "shell/javatests/src"
 491 }
 492
 493 # GYP: //chrome/chrome_tests.gypi:chrome_shell_test_apk
 494 instrumentation_test_apk("chrome_shell_test_apk") {
 495   apk_under_test = ":chrome_shell_apk"
 496   deps = [
 497     ":chrome_javatests",
 498     ":chrome_shell_test_java",
 499     "//sync/android:sync_javatests",
 500     "//ui/android:ui_javatests",
 501   ]
 502   apk_name = "ChromeShellTest"
 503   android_manifest = "shell/javatests/AndroidManifest.xml"
 504   isolate_file = "../chrome_shell_test_apk.isolate"
 505 }
 506
 507 # GYP: //chrome/chrome_tests.gypi:chrome_junit_tests
 508 junit_binary("chrome_junit_tests") {
 509   java_files = [
 510     "junit/src/org/chromium/chrome/browser/child_accounts/ChildAccountServiceTest.java",
 511     "junit/src/org/chromium/chrome/browser/externalauth/ExternalAuthUtilsTest.java",
 512     "junit/src/org/chromium/chrome/browser/omaha/ResponseParserTest.java",
 513     "junit/src/org/chromium/chrome/browser/media/remote/AbstractMediaRouteControllerTest.java",
 514     "junit/src/org/chromium/chrome/browser/media/remote/MediaUrlResolverTest.java",
 515     "junit/src/org/chromium/chrome/browser/media/remote/RemoteVideoInfoTest.java",
 516     "junit/src/org/chromium/chrome/browser/media/remote/TransportControlTest.java",
 517   ]
 518   deps = [
 519     ":chrome_java",
 520     "//base:base_java",
 521     "//base:base_java_test_support",
 522     "//sync:sync_java_test_support",
 523     "//third_party/junit:hamcrest",
 524     "//third_party/android_tools:android_support_v7_mediarouter_java",
 525   ]
 526 }
 527
 528 # GYP: //chrome/chrome_tests.gypi:chrome_sync_shell_test_apk
 529 if (false) {
 530   # TODO(GYP): We need sync/sync_tests.gypi:test_support_sync_proto_java to be ported.
 531   # crbug.com/475612
 532   instrumentation_test_apk("chrome_sync_shell_test_apk") {
 533     apk_under_test = ":chrome_sync_shell_apk"
 534     deps = [
 535       ":chrome_java",
 536       ":chrome_shell_java",
 537       ":chrome_shell_test_java",
 538       "//base:base_java",
 539       "//base:base_java_test_support",
 540       "//chrome/test/android:chrome_java_test_support",
 541       "//components/invalidation/impl:java",
 542       "//content/public/android:content_java",
 543       "//content/public/test/android:content_java_test_support",
 544       "//sync/android:sync_java",
 545       "//sync:sync_java_test_support",
 546       "//third_party/android_tools:android_support_v13_java",
 547       "//third_party/android_tools:android_support_v7_appcompat_java",
 548       "//ui/android:ui_java",
 549     ]
 550     apk_name = "ChromeSyncShellTest"
 551     DEPRECATED_java_in_dir = "sync_shell/javatests/src"
 552     android_manifest = "sync_shell/javatests/AndroidManifest.xml"
 553   }
 554 }
 555
 556 # GYP: //chrome/chrome_tests.gypi:chrome_shell_uiautomator_tests_java
 557 android_library("uiautomator_tests_java") {
 558   testonly = true
 559   DEPRECATED_java_in_dir = "uiautomator_tests/src"
 560   deps = [
 561     "//base:base_java_test_support",
 562     "//third_party/android_tools:uiautomator_java",
 563   ]
 564 }
 565
 566 # GYP: //chrome/chrome_tests.gypi:chrome_shell_uiautomator_tests
 567 uiautomator_test("uiautomator_tests") {
 568   testonly = true
 569   deps = [
 570     ":uiautomator_tests_java",
 571   ]
 572 }
 573
 574 # GYP: //chrome/chrome_android.gypi:chrome_version_java
 575 chrome_version_java_dir = "$root_gen_dir/templates/chrome_version_java"
 576 chrome_version_java_file = "$chrome_version_java_dir/org/chromium/chrome/browser/ChromeVersionConstants.java"
 577 process_version("chrome_version_java") {
 578   template_file = "java/ChromeVersionConstants.java.version"
 579   output = chrome_version_java_file
 580   extra_args = [
 581     "-e",
 582     "CHANNEL=str.upper('$android_channel')",
 583   ]
 584 }
 585
 586 zip("chrome_version_srcjar") {
 587   inputs = [
 588     chrome_version_java_file,
 589   ]
 590   output = "$target_gen_dir/$target_name.srcjar"
 591   base_dir = chrome_version_java_dir
 592   deps = [
 593     ":chrome_version_java",
 594   ]
 595 }
 596
 597 #GYP: //chrome/android/chrome_apk.gyp:custom_tabs_service_aidl
 598 android_aidl("custom_tabs_service_aidl") {
 599   import_include = "java/src/org/chromium/chrome/browser/customtabs"
 600   interface_file = "java/src/org/chromium/chrome/browser/customtabs/common.aidl"
 601   sources = [
 602     "java/src/org/chromium/chrome/browser/customtabs/ICustomTabsConnectionCallback.aidl",
 603     "java/src/org/chromium/chrome/browser/customtabs/ICustomTabsConnectionService.aidl",
 604   ]
 605 }
 606
 607 # GYP: //chrome/android/chrome_apk.gyp:chrome_shared_test_java
 608 android_library("chrome_shared_test_java") {
 609   testonly = true
 610   DEPRECATED_java_in_dir = "javatests/src"
 611
 612   deps = [
 613     "//base:base_java",
 614     "//base:base_java_test_support",
 615     "//chrome/android:chrome_java",
 616     "//chrome/android:chrome_java_resources",
 617     "//chrome/test/android:chrome_java_test_support",
 618     "//components/bookmarks/common/android:bookmarks_java",
 619     "//components/dom_distiller/android:dom_distiller_core_java",
 620     "//components/invalidation/impl:java",
 621     "//components/precache/android:precache_java",
 622     "//components/precache/android:precache_javatests",
 623     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 624     "//content/public/android:content_java",
 625     "//content/public/test/android:content_java_test_support",
 626     "//net/android:net_java",
 627     "//net/android:net_java_test_support",
 628     "//sync/android:sync_java",
 629     "//sync:sync_java_test_support",
 630     "//third_party/android_tools:android_support_v7_appcompat_java",
 631     "//third_party/android_tools:android_support_v7_recyclerview_java",
 632     "//third_party/android_tools:android_support_v13_java",
 633     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 634     "//third_party/jsr-305:jsr_305_javalib",
 635     "//ui/android:ui_java",
 636   ]
 637 }
 638
 639 chrome_public_apk_assets_dir = "$root_build_dir/chrome_public_apk_assets"
 640
 641 copy_ex("chrome_public_apk_assets") {
 642   clear_dir = true
 643   dest = chrome_public_apk_assets_dir
 644   sources = chrome_android_paks_gypi.chrome_android_pak_input_resources
 645   if (icu_use_data_file) {
 646     sources += [ "$root_build_dir/icudtl.dat" ]
 647   }
 648   deps = [
 649     "//chrome:packed_extra_resources",
 650     "//chrome:packed_resources",
 651     "//third_party/icu:icudata",
 652   ]
 653
 654   if (v8_use_external_startup_data) {
 655     sources += [
 656       "$root_build_dir/natives_blob.bin",
 657       "$root_build_dir/snapshot_blob.bin",
 658     ]
 659     deps += [ "//v8" ]
 660   }
 661
 662   sources += [ "$root_build_dir/resources.pak" ]
 663 }
 664
 665 # GYP: //chrome/android/chrome_apk.gyp:chrome_apk_manifest
 666 jinja_template("chrome_public_apk_manifest") {
 667   input = "java/AndroidManifest.xml"
 668   output = "$root_gen_dir/chrome_public_apk_manifest/AndroidManifest.xml"
 669   variables = jinja_variables
 670   variables += [
 671     "min_sdk_version=16",
 672     "target_sdk_version=22",
 673   ]
 674 }
 675
 676 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_template_resources
 677 jinja_template_resources("chrome_public_template_resources") {
 678   resources = [
 679     "java/res_template/xml/searchable.xml",
 680     "java/res_template/xml/syncadapter.xml",
 681   ]
 682   res_dir = "java/res_template"
 683   variables = jinja_variables
 684 }
 685
 686 # GYP: //chrome/android/chrome_apk.gyp:libchrome_public
 687 shared_library("chrome_public") {
 688   deps = [
 689     "//chrome:chrome_android_core",
 690   ]
 691   gypi_values = exec_script(
 692           "//build/gypi_to_gn.py",
 693           [
 694             rebase_path("chrome_apk.gyp"),
 695             "--replace=<(chrome_native_sources_dir)=../browser/android/",
 696           ],
 697           "scope",
 698           [ "chrome_apk.gyp" ])
 699   sources = gypi_values.chrome_public_app_native_sources
 700
 701   # TODO(GYP):
 702   #'target_conditions': [
 703   #['component != "shared_library"', {
 704   #'product_extension': '<(version_libchrome_short).so',
 705   #}],
 706   #],
 707 }
 708
 709 android_apk("chrome_public_apk") {
 710   version_name = "Developer Build"
 711   version_code = "1"
 712   android_manifest = get_target_outputs(":chrome_public_apk_manifest")
 713   android_manifest = android_manifest[1]
 714   apk_name = "ChromePublic"
 715   native_libs = [ "$root_build_dir/lib.stripped/libchrome_public.so" ]
 716   native_lib_version_name = _version_full
 717   asset_location = chrome_public_apk_assets_dir
 718
 719   deps = [
 720     ":chrome_java",
 721     ":chrome_java_resources",
 722     ":chrome_public",
 723     ":chrome_public_apk_assets",
 724     ":chrome_public_apk_manifest",
 725     ":chrome_public_template_resources",
 726     "//base:base_java",
 727     "//third_party/android_tools:google_play_services_default_resources",
 728   ]
 729 }
 730
 731 chrome_public_test_apk_manifest =
 732     "$root_gen_dir/chrome_public_test_apk_manifest/AndroidManifest.xml"
 733
 734 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_test_apk_manifest
 735 jinja_template("chrome_public_test_apk_manifest") {
 736   input = "javatests/AndroidManifest.xml"
 737   output = chrome_public_test_apk_manifest
 738   variables = jinja_variables
 739 }
 740
 741 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_test_apk
 742 instrumentation_test_apk("chrome_public_test_apk") {
 743   # TODO(GYP,cjhopman): Does this need version code/name?
 744   apk_name = "ChromePublicTest"
 745   apk_under_test = ":chrome_public_apk"
 746   android_manifest = chrome_public_test_apk_manifest
 747   deps = [
 748     ":chrome_public_test_apk_manifest",
 749     "//chrome/android:chrome_shared_test_java",
 750   ]
 751   isolate_file = "../chrome_public_test_apk.isolate"
 752 }