remoting/remoting_version.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6
   7 _version_py_abspath = "//build/util/version.py"
   8 _remoting_version_abspath = "//remoting/VERSION"
   9 _chrome_version_abspath = "//chrome/VERSION"
  10 if (is_chrome_branded) {
  11   _remoting_branding_abspath = "//remoting/branding_Chrome"
  12 } else {
  13   _remoting_branding_abspath = "//remoting/branding_Chromium"
  14 }
  15
  16 # Set these files as being input dependencies to the scripts, so the build will
  17 # be re-run if the files change.
  18 _script_deps = [
  19   _remoting_version_abspath,
  20   _chrome_version_abspath,
  21   _remoting_branding_abspath,
  22 ]
  23
  24 _chrome_version_path = rebase_path(_chrome_version_abspath, root_build_dir)
  25 _remoting_version_path = rebase_path(_remoting_version_abspath, root_build_dir)
  26 _remoting_branding_path =
  27     rebase_path(_remoting_branding_abspath, root_build_dir)
  28
  29 version_major = exec_script(_version_py_abspath,
  30                             [
  31                               "-f",
  32                               _chrome_version_path,
  33                               "-f",
  34                               _remoting_version_path,
  35                               "-t \"@MAJOR@\"",
  36                             ],
  37                             "value",
  38                             _script_deps)
  39
  40 version_minor = exec_script(_version_py_abspath,
  41                             [
  42                               "-f",
  43                               _remoting_version_path,
  44                               "-t \"@REMOTING_PATCH@\"",
  45                             ],
  46                             "value",
  47                             _script_deps)
  48
  49 version_short =
  50     "${version_major}.${version_minor}." + exec_script(_version_py_abspath,
  51                                                        [
  52                                                          "-f",
  53                                                          _chrome_version_path,
  54                                                          "-f",
  55                                                          _remoting_version_path,
  56                                                          "-t \"@BUILD@\"",
  57                                                        ],
  58                                                        "value",
  59                                                        _script_deps)
  60
  61 version_full = "${version_short}." + exec_script(_version_py_abspath,
  62                                                  [
  63                                                    "-f",
  64                                                    _chrome_version_path,
  65                                                    "-f",
  66                                                    _remoting_version_path,
  67                                                    "-t \"@PATCH@\"",
  68                                                  ],
  69                                                  "value",
  70                                                  _script_deps)
  71
  72 prefpane_bundle_name = exec_script(_version_py_abspath,
  73                                    [
  74                                      "-f",
  75                                      _remoting_branding_path,
  76                                      "-t \"@MAC_PREFPANE_BUNDLE_NAME@\"",
  77                                    ],
  78                                    "string",
  79                                    _script_deps)
  80
  81 host_bundle_name = exec_script(_version_py_abspath,
  82                                [
  83                                  "-f",
  84                                  _remoting_branding_path,
  85                                  "-t \"@MAC_HOST_BUNDLE_NAME@\"",
  86                                ],
  87                                "string",
  88                                _script_deps)