mojo/services/native_viewport/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//mojo/system.gni")
   7
   8 static_library("native_viewport") {
   9   output_name = "mojo_native_viewport"
  10
  11   deps = [
  12     "//base",
  13     "//ui/events",
  14     "//ui/events/platform",
  15     "//ui/gfx",
  16     "//ui/gfx/geometry",
  17     "//mojo/public/cpp/application:chromium",
  18     "//mojo/common",
  19     "//mojo/environment:chromium",
  20     "//mojo/services/public/cpp/geometry",
  21     "//mojo/services/public/interfaces/geometry",
  22     "//mojo/services/gles2",
  23     "//mojo/services/public/cpp/input_events",
  24     "//mojo/services/public/interfaces/native_viewport",
  25   ]
  26
  27   sources = [
  28     "gpu_impl.cc",
  29     "gpu_impl.h",
  30     "native_viewport_impl.cc",
  31     "native_viewport_impl.h",
  32     "platform_viewport.h",
  33     "platform_viewport_android.cc",
  34     "platform_viewport_android.h",
  35     "platform_viewport_mac.mm",
  36     "platform_viewport_win.cc",
  37   ]
  38
  39   if (is_ios) {
  40     sources += [ "platform_viewport_stub.cc" ]
  41   }
  42
  43   if (is_android) {
  44     deps += [ "//mojo:jni_headers" ]
  45   }
  46
  47   if (is_win) {
  48     deps += [
  49       # TODO(GYP)
  50       # '../ui/platform_window/win/win_window.gyp:win_window',
  51     ]
  52   }
  53
  54   if (use_x11) {
  55     sources += [ "platform_viewport_x11.cc" ]
  56     deps += [
  57       "//ui/events/platform/x11",
  58       "//ui/platform_window/x11",
  59     ]
  60   }
  61
  62   if (use_ozone) {
  63     sources += [ "platform_viewport_ozone.cc" ]
  64   }
  65 }