ppapi/ppapi_cpp.gypi

   1 # Copyright (c) 2011 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # Shared source lists between trusted and untrusted targets are stored in
   6 # ppapi_sources.gypi.
   7
   8 {
   9   'includes': [
  10     'ppapi_sources.gypi',
  11   ],
  12   'targets': [
  13     {
  14       # GN version: //ppapi:ppapi_c
  15       'target_name': 'ppapi_c',
  16       'type': 'none',
  17       'all_dependent_settings': {
  18         'include_dirs+': [
  19           '..',
  20         ],
  21       },
  22       'sources': [
  23         '<@(c_source_files)',
  24       ],
  25     },
  26     {
  27       # GN version: //ppapi:ppapi_cpp_objects
  28       'target_name': 'ppapi_cpp_objects',
  29       'type': 'static_library',
  30       'dependencies': [
  31         'ppapi_c'
  32       ],
  33       'include_dirs+': [
  34         '..',
  35       ],
  36       'sources': [
  37         '<@(cpp_source_files)',
  38       ],
  39       'conditions': [
  40         ['OS=="win"', {
  41           'msvs_settings': {
  42             'VCCLCompilerTool': {
  43               'AdditionalOptions': ['/we4244'],  # implicit conversion, possible loss of data
  44             },
  45           },
  46           'msvs_disabled_warnings': [
  47             4267,
  48           ],
  49         }],
  50         ['OS=="linux"', {
  51           'cflags': ['-Wextra', '-pedantic'],
  52         }],
  53         ['OS=="mac"', {
  54           'xcode_settings': {
  55             'WARNING_CFLAGS': ['-Wextra', '-pedantic'],
  56            },
  57         }],
  58       ],
  59     },
  60     {
  61       # GN version: //ppapi:ppapi_cpp
  62       'target_name': 'ppapi_cpp',
  63       'type': 'static_library',
  64       'dependencies': [
  65         'ppapi_c',
  66         'ppapi_cpp_objects',
  67       ],
  68       'include_dirs+': [
  69         '..',
  70       ],
  71       'sources': [
  72         'cpp/module_embedder.h',
  73         'cpp/ppp_entrypoints.cc',
  74       ],
  75       'conditions': [
  76         ['OS=="linux"', {
  77           'cflags': ['-Wextra', '-pedantic'],
  78         }],
  79         ['OS=="mac"', {
  80           'xcode_settings': {
  81             'WARNING_CFLAGS': ['-Wextra', '-pedantic'],
  82            },
  83         }]
  84       ],
  85     },
  86     {
  87       # GN version: //ppapi:ppapi_internal_module
  88       'target_name': 'ppapi_internal_module',
  89       'type': 'static_library',
  90       'include_dirs+': [
  91         '..',
  92       ],
  93       'sources': [
  94         'cpp/private/internal_module.cc',
  95         'cpp/private/internal_module.h',
  96       ]
  97     },
  98   ],
  99 }