ui/base/resource/resource_bundle_mac.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "ui/base/resource/resource_bundle.h"
   6
   7 #import <AppKit/AppKit.h>
   8
   9 #include "base/basictypes.h"
  10 #include "base/file_util.h"
  11 #include "base/files/file_path.h"
  12 #include "base/mac/bundle_locations.h"
  13 #include "base/mac/mac_util.h"
  14 #include "base/mac/scoped_nsobject.h"
  15 #include "base/memory/ref_counted_memory.h"
  16 #include "base/strings/sys_string_conversions.h"
  17 #include "base/synchronization/lock.h"
  18 #include "ui/base/resource/resource_handle.h"
  19 #include "ui/gfx/image/image.h"
  20
  21 namespace ui {
  22
  23 namespace {
  24
  25 base::FilePath GetResourcesPakFilePath(NSString* name, NSString* mac_locale) {
  26   NSString *resource_path;
  27   // Some of the helper processes need to be able to fetch resources
  28   // (chrome_main.cc: SubprocessNeedsResourceBundle()). Fetch the same locale
  29   // as the already-running browser instead of using what NSBundle might pick
  30   // based on values at helper launch time.
  31   if ([mac_locale length]) {
  32     resource_path = [base::mac::FrameworkBundle() pathForResource:name
  33                                                            ofType:@"pak"
  34                                                       inDirectory:@""
  35                                                   forLocalization:mac_locale];
  36   } else {
  37     resource_path = [base::mac::FrameworkBundle() pathForResource:name
  38                                                            ofType:@"pak"];
  39   }
  40
  41   if (!resource_path) {
  42     // Return just the name of the pack file.
  43     return base::FilePath(base::SysNSStringToUTF8(name) + ".pak");
  44   }
  45
  46   return base::FilePath([resource_path fileSystemRepresentation]);
  47 }
  48
  49 }  // namespace
  50
  51 void ResourceBundle::LoadCommonResources() {
  52   AddDataPackFromPath(GetResourcesPakFilePath(@"chrome_100_percent",
  53                         nil), SCALE_FACTOR_100P);
  54   AddDataPackFromPath(GetResourcesPakFilePath(@"content_resources_100_percent",
  55                         nil), SCALE_FACTOR_100P);
  56
  57   // On Mac we load 1x and 2x resources and we let the UI framework decide
  58   // which one to use.
  59   if (IsScaleFactorSupported(SCALE_FACTOR_200P)) {
  60     AddDataPackFromPath(GetResourcesPakFilePath(@"chrome_200_percent", nil),
  61                         SCALE_FACTOR_200P);
  62     AddDataPackFromPath(
  63         GetResourcesPakFilePath(@"content_resources_200_percent", nil),
  64         SCALE_FACTOR_200P);
  65   }
  66 }
  67
  68 base::FilePath ResourceBundle::GetLocaleFilePath(const std::string& app_locale,
  69                                                  bool test_file_exists) {
  70   NSString* mac_locale = base::SysUTF8ToNSString(app_locale);
  71
  72   // Mac OS X uses "_" instead of "-", so swap to get a Mac-style value.
  73   mac_locale = [mac_locale stringByReplacingOccurrencesOfString:@"-"
  74                                                      withString:@"_"];
  75
  76   // On disk, the "en_US" resources are just "en" (http://crbug.com/25578).
  77   if ([mac_locale isEqual:@"en_US"])
  78     mac_locale = @"en";
  79
  80   base::FilePath locale_file_path =
  81       GetResourcesPakFilePath(@"locale", mac_locale);
  82
  83   if (delegate_) {
  84     locale_file_path =
  85         delegate_->GetPathForLocalePack(locale_file_path, app_locale);
  86   }
  87
  88   // Don't try to load empty values or values that are not absolute paths.
  89   if (locale_file_path.empty() || !locale_file_path.IsAbsolute())
  90     return base::FilePath();
  91
  92   if (test_file_exists && !base::PathExists(locale_file_path))
  93     return base::FilePath();
  94
  95   return locale_file_path;
  96 }
  97
  98 gfx::Image& ResourceBundle::GetNativeImageNamed(int resource_id, ImageRTL rtl) {
  99   // Flipped images are not used on Mac.
 100   DCHECK_EQ(rtl, RTL_DISABLED);
 101
 102   // Check to see if the image is already in the cache.
 103   {
 104     base::AutoLock lock(*images_and_fonts_lock_);
 105     if (images_.count(resource_id)) {
 106       if (!images_[resource_id].HasRepresentation(gfx::Image::kImageRepCocoa)) {
 107         DLOG(WARNING) << "ResourceBundle::GetNativeImageNamed() is returning a"
 108           << " cached gfx::Image that isn't backed by an NSImage. The image"
 109           << " will be converted, rather than going through the NSImage loader."
 110           << " resource_id = " << resource_id;
 111       }
 112       return images_[resource_id];
 113     }
 114   }
 115
 116   gfx::Image image;
 117   if (delegate_)
 118     image = delegate_->GetNativeImageNamed(resource_id, rtl);
 119
 120   if (image.IsEmpty()) {
 121     base::scoped_nsobject<NSImage> ns_image;
 122     for (size_t i = 0; i < data_packs_.size(); ++i) {
 123       scoped_refptr<base::RefCountedStaticMemory> data(
 124           data_packs_[i]->GetStaticMemory(resource_id));
 125       if (!data.get())
 126         continue;
 127
 128       base::scoped_nsobject<NSData> ns_data(
 129           [[NSData alloc] initWithBytes:data->front() length:data->size()]);
 130       if (!ns_image.get()) {
 131         ns_image.reset([[NSImage alloc] initWithData:ns_data]);
 132       } else {
 133         NSImageRep* image_rep = [NSBitmapImageRep imageRepWithData:ns_data];
 134         if (image_rep)
 135           [ns_image addRepresentation:image_rep];
 136       }
 137     }
 138
 139     if (!ns_image.get()) {
 140       LOG(WARNING) << "Unable to load image with id " << resource_id;
 141       NOTREACHED();  // Want to assert in debug mode.
 142       return GetEmptyImage();
 143     }
 144
 145     image = gfx::Image(ns_image.release());
 146   }
 147
 148   base::AutoLock lock(*images_and_fonts_lock_);
 149
 150   // Another thread raced the load and has already cached the image.
 151   if (images_.count(resource_id))
 152     return images_[resource_id];
 153
 154   images_[resource_id] = image;
 155   return images_[resource_id];
 156 }
 157
 158 }  // namespace ui