content/test/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/crypto.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/ui.gni")
   9 import("//build/module_args/v8.gni")
  10 import("//testing/test.gni")
  11 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
  12
  13 content_tests_gypi_values =
  14     exec_script("//build/gypi_to_gn.py",
  15                 [
  16                   rebase_path("../content_tests.gypi"),
  17                   "--replace=<(SHARED_INTERMEDIATE_DIR)=$root_gen_dir",
  18                 ],
  19                 "scope",
  20                 [ "../content_tests.gypi" ])
  21
  22 # GYP version //content/content_tests.gypi:test_support_content
  23 source_set("test_support") {
  24   testonly = true
  25   configs += [ "//build/config:precompiled_headers" ]
  26   public_deps = [
  27     "//content/public/app:both",
  28     "//content/public/browser",
  29     "//content/public/common",
  30   ]
  31   deps = [
  32     "//cc/blink",
  33     "//net:test_support",
  34     "//skia",
  35     "//storage/common",
  36     "//testing/gmock",
  37     "//testing/gtest",
  38     "//ui/accessibility:ax_gen",
  39     "//ui/base",
  40     "//ui/base/ime",
  41     "//ui/base:test_support",
  42     "//ui/events:dom_keycode_converter",
  43     "//ui/events:events_base",
  44     "//ui/events:test_support",
  45     "//ui/events:gesture_detection",
  46     "//ui/gfx:test_support",
  47     "//ui/gl",
  48     "//ui/gl:test_support",
  49     "//ui/resources",
  50     "//url",
  51   ]
  52
  53   if (!is_ios) {
  54     sources =
  55         rebase_path(content_tests_gypi_values.test_support_content_sources,
  56                     ".",
  57                     "//content")
  58
  59     public_deps += [ "//third_party/WebKit/public:blink" ]
  60     deps += [
  61       ":content_test_mojo_bindings",
  62       "//components/scheduler:scheduler",
  63       "//components/scheduler:test_support",
  64       "//content/browser/speech/proto",
  65       "//content/public/child",
  66       "//content/gpu",
  67       "//content/public/plugin",
  68       "//content/public/renderer",
  69       "//content/public/utility",
  70       "//content/shell:pak",
  71       "//cc",
  72       "//cc:test_support",
  73       "//ipc/mojo",
  74       "//media",
  75       "//mojo/application/public/cpp:cpp_for_chromium",
  76       "//mojo/environment:chromium",
  77       "//ppapi/host",
  78       "//ppapi/proxy",
  79       "//ppapi/proxy:test_support",
  80       "//ppapi/shared_impl",
  81       "//ppapi/shared_impl:test_support",
  82       "//storage/browser",
  83       "//storage/common",
  84       "//ui/surface",
  85       "//v8",
  86     ]
  87
  88     if (enable_plugins) {
  89       deps += [ "//content/ppapi_plugin" ]
  90     }
  91
  92     if (enable_webrtc) {
  93       sources += [
  94         "../renderer/media/mock_data_channel_impl.cc",
  95         "../renderer/media/mock_data_channel_impl.h",
  96         "../renderer/media/mock_media_stream_dispatcher.cc",
  97         "../renderer/media/mock_media_stream_dispatcher.h",
  98         "../renderer/media/mock_peer_connection_impl.cc",
  99         "../renderer/media/mock_peer_connection_impl.h",
 100         "../renderer/media/mock_web_rtc_peer_connection_handler_client.cc",
 101         "../renderer/media/mock_web_rtc_peer_connection_handler_client.h",
 102         "../renderer/media/webrtc/mock_peer_connection_dependency_factory.cc",
 103         "../renderer/media/webrtc/mock_peer_connection_dependency_factory.h",
 104       ]
 105
 106       deps += [
 107         "//third_party/libjingle:libjingle_webrtc",
 108         "//third_party/libjingle:libpeerconnection",
 109         "//third_party/webrtc/modules/video_capture",
 110       ]
 111     }
 112     if (!enable_plugins) {
 113       sources -= [ "ppapi_unittest.cc" ]
 114     }
 115
 116     if (use_glib) {
 117       configs += [ "//build/config/linux:glib" ]
 118     }
 119
 120     if (use_aura) {
 121       deps += [
 122         "//ui/aura:test_support",
 123         "//ui/resources:ui_test_pak",
 124         "//ui/wm",
 125       ]
 126     }
 127
 128     if (use_aura || is_mac) {
 129       deps += [ "//ui/compositor" ]
 130     }
 131
 132     if (use_ozone) {
 133       deps += [ "//ui/ozone" ]
 134     }
 135
 136     if (is_win) {
 137       deps += [
 138         "//content:startup_helper_win",
 139         "//third_party/iaccessible2",
 140       ]
 141     }
 142
 143     if (!is_android && !is_ios) {
 144       sources += [
 145         "../browser/compositor/test/no_transport_image_transport_factory.cc",
 146         "../browser/compositor/test/no_transport_image_transport_factory.h",
 147       ]
 148       deps += [
 149         "//ui/compositor",
 150         "//third_party/libvpx",
 151       ]
 152     }
 153
 154     if (is_android) {
 155       deps += [
 156         "//content/shell/android:copy_content_shell_assets",
 157         "//ui/android",
 158         "//ui/shell_dialogs",
 159       ]
 160     }
 161
 162     if (is_win) {
 163       deps += [ "//sandbox" ]
 164     }
 165   } else {  # is_ios
 166     sources = [
 167       "public/test/content_test_suite_base.cc",
 168       "public/test/mock_notification_observer.cc",
 169       "public/test/mock_resource_context.cc",
 170       "public/test/test_browser_thread.cc",
 171       "public/test/test_content_client_initializer.cc",
 172       "public/test/test_notification_tracker.cc",
 173       "public/test/test_utils.cc",
 174       "public/test/unittest_test_suite.cc",
 175       "test/content_test_suite.cc",
 176       "test/test_content_browser_client.cc",
 177       "test/test_content_client.cc",
 178     ]
 179   }
 180   if (v8_use_external_startup_data) {
 181     deps += [ "//gin:gin" ]
 182   }
 183 }
 184
 185 source_set("browsertest_support") {
 186   testonly = true
 187
 188   sources = [
 189     "../public/test/content_browser_test.cc",
 190     "../public/test/content_browser_test.h",
 191     "../public/test/content_browser_test_utils.cc",
 192     "../public/test/content_browser_test_utils.h",
 193     "../public/test/content_browser_test_utils_mac.mm",
 194     "content_browser_test_utils_internal.cc",
 195     "content_browser_test_utils_internal.h",
 196     "content_test_launcher.cc",
 197   ]
 198
 199   deps = [
 200     "//content/shell:content_shell_lib",
 201     "//skia",
 202     "//testing/gtest",
 203     "//ui/accessibility:ax_gen",
 204   ]
 205
 206   if (is_android) {
 207     deps += [ "//content/public/app:both" ]
 208   } else {
 209     deps += [ "//content/public/browser" ]
 210   }
 211 }
 212
 213 mojom("content_test_mojo_bindings") {
 214   sources = [
 215     "../public/test/test_mojo_service.mojom",
 216   ]
 217 }
 218
 219 mojom("web_ui_test_mojo_bindings") {
 220   sources = [
 221     "data/web_ui_test_mojo_bindings.mojom",
 222   ]
 223 }
 224
 225 if (!is_ios) {
 226   # GYP version //content/content_tests.gypi:layouttest_support_content
 227   static_library("layouttest_support") {
 228     testonly = true
 229     sources = rebase_path(
 230             content_tests_gypi_values.layouttest_support_content_sources,
 231             ".",
 232             "//content")
 233
 234     deps = [
 235       ":test_support",
 236       "//cc",
 237       "//cc/blink",
 238       "//components/test_runner:test_runner",
 239       "//content/public/common",
 240       "//skia",
 241       "//v8",
 242       "//ui/accessibility:ax_gen",
 243     ]
 244
 245     if (is_android) {
 246       deps += [ ":jni" ]
 247     }
 248   }
 249
 250   if (is_android) {
 251     import("//build/config/android/rules.gni")
 252
 253     generate_jni("jni") {
 254       sources = [
 255         "../public/test/android/javatests/src/org/chromium/content/browser/test/NestedSystemMessageHandler.java",
 256       ]
 257       jni_package = "content/public/test"
 258     }
 259   }
 260 }  # !is_ios
 261
 262 # TODO(GYP) enable content_browsertests on Mac when it links.
 263 if (!is_mac) {
 264   # TODO(GYP): Delete this after we've converted everything to GN.
 265   # The _run targets exist only for compatibility w/ GYP.
 266   group("content_browsertests_run") {
 267     testonly = true
 268     deps = [
 269       ":content_browsertests",
 270     ]
 271   }
 272
 273   test("content_browsertests") {
 274     sources =
 275         rebase_path(content_tests_gypi_values.content_browsertests_sources,
 276                     ".",
 277                     "//content")
 278
 279     if (is_android || is_linux || is_mac || is_win) {
 280       data = [
 281         "data/",
 282         "//net/data/",
 283         "//media/test/data/",
 284       ]
 285
 286       if (is_android) {
 287         data += [ "$root_out_dir/content_shell_assets/content_shell.pak" ]
 288       } else {
 289         data += [
 290           "$root_out_dir/content_shell.pak",
 291           "//net/tools/testserver/",
 292           "//ppapi/tests/test_case.html",
 293           "//ppapi/tests/test_page.css",
 294           "//third_party/pyftpdlib/",
 295           "//third_party/pywebsocket/",
 296           "//third_party/tlslite/",
 297         ]
 298
 299         if (is_mac) {
 300           data += [
 301             "$root_out_dir/Content Shell.app/",
 302             "$root_out_dir/plugins/test_netscape_plugin.plugin/",
 303           ]
 304         }
 305         if (is_win) {
 306           data += [ "$root_out_dir/plugins/np_test_netscape_plugin.dll" ]
 307         }
 308       }
 309     }
 310
 311     defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
 312
 313     configs += [
 314       "//build/config:precompiled_headers",
 315       "//build/config/compiler:no_size_t_to_int_warning",
 316     ]
 317
 318     deps = [
 319       ":browsertest_support",
 320       ":web_ui_test_mojo_bindings",
 321       "//base/allocator",
 322       "//base/test:test_support",
 323       "//content/common:mojo_bindings",
 324       "//content/gpu",
 325       "//content/public/common",
 326       "//content/public/plugin",
 327       "//content/public/renderer",
 328       "//content:resources",
 329       "//content/shell:content_shell_lib",
 330       "//content/shell:pak",
 331       "//content/test:test_support",
 332       "//device/battery",
 333       "//device/battery:mojo_bindings",
 334       "//gin",
 335       "//gpu",
 336       "//ipc:test_support",
 337       "//media:test_support",
 338       "//media/audio:test_support",
 339       "//media/base:test_support",
 340       "//media:shared_memory_support",
 341       "//mojo/application/public/cpp:cpp_for_chromium",
 342       "//mojo/environment:chromium",
 343       "//mojo/test:test_support",
 344       "//net:test_support",
 345       "//ppapi/host",
 346       "//ppapi/proxy",
 347       "//ppapi/proxy:ipc",
 348       "//ppapi/shared_impl",
 349       "//third_party/mojo/src/mojo/edk/system",
 350       "//third_party/mojo/src/mojo/edk/test:test_support",
 351       "//third_party/mojo/src/mojo/public/cpp/bindings",
 352       "//third_party/mojo/src/mojo/public/js",
 353       "//testing/gmock",
 354       "//testing/gtest",
 355       "//third_party/WebKit/public:blink",
 356       "//third_party/leveldatabase",
 357       "//third_party/mesa:osmesa",
 358       "//third_party/zlib",
 359       "//ui/accessibility",
 360       "//ui/accessibility:ax_gen",
 361       "//ui/base",
 362       "//ui/base/ime",
 363       "//ui/gfx",
 364       "//ui/gfx/geometry",
 365       "//ui/gl",
 366       "//ui/gl:test_support",
 367       "//ui/resources",
 368       "//ui/shell_dialogs",
 369       "//ui/snapshot",
 370     ]
 371
 372     data_deps = [
 373       "//ppapi:ppapi_tests",
 374       "//third_party/mesa:osmesa",
 375     ]
 376
 377     if (!is_chromeos) {
 378       sources -=
 379           [ "../browser/web_contents/touch_editable_impl_aura_browsertest.cc" ]
 380     }
 381
 382     if (is_win) {
 383       sources += rebase_path(
 384               content_tests_gypi_values.content_browsertests_win_sources,
 385               ".",
 386               "//content")
 387
 388       deps += [
 389         "//content/app/strings",
 390         "//net:net_resources",
 391         "//third_party/WebKit/public:resources",
 392         "//third_party/iaccessible2",
 393         "//third_party/isimpledom",
 394       ]
 395
 396       libs = [ "oleacc.lib" ]
 397     }
 398
 399     if (is_linux) {
 400       sources -=
 401           [ "../browser/accessibility/dump_accessibility_tree_browsertest.cc" ]
 402     }
 403
 404     if (is_android) {
 405       sources += rebase_path(
 406               content_tests_gypi_values.content_browsertests_android_sources,
 407               ".",
 408               "//content")
 409       sources -=
 410           [ "../browser/battery_status/battery_monitor_impl_browsertest.cc" ]
 411       deps += [
 412         "//content/shell/android:content_shell_jni_headers",
 413         "//content/shell:content_shell_lib",
 414         "//testing/android/native_test:native_test_support",
 415       ]
 416
 417       use_launcher = false
 418     }
 419
 420     if (is_mac) {
 421       sources += [ "../renderer/external_popup_menu_browsertest.cc" ]
 422       deps += [
 423         # Needed for Content Shell.app's Helper.
 424         #"//content/shell:content_shell",  #TODO(GYP) enable for mac
 425       ]
 426     }
 427
 428     if (use_aura && !is_win) {
 429       deps += [ "//ui/events:test_support" ]
 430     }
 431
 432     if (!use_aura && !is_mac) {
 433       sources -=
 434           [ "../browser/compositor/image_transport_factory_browsertest.cc" ]
 435     }
 436
 437     if (enable_webrtc) {
 438       sources += rebase_path(
 439               content_tests_gypi_values.content_browsertests_webrtc_sources,
 440               ".",
 441               "//content")
 442       deps += [ "//testing/perf" ]
 443     }
 444
 445     if (enable_plugins) {
 446       sources += rebase_path(
 447               content_tests_gypi_values.content_browsertests_plugins_sources,
 448               ".",
 449               "//content")
 450       data_deps += [ "//ppapi:ppapi_tests" ]
 451     }
 452
 453     if (enable_web_speech) {
 454       sources += rebase_path(
 455               content_tests_gypi_values.content_browsertests_speech_sources,
 456               ".",
 457               "//content")
 458     }
 459
 460     if (!is_chrome_branded) {
 461       sources += rebase_path(
 462               content_tests_gypi_values.content_browsertests_unofficial_build_sources,
 463               ".",
 464               "//content")
 465     }
 466
 467     if (!use_aura) {
 468       sources -=
 469           [ "../browser/web_contents/web_contents_view_aura_browsertest.cc" ]
 470     }
 471   }
 472 }
 473
 474 # TODO(GYP): Delete this after we've converted everything to GN.
 475 # The _run targets exist only for compatibility w/ GYP.
 476 group("content_unittests_run") {
 477   testonly = true
 478   deps = [
 479     ":content_unittests",
 480   ]
 481 }
 482
 483 test("content_unittests") {
 484   sources = rebase_path(content_tests_gypi_values.content_unittests_sources,
 485                         ".",
 486                         "//content")
 487
 488   if (is_android || is_linux || is_mac || is_win) {
 489     data = [
 490       "data/",
 491       "//net/data/ssl/certificates/",
 492       "//media/test/data/",
 493     ]
 494
 495     if (is_android) {
 496       data += [ "$root_out_dir/content_shell_assets/content_shell.pak" ]
 497     } else {
 498       data += [ "$root_out_dir/content_shell.pak" ]
 499     }
 500   }
 501
 502   configs += [ "//build/config:precompiled_headers" ]
 503
 504   deps = [
 505     ":test_support",
 506     "//base/allocator",
 507     "//base/test:test_support",
 508     "//content/browser/background_sync:background_sync_proto",
 509     "//content/browser/notifications:notification_proto",
 510     "//content/browser/service_worker:service_worker_proto",
 511     "//content/browser/speech/proto",
 512     "//content/common:mojo_bindings",
 513     "//content/public/browser",
 514     "//content/public/common",
 515     "//content/public/common:mojo_bindings",
 516     "//crypto",
 517     "//device/battery",
 518     "//device/battery:mojo_bindings",
 519     "//mojo/environment:chromium",
 520     "//net:extras",
 521     "//net:test_support",
 522     "//skia",
 523     "//sql",
 524     "//sql:test_support",
 525     "//testing/gmock",
 526     "//testing/gtest",
 527     "//third_party/mojo/src/mojo/edk/test:test_support",
 528     "//third_party/mojo/src/mojo/public/cpp/bindings",
 529     "//third_party/re2",
 530     "//ui/accessibility",
 531     "//ui/base",
 532     "//ui/events/blink",
 533     "//ui/gfx",
 534     "//ui/gfx/geometry",
 535     "//ui/gfx/ipc",
 536   ]
 537
 538   if (!is_ios) {
 539     deps += [
 540       "//base/third_party/dynamic_annotations",
 541       "//cc",
 542       "//cc:test_support",
 543       "//cc/surfaces",
 544       "//content:resources",
 545       "//content/gpu",
 546       "//content/public/browser",
 547       "//content/public/child",
 548       "//content/public/plugin",
 549       "//content/public/renderer",
 550       "//gin",
 551       "//gpu",
 552       "//gpu:test_support",
 553       "//ipc:test_support",
 554       "//media:test_support",
 555       "//media:shared_memory_support",
 556       "//media/audio:test_support",
 557       "//media/base:test_support",
 558       "//media/midi:midi",
 559       "//storage/browser",
 560       "//storage/common",
 561       "//third_party/WebKit/public:blink",
 562       "//third_party/icu",
 563       "//third_party/leveldatabase",
 564       "//third_party/libjingle",
 565       "//ui/gl",
 566       "//ui/gl:test_support",
 567     ]
 568   }
 569
 570   data_deps = [ "//third_party/mesa:osmesa" ]
 571
 572   if (!is_win) {
 573     sources += [ "../browser/file_descriptor_info_impl_unittest.cc" ]
 574   }
 575
 576   if (enable_plugins) {
 577     sources +=
 578         rebase_path(content_tests_gypi_values.content_unittests_plugins_sources,
 579                     ".",
 580                     "//content")
 581   }
 582
 583   if (enable_webrtc) {
 584     sources +=
 585         rebase_path(content_tests_gypi_values.content_unittests_webrtc_sources,
 586                     ".",
 587                     "//content")
 588     deps += [
 589       "//third_party/libjingle:libjingle_webrtc",
 590       "//third_party/libjingle:libpeerconnection",
 591       "//third_party/webrtc/modules/video_capture",
 592     ]
 593
 594     if (is_linux || is_mac || is_win) {
 595       sources +=
 596           [ "../browser/media/capture/desktop_capture_device_unittest.cc" ]
 597       deps += [ "//third_party/webrtc/modules/desktop_capture" ]
 598     }
 599
 600     if (is_chromeos) {
 601       sources +=
 602           [ "../browser/media/capture/desktop_capture_device_aura_unittest.cc" ]
 603     }
 604   } else {
 605     if (enable_plugins) {
 606       # This file is added only when plugins are enabled, but we don't want it
 607       # unless webrtc is also enabled.
 608       sources -=
 609           [ "../renderer/media/webrtc/video_destination_handler_unittest.cc" ]
 610     }
 611   }
 612
 613   if (enable_web_speech) {
 614     sources +=
 615         rebase_path(content_tests_gypi_values.content_unittests_speech_sources,
 616                     ".",
 617                     "//content")
 618   }
 619
 620   if (is_linux) {
 621     if (use_dbus) {
 622       deps += [ "//dbus:test_support" ]
 623     } else {
 624       sources -=
 625           [ "../browser/geolocation/wifi_data_provider_linux_unittest.cc" ]
 626     }
 627   }
 628   if (is_win) {
 629     deps += [ "//third_party/iaccessible2" ]
 630   }
 631   if (is_mac) {
 632     # These flags are needed to run the test on Mac.
 633     # Search for comments about "xcode_settings" in chrome_tests.gypi.
 634     ldflags = [ "-Wl,-ObjC" ]
 635
 636     deps += [ "//third_party/ocmock" ]
 637   }
 638   if (is_chromeos) {
 639     sources -= [ "../browser/geolocation/wifi_data_provider_linux_unittest.cc" ]
 640     deps += [ "//chromeos" ]
 641   }
 642   if (is_android) {
 643     sources +=
 644         rebase_path(content_tests_gypi_values.content_unittests_android_sources,
 645                     ".",
 646                     "//content")
 647     sources -= [
 648       "../browser/geolocation/network_location_provider_unittest.cc",
 649       "../browser/geolocation/wifi_data_provider_common_unittest.cc",
 650       "../browser/renderer_host/begin_frame_observer_proxy_unittest.cc",
 651       "../browser/webui/url_data_manager_backend_unittest.cc",
 652     ]
 653     deps += [ "//testing/android/native_test:native_test_native_code" ]
 654   }
 655   if (!is_android && !is_ios) {
 656     deps += [ "//third_party/libvpx" ]
 657   }
 658
 659   if (use_aura) {
 660     deps += [
 661       "//ui/aura",
 662       "//ui/aura_extra",
 663       "//ui/wm",
 664     ]
 665   } else {
 666     sources -= [
 667       "../browser/renderer_host/render_widget_host_view_aura_unittest.cc",
 668       "../browser/renderer_host/web_input_event_aura_unittest.cc",
 669       "../browser/web_contents/aura/overscroll_navigation_overlay_unittest.cc",
 670       "../browser/web_contents/aura/overscroll_window_animation_unittest.cc",
 671       "../browser/web_contents/aura/overscroll_window_delegate_unittest.cc",
 672       "../browser/web_contents/web_contents_view_aura_unittest.cc",
 673     ]
 674   }
 675   if (use_aura || toolkit_views) {
 676     deps += [ "//ui/events:test_support" ]
 677   }
 678   if (!use_aura && !is_mac) {
 679     sources -= [
 680       "../browser/compositor/buffer_queue_unittest.cc",
 681       "../browser/compositor/reflector_impl_unittest.cc",
 682       "../browser/compositor/software_browser_compositor_output_surface_unittest.cc",
 683     ]
 684   }
 685
 686   if (!is_win && !is_mac) {
 687     sources -= [ "../common/plugin_list_unittest.cc" ]
 688   }
 689
 690   if (use_ozone) {
 691     deps += [
 692       "//ui/ozone",
 693       "//ui/ozone:ozone_base",
 694     ]
 695   } else {
 696     sources -=
 697         [ "../browser/compositor/software_output_device_ozone_unittest.cc" ]
 698   }
 699
 700   if (is_mac && use_openssl) {
 701     deps += [ "//third_party/boringssl" ]
 702   }
 703 }
 704
 705 if (!is_mac) {  # TODO(GYP) enable on Mac once it links.
 706   test("content_perftests") {
 707     sources = [
 708       "../browser/renderer_host/input/input_router_impl_perftest.cc",
 709       "../common/cc_messages_perftest.cc",
 710       "../test/run_all_perftests.cc",
 711     ]
 712     deps = [
 713       "//base/allocator",
 714       "//base/test:test_support",
 715       "//content/public/browser",
 716       "//content/public/common",
 717       "//content/test:test_support",
 718       "//cc",
 719       "//skia",
 720       "//testing/gtest",
 721       "//testing/perf",
 722       "//ui/gfx",
 723       "//ui/gfx/geometry",
 724     ]
 725
 726     if (is_android) {
 727       deps += [ "//testing/android/native_test:native_test_native_code" ]
 728     }
 729   }
 730
 731   test("content_gl_tests") {
 732     sources = [
 733       "../common/gpu/client/gl_helper_unittest.cc",
 734       "../common/gpu/client/gpu_in_process_context_tests.cc",
 735     ]
 736
 737     deps = [
 738       ":test_support",
 739       "//base/allocator",
 740       "//base/test:test_support",
 741       "//content/public/common",
 742       "//gpu/blink",
 743       "//gpu/command_buffer/common",
 744       "//testing/gtest",
 745       "//third_party/WebKit/public:blink",
 746       "//ui/base",
 747       "//ui/gfx",
 748       "//ui/gfx:test_support",
 749       "//ui/gfx/geometry",
 750       "//ui/gl",
 751       "//ui/gl:test_support",
 752       "//v8",
 753     ]
 754
 755     if (is_android) {
 756       deps += [ "//testing/android/native_test:native_test_native_code" ]
 757     } else {
 758       data_deps = [
 759         "//third_party/ffmpeg",
 760         "//third_party/mesa:osmesa",
 761       ]
 762     }
 763   }
 764
 765   test("content_gl_benchmark") {
 766     sources = [
 767       "../common/gpu/client/gl_helper_benchmark.cc",
 768     ]
 769
 770     deps = [
 771       ":test_support",
 772       "//base/allocator",
 773       "//base/test:test_support",
 774       "//content/public/common",
 775       "//gpu/blink",
 776       "//testing/gtest",
 777       "//third_party/WebKit/public:blink",
 778       "//ui/base",
 779       "//ui/gfx",
 780       "//ui/gfx/geometry",
 781       "//ui/gl",
 782       "//ui/gl:test_support",
 783     ]
 784   }
 785 }