skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
  12   import("//build/config/mips.gni")
  13 }
  14
  15 skia_support_gpu = !is_ios
  16 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  17
  18 # The list of Skia defines that are to be set for blink.
  19 gypi_blink_skia_defines =
  20     exec_script("//build/gypi_to_gn.py",
  21                 [
  22                   rebase_path(
  23                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  24                   "--replace=<(skia_include_path)=//third_party/skia/include",
  25                   "--replace=<(skia_src_path)=//third_party/skia/src",
  26                 ],
  27                 "scope",
  28                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  29
  30 # The list of Skia defines that are to be set for chromium.
  31 gypi_skia_defines =
  32     exec_script("//build/gypi_to_gn.py",
  33                 [
  34                   rebase_path(
  35                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  36                   "--replace=<(skia_include_path)=//third_party/skia/include",
  37                   "--replace=<(skia_src_path)=//third_party/skia/src",
  38                 ],
  39                 "scope",
  40                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  41
  42 # The list of Skia core sources that are to be set for chromium.
  43 gypi_skia_core =
  44     exec_script("//build/gypi_to_gn.py",
  45                 [
  46                   rebase_path("//third_party/skia/gyp/core.gypi"),
  47                   "--replace=<(skia_include_path)=//third_party/skia/include",
  48                   "--replace=<(skia_src_path)=//third_party/skia/src",
  49                 ],
  50                 "scope",
  51                 [ "//third_party/skia/gyp/core.gypi" ])
  52
  53 # The list of Skia gpu sources that are to be set for chromium.
  54 if (skia_support_gpu) {
  55   gypi_skia_gpu =
  56       exec_script("//build/gypi_to_gn.py",
  57                   [
  58                     rebase_path("//third_party/skia/gyp/gpu.gypi"),
  59                     "--replace=<(skia_include_path)=//third_party/skia/include",
  60                     "--replace=<(skia_src_path)=//third_party/skia/src",
  61                   ],
  62                   "scope",
  63                   [ "//third_party/skia/gyp/gpu.gypi" ])
  64 }
  65
  66 # The list of Skia pdf sources that are to be set for chromium.
  67 if (skia_support_pdf) {
  68   gypi_skia_pdf =
  69       exec_script("//build/gypi_to_gn.py",
  70                   [
  71                     rebase_path("//third_party/skia/gyp/pdf.gypi"),
  72                     "--replace=<(skia_include_path)=//third_party/skia/include",
  73                     "--replace=<(skia_src_path)=//third_party/skia/src",
  74                   ],
  75                   "scope",
  76                   [ "//third_party/skia/gyp/pdf.gypi" ])
  77 }
  78
  79 # The list of Skia effects that are to be set for chromium.
  80 gypi_skia_effects =
  81     exec_script("//build/gypi_to_gn.py",
  82                 [
  83                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  84                   "--replace=<(skia_include_path)=//third_party/skia/include",
  85                   "--replace=<(skia_src_path)=//third_party/skia/src",
  86                 ],
  87                 "scope",
  88                 [ "//third_party/skia/gyp/effects.gypi" ])
  89
  90 # The list of Skia utils that are to be set for chromium.
  91 gypi_skia_utils =
  92     exec_script("//build/gypi_to_gn.py",
  93                 [
  94                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  95                   "--replace=<(skia_include_path)=//third_party/skia/include",
  96                   "--replace=<(skia_src_path)=//third_party/skia/src",
  97                 ],
  98                 "scope",
  99                 [ "//third_party/skia/gyp/utils.gypi" ])
 100
 101 gypi_skia_opts =
 102     exec_script("//build/gypi_to_gn.py",
 103                 [
 104                   rebase_path("//third_party/skia/gyp/opts.gypi"),
 105                   "--replace=<(skia_include_path)=//third_party/skia/include",
 106                   "--replace=<(skia_src_path)=//third_party/skia/src",
 107                 ],
 108                 "scope",
 109                 [ "//third_party/skia/gyp/opts.gypi" ])
 110
 111 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 112 gypi_values =
 113     exec_script("//build/gypi_to_gn.py",
 114                 [
 115                   rebase_path("skia_gn_files.gypi"),
 116                   "--replace=<(skia_include_path)=//third_party/skia/include",
 117                   "--replace=<(skia_src_path)=//third_party/skia/src",
 118                 ],
 119                 "scope",
 120                 [ "skia_gn_files.gypi" ])
 121
 122 # External-facing config for dependent code.
 123 config("skia_config") {
 124   include_dirs = [
 125     "config",
 126     "ext",
 127     "//third_party/skia/include/c",
 128     "//third_party/skia/include/config",
 129     "//third_party/skia/include/core",
 130     "//third_party/skia/include/effects",
 131     "//third_party/skia/include/images",
 132     "//third_party/skia/include/lazy",
 133     "//third_party/skia/include/pathops",
 134     "//third_party/skia/include/pdf",
 135     "//third_party/skia/include/pipe",
 136     "//third_party/skia/include/ports",
 137     "//third_party/skia/include/utils",
 138   ]
 139
 140   defines = gypi_blink_skia_defines.blink_skia_defines
 141   defines += gypi_skia_defines.skia_for_chromium_defines
 142
 143   defines += []
 144
 145   if (component_mode == "shared_library") {
 146     defines += [
 147       "SKIA_DLL",
 148       "GR_GL_IGNORE_ES3_MSAA=0",
 149     ]
 150   }
 151
 152   if (skia_support_gpu) {
 153     include_dirs += [
 154       "//third_party/skia/include/gpu",
 155       "//third_party/skia/src/gpu",
 156     ]
 157     defines += [ "SK_SUPPORT_GPU=1" ]
 158   } else {
 159     defines += [ "SK_SUPPORT_GPU=0" ]
 160   }
 161
 162   if (is_android) {
 163     defines += [
 164       "SK_BUILD_FOR_ANDROID",
 165       "USE_CHROMIUM_SKIA",
 166     ]
 167   }
 168
 169   if (is_mac) {
 170     defines += [ "SK_BUILD_FOR_MAC" ]
 171   }
 172 }
 173
 174 # Internal-facing config for Skia library code.
 175 config("skia_library_config") {
 176   # These include directories are only included for Skia code and are not
 177   # exported to dependents. It's not clear if this is on purpose, but this
 178   # matches the GYP build.
 179   include_dirs = [
 180     "//third_party/skia/src/core",
 181     "//third_party/skia/src/image",
 182     "//third_party/skia/src/opts",
 183     "//third_party/skia/src/pdf",
 184     "//third_party/skia/src/ports",
 185     "//third_party/skia/src/sfnt",
 186     "//third_party/skia/src/utils",
 187     "//third_party/skia/src/lazy",
 188   ]
 189   if (is_mac || is_ios) {
 190     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 191   }
 192   if (is_mac) {
 193     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 194   }
 195
 196   defines = []
 197
 198   if (component_mode == "shared_library") {
 199     defines += [ "SKIA_IMPLEMENTATION=1" ]
 200   }
 201
 202   if (current_cpu == "arm") {
 203     if (arm_use_neon) {
 204       defines += [ "SK_ARM_HAS_NEON" ]
 205     }
 206     if (arm_optionally_use_neon) {
 207       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 208     }
 209   }
 210
 211   # Settings for text blitting, chosen to approximate the system browser.
 212   if (is_linux) {
 213     defines += [
 214       "SK_GAMMA_EXPONENT=1.2",
 215       "SK_GAMMA_CONTRAST=0.2",
 216       "SK_HIGH_QUALITY_IS_LANCZOS",
 217     ]
 218   } else if (is_android) {
 219     defines += [
 220       "SK_GAMMA_APPLY_TO_A8",
 221       "SK_GAMMA_EXPONENT=1.4",
 222       "SK_GAMMA_CONTRAST=0.0",
 223     ]
 224   } else if (is_win) {
 225     defines += [
 226       "SK_GAMMA_SRGB",
 227       "SK_GAMMA_CONTRAST=0.5",
 228       "SK_HIGH_QUALITY_IS_LANCZOS",
 229     ]
 230   } else if (is_mac) {
 231     defines += [
 232       "SK_GAMMA_SRGB",
 233       "SK_GAMMA_CONTRAST=0.0",
 234       "SK_HIGH_QUALITY_IS_LANCZOS",
 235     ]
 236   }
 237
 238   if (is_android) {
 239     defines += [
 240       # Android devices are typically more memory constrained, so default to a
 241       # smaller glyph cache (it may be overriden at runtime when the renderer
 242       # starts up, depending on the actual device memory).
 243       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 244     ]
 245   } else {
 246     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 247   }
 248
 249   if (is_win) {
 250     include_dirs += [
 251       "//third_party/skia/include/utils/win",
 252       "//third_party/skia/src/utils/win",
 253     ]
 254
 255     defines += [
 256       # On windows, GDI handles are a scarse system-wide resource so we have to
 257       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 258       # fairly small size. http://crbug.com/314387
 259       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 260     ]
 261
 262     cflags = [
 263       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 264       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 265       "/wd4341",  # signed value is out of range for enum constant.
 266       "/wd4345",  # Object is default-initialized if initialization is omitted.
 267       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 268       "/wd4554",  # 'operator' : check operator precedence for possible error
 269       "/wd4748",  # compiler will disable optimizations if a function has inline
 270                   # assembly code contains flow control(jmp or jcc) statements.
 271
 272       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 273     ]
 274   }
 275 }
 276
 277 component("skia") {
 278   sources = [
 279     # Chrome sources.
 280     "config/SkUserConfig.h",
 281     "ext/SkDiscardableMemory_chrome.cc",
 282     "ext/SkDiscardableMemory_chrome.h",
 283     "ext/SkMemory_new_handler.cpp",
 284     "ext/analysis_canvas.cc",
 285     "ext/analysis_canvas.h",
 286     "ext/benchmarking_canvas.cc",
 287     "ext/benchmarking_canvas.h",
 288     "ext/bitmap_platform_device.h",
 289     "ext/convolver.cc",
 290     "ext/convolver.h",
 291     "ext/event_tracer_impl.cc",
 292     "ext/event_tracer_impl.h",
 293     "ext/fontmgr_default_win.cc",
 294     "ext/fontmgr_default_win.h",
 295     "ext/google_logging.cc",
 296     "ext/image_operations.cc",
 297     "ext/image_operations.h",
 298     "ext/opacity_draw_filter.cc",
 299     "ext/opacity_draw_filter.h",
 300     "ext/pixel_ref_utils.cc",
 301     "ext/pixel_ref_utils.h",
 302     "ext/platform_canvas.cc",
 303     "ext/platform_canvas.h",
 304     "ext/platform_device.cc",
 305     "ext/platform_device.h",
 306     "ext/platform_device_linux.cc",
 307     "ext/platform_device_mac.cc",
 308     "ext/platform_device_win.cc",
 309     "ext/recursive_gaussian_convolution.cc",
 310     "ext/recursive_gaussian_convolution.h",
 311     "ext/refptr.h",
 312     "ext/skia_utils_base.cc",
 313     "ext/skia_utils_base.h",
 314     "ext/skia_utils_ios.h",
 315     "ext/skia_utils_ios.mm",
 316     "ext/skia_utils_mac.h",
 317     "ext/skia_utils_mac.mm",
 318     "ext/skia_utils_win.cc",
 319     "ext/skia_utils_win.h",
 320   ]
 321
 322   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 323   sources += gypi_skia_core.sources
 324   sources += gypi_skia_effects.sources
 325   sources += gypi_skia_utils.sources
 326   sources += gypi_values.skia_library_sources
 327
 328   # This and skia_opts are really the same conceptual target so share headers.
 329   allow_circular_includes_from = [ ":skia_opts" ]
 330
 331   if (current_cpu == "arm") {
 332     sources += [
 333       "//third_party/skia/src/core/SkUtilsArm.cpp",
 334       "//third_party/skia/src/core/SkUtilsArm.h",
 335     ]
 336   }
 337
 338   # GPU
 339   if (skia_support_gpu) {
 340     sources += gypi_skia_gpu.skgpu_sources
 341     sources += gypi_skia_gpu.skgpu_null_gl_sources
 342   }
 343
 344   # Remove unused util files include in utils.gypi
 345   sources -= [
 346     "//third_party/skia/include/utils/SkBoundaryPatch.h",
 347     "//third_party/skia/include/utils/SkCamera.h",
 348     "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 349     "//third_party/skia/include/utils/SkCubicInterval.h",
 350     "//third_party/skia/include/utils/SkCullPoints.h",
 351     "//third_party/skia/include/utils/SkDebugUtils.h",
 352     "//third_party/skia/include/utils/SkDumpCanvas.h",
 353     "//third_party/skia/include/utils/SkEventTracer.h",
 354     "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 355     "//third_party/skia/include/utils/SkInterpolator.h",
 356     "//third_party/skia/include/utils/SkLayer.h",
 357     "//third_party/skia/include/utils/SkMeshUtils.h",
 358     "//third_party/skia/include/utils/SkNinePatch.h",
 359     "//third_party/skia/include/utils/SkParsePaint.h",
 360     "//third_party/skia/include/utils/SkParsePath.h",
 361     "//third_party/skia/include/utils/SkRandom.h",
 362     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 363     "//third_party/skia/src/utils/SkBitmapHasher.h",
 364     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 365     "//third_party/skia/src/utils/SkCamera.cpp",
 366     "//third_party/skia/src/utils/SkCanvasStack.h",
 367     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 368     "//third_party/skia/src/utils/SkCullPoints.cpp",
 369     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 370     "//third_party/skia/src/utils/SkFloatUtils.h",
 371     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 372     "//third_party/skia/src/utils/SkInterpolator.cpp",
 373     "//third_party/skia/src/utils/SkLayer.cpp",
 374     "//third_party/skia/src/utils/SkMD5.cpp",
 375     "//third_party/skia/src/utils/SkMD5.h",
 376     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 377     "//third_party/skia/src/utils/SkNinePatch.cpp",
 378     "//third_party/skia/src/utils/SkOSFile.cpp",
 379     "//third_party/skia/src/utils/SkParsePath.cpp",
 380     "//third_party/skia/src/utils/SkSHA1.cpp",
 381     "//third_party/skia/src/utils/SkSHA1.h",
 382     "//third_party/skia/src/utils/SkTFitsIn.h",
 383     "//third_party/skia/src/utils/SkTLogic.h",
 384
 385     # We don't currently need to change thread affinity, so leave out this complexity for now.
 386     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 387     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 388
 389     #testing
 390     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 391     "//third_party/skia/src/fonts/SkGScalerContext.h",
 392   ]
 393
 394   if (is_win) {
 395     sources -= [
 396       # Keeping _win.cpp
 397       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 398       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 399     ]
 400   } else {
 401     sources -= [
 402       # Keeping _pthread.cpp and _pthread_other.cpp.
 403       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 404     ]
 405   }
 406
 407   # need separate win section to handle chromes auto gn filter
 408   # (build/config/BUILDCONFIG.gn)
 409   if (is_win) {
 410     sources -= [
 411       #windows
 412       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 413       "//third_party/skia/include/utils/win/SkHRESULT.h",
 414       "//third_party/skia/include/utils/win/SkIStream.h",
 415       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 416       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 417       "//third_party/skia/src/utils/win/SkIStream.cpp",
 418       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 419     ]
 420   }
 421
 422   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 423     sources -= [ "ext/skia_utils_base.cc" ]
 424   }
 425
 426   # Fixup skia library sources.
 427   if (is_win) {
 428     sources -= [
 429       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 430       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 431       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 432     ]
 433   } else {
 434     sources -= [
 435       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 436       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 437       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 438       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 439       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 440       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 441       "//third_party/skia/src/ports/SkTLS_win.cpp",
 442       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 443       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 444     ]
 445   }
 446   if (!is_android) {
 447     sources -= [
 448       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 449       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 450     ]
 451   }
 452   if (!is_mac) {
 453     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 454   }
 455
 456   if (!is_linux) {
 457     sources -= [
 458       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 459       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 460       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 461     ]
 462   }
 463
 464   if (!is_linux && !is_android) {
 465     sources -= [
 466       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 467       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 468     ]
 469   }
 470
 471   # Select the right BitmapPlatformDevice.
 472   if (is_win) {
 473     sources += [
 474       "ext/bitmap_platform_device_win.cc",
 475       "ext/bitmap_platform_device_win.h",
 476     ]
 477   } else if (is_mac) {
 478     sources += [
 479       "ext/bitmap_platform_device_mac.cc",
 480       "ext/bitmap_platform_device_mac.h",
 481     ]
 482   } else if (use_cairo) {
 483     sources += [
 484       "ext/bitmap_platform_device_cairo.cc",
 485       "ext/bitmap_platform_device_cairo.h",
 486     ]
 487   } else {
 488     sources += [
 489       "ext/bitmap_platform_device_skia.cc",
 490       "ext/bitmap_platform_device_skia.h",
 491     ]
 492   }
 493
 494   if (is_clang) {
 495     # Skia won't compile with some of the more strict clang warnings.
 496     # e.g. it does:
 497     #  SkASSERT(!"sk_out_of_memory");
 498     configs -= [ "//build/config/clang:extra_warnings" ]
 499   }
 500
 501   configs -= [ "//build/config/compiler:chromium_code" ]
 502   configs += [
 503     ":skia_library_config",
 504     "//build/config/compiler:no_chromium_code",
 505   ]
 506   public_configs = [ ":skia_config" ]
 507
 508   deps = [
 509     ":skia_opts",
 510     "//base",
 511     "//base/third_party/dynamic_annotations",
 512     "//third_party/zlib",
 513   ]
 514
 515   if (is_linux) {
 516     configs += [
 517       "//build/config/linux:fontconfig",
 518       "//build/config/linux:freetype2",
 519     ]
 520     if (use_pango) {
 521       configs += [ "//build/config/linux:pangocairo" ]
 522     }
 523     deps += [ "//third_party/icu:icuuc" ]
 524   }
 525
 526   if (is_android) {
 527     set_sources_assignment_filter([])
 528     sources += [ "ext/platform_device_linux.cc" ]
 529     set_sources_assignment_filter(sources_assignment_filter)
 530     deps += [
 531       "//third_party/expat",
 532       "//third_party/freetype",
 533       "//third_party/android_tools:cpu_features",
 534     ]
 535   }
 536
 537   if (skia_support_pdf) {
 538     deps += [ "//third_party/sfntly" ]
 539     sources += gypi_skia_pdf.sources
 540   }
 541
 542   if (is_android && !is_debug) {
 543     configs -= [ "//build/config/compiler:optimize" ]
 544     configs += [ "//build/config/compiler:optimize_max" ]
 545   }
 546 }
 547
 548 # Separated out so it can be compiled with different flags for SSE.
 549 source_set("skia_opts") {
 550   cflags = []
 551   defines = []
 552
 553   if (current_cpu == "x86" || current_cpu == "x64") {
 554     sources = gypi_skia_opts.sse2_sources + gypi_skia_opts.ssse3_sources +
 555               gypi_skia_opts.sse41_sources +
 556               [
 557                 # Chrome-specific.
 558                 "ext/convolver_SSE2.cc",
 559                 "ext/convolver_SSE2.h",
 560               ]
 561
 562     if (is_linux || is_mac) {
 563       cflags += [ "-msse4.1" ]
 564     } else if (is_win) {
 565       defines += [ "SK_CPU_SSE_LEVEL=41" ]
 566     }
 567   } else if (current_cpu == "arm") {
 568     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 569     # ARM), the compiler doesn't like that.
 570     cflags += [ "-fomit-frame-pointer" ]
 571
 572     if (arm_version >= 7) {
 573       sources = gypi_skia_opts.armv7_sources
 574       if (arm_use_neon || arm_optionally_use_neon) {
 575         sources += gypi_skia_opts.neon_sources
 576
 577         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 578         # when running this.
 579         if (!arm_use_neon) {
 580           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 581           cflags += [ "-mfpu=neon" ]
 582         }
 583       }
 584     } else {
 585       sources = gypi_skia_opts.none_sourcees
 586     }
 587   } else if (current_cpu == "mipsel") {
 588     cflags += [ "-fomit-frame-pointer" ]
 589
 590     if (mips_dsp_rev >= 1) {
 591       sources = gypi_skia_opts.mips_dsp_sources
 592       if (mips_dsp_rev >= 2) {
 593         sources += [
 594           # Chrome-specific.
 595           "ext/convolver_mips_dspr2.cc",
 596           "ext/convolver_mips_dspr2.h",
 597         ]
 598       }
 599     } else {
 600       sources = gypi_skia_opts.none_sources
 601     }
 602   } else {
 603     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 604   }
 605
 606   if (is_android && !is_debug) {
 607     configs -= [ "//build/config/compiler:optimize" ]
 608     configs += [ "//build/config/compiler:optimize_max" ]
 609   }
 610
 611   configs -= [ "//build/config/compiler:chromium_code" ]
 612   configs += [
 613     ":skia_config",
 614     ":skia_library_config",
 615     "//build/config/compiler:no_chromium_code",
 616   ]
 617
 618   deps = [
 619     "//base",
 620   ]
 621
 622   visibility = [ ":skia" ]
 623 }
 624
 625 test("skia_unittests") {
 626   sources = [
 627     "ext/analysis_canvas_unittest.cc",
 628     "ext/bitmap_platform_device_mac_unittest.cc",
 629     "ext/convolver_unittest.cc",
 630     "ext/image_operations_unittest.cc",
 631     "ext/pixel_ref_utils_unittest.cc",
 632     "ext/platform_canvas_unittest.cc",
 633     "ext/recursive_gaussian_convolution_unittest.cc",
 634     "ext/refptr_unittest.cc",
 635     "ext/skia_utils_ios_unittest.mm",
 636     "ext/skia_utils_mac_unittest.mm",
 637   ]
 638
 639   if (!is_win && !is_mac) {
 640     sources -= [ "ext/platform_canvas_unittest.cc" ]
 641   }
 642
 643   deps = [
 644     ":skia",
 645     "//base",
 646     "//base/test:run_all_unittests",
 647     "//cc:test_support",  # TODO: Fix this test to not depend on cc.
 648     "//testing/gtest",
 649     "//ui/gfx",
 650     "//ui/gfx/geometry",
 651   ]
 652 }
 653
 654 if (is_linux && !is_chromeos) {
 655   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 656   executable("image_operations_bench") {
 657     sources = [
 658       "ext/image_operations_bench.cc",
 659     ]
 660
 661     deps = [
 662       ":skia",
 663       "//base",
 664     ]
 665   }
 666
 667   executable("filter_fuzz_stub") {
 668     sources = [
 669       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 670     ]
 671
 672     deps = [
 673       ":skia",
 674       "//base",
 675     ]
 676   }
 677 }