gin/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/module_args/v8.gni")
   6 import("//testing/test.gni")
   7
   8 component("gin") {
   9   sources = [
  10     "arguments.cc",
  11     "arguments.h",
  12     "array_buffer.cc",
  13     "array_buffer.h",
  14     "context_holder.cc",
  15     "converter.cc",
  16     "converter.h",
  17     "debug_impl.cc",
  18     "debug_impl.h",
  19     "dictionary.cc",
  20     "dictionary.h",
  21     "function_template.cc",
  22     "function_template.h",
  23     "gin_export.h",
  24     "handle.h",
  25     "interceptor.cc",
  26     "interceptor.h",
  27     "isolate_holder.cc",
  28     "modules/console.cc",
  29     "modules/console.h",
  30     "modules/file_module_provider.cc",
  31     "modules/file_module_provider.h",
  32     "modules/module_registry.cc",
  33     "modules/module_registry.h",
  34     "modules/module_registry_observer.h",
  35     "modules/module_runner_delegate.cc",
  36     "modules/module_runner_delegate.h",
  37     "modules/timer.cc",
  38     "modules/timer.h",
  39     "object_template_builder.cc",
  40     "object_template_builder.h",
  41     "per_context_data.cc",
  42     "per_context_data.h",
  43     "per_isolate_data.cc",
  44     "per_isolate_data.h",
  45     "public/context_holder.h",
  46     "public/debug.h",
  47     "public/gin_embedders.h",
  48     "public/isolate_holder.h",
  49     "public/v8_idle_task_runner.h",
  50     "public/v8_platform.h",
  51     "public/wrapper_info.h",
  52     "run_microtasks_observer.cc",
  53     "run_microtasks_observer.h",
  54     "runner.cc",
  55     "runner.h",
  56     "shell_runner.cc",
  57     "shell_runner.h",
  58     "try_catch.cc",
  59     "try_catch.h",
  60     "v8_initializer.cc",
  61     "v8_initializer.h",
  62     "v8_isolate_memory_dump_provider.cc",
  63     "v8_isolate_memory_dump_provider.h",
  64     "v8_platform.cc",
  65     "wrappable.cc",
  66     "wrappable.h",
  67     "wrapper_info.cc",
  68   ]
  69
  70   defines = [ "GIN_IMPLEMENTATION" ]
  71
  72   public_deps = [
  73     "//base",
  74     "//v8",
  75   ]
  76   deps = [
  77     "//base/third_party/dynamic_annotations",
  78   ]
  79   if (v8_use_external_startup_data && is_win) {
  80     public_deps += [ ":gin_v8_snapshot_fingerprint" ]
  81     deps += [ "//crypto:crypto" ]
  82     sources += [ "$target_gen_dir/v8_snapshot_fingerprint.cc" ]
  83     defines += [ "V8_VERIFY_EXTERNAL_STARTUP_DATA" ]
  84   }
  85 }
  86
  87 if (v8_use_external_startup_data) {
  88   action("gin_v8_snapshot_fingerprint") {
  89     script = "//gin/fingerprint/fingerprint_v8_snapshot.py"
  90
  91     snapshot_file = "$root_build_dir/snapshot_blob.bin"
  92     natives_file = "$root_build_dir/natives_blob.bin"
  93     output_file = "$target_gen_dir/v8_snapshot_fingerprint.cc"
  94
  95     args = [
  96       "--snapshot_file",
  97       rebase_path(snapshot_file, root_build_dir),
  98       "--natives_file",
  99       rebase_path(natives_file, root_build_dir),
 100       "--output_file",
 101       rebase_path(output_file, root_build_dir),
 102     ]
 103     inputs = [
 104       snapshot_file,
 105       natives_file,
 106     ]
 107     outputs = [
 108       output_file,
 109     ]
 110
 111     deps = [
 112       "//v8",
 113     ]
 114   }
 115 }
 116
 117 executable("gin_shell") {
 118   sources = [
 119     "shell/gin_main.cc",
 120   ]
 121
 122   deps = [
 123     ":gin",
 124     "//base",
 125     "//base:i18n",
 126     "//v8",
 127   ]
 128 }
 129
 130 source_set("gin_test") {
 131   testonly = true
 132   sources = [
 133     "test/file.cc",
 134     "test/file.h",
 135     "test/file_runner.cc",
 136     "test/file_runner.h",
 137     "test/gc.cc",
 138     "test/gc.h",
 139     "test/gtest.cc",
 140     "test/gtest.h",
 141     "test/v8_test.cc",
 142     "test/v8_test.h",
 143   ]
 144
 145   public_deps = [
 146     ":gin",
 147     "//testing/gtest",
 148   ]
 149   deps = [
 150     "//v8",
 151   ]
 152 }
 153
 154 test("gin_unittests") {
 155   sources = [
 156     "converter_unittest.cc",
 157     "interceptor_unittest.cc",
 158     "modules/module_registry_unittest.cc",
 159     "modules/timer_unittest.cc",
 160     "per_context_data_unittest.cc",
 161     "shell/gin_shell_unittest.cc",
 162     "shell_runner_unittest.cc",
 163     "test/run_all_unittests.cc",
 164     "test/run_js_tests.cc",
 165     "v8_isolate_memory_dump_provider_unittest.cc",
 166     "wrappable_unittest.cc",
 167   ]
 168
 169   deps = [
 170     ":gin_test",
 171     "//base/test:test_support",
 172     "//v8",
 173   ]
 174 }