content/public/common/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//content/common/common.gni")
   7 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
   8
   9 # See //content/BUILD.gn for how this works.
  10 group("common") {
  11   if (is_component_build) {
  12     public_deps = [
  13       "//content",
  14     ]
  15   } else {
  16     public_deps = [
  17       ":common_sources",
  18     ]
  19   }
  20 }
  21
  22 # This target allows other targets to depend on result_codes.h which is a
  23 # header-only dependency, without bringing in all of content.
  24 source_set("result_codes") {
  25   sources = [
  26     "result_codes.h",
  27   ]
  28 }
  29
  30 source_set("common_sources") {
  31   visibility = [ "//content/*" ]
  32
  33   sources = rebase_path(content_common_gypi_values.public_common_sources,
  34                         ".",
  35                         "//content")
  36
  37   configs += [
  38     "//build/config:precompiled_headers",
  39     "//content:content_implementation",
  40   ]
  41
  42   public_deps = [
  43     "//content/common",
  44     "//third_party/mojo/src/mojo/public/cpp/bindings",
  45   ]
  46   deps = [
  47     "//net",
  48     "//skia",
  49     "//third_party/WebKit/public:blink_headers",
  50     "//third_party/icu",
  51     "//ui/base",
  52     "//ui/gfx",
  53   ]
  54
  55   if (!enable_plugins) {
  56     sources -= [
  57       "pepper_plugin_info.cc",
  58       "pepper_plugin_info.h",
  59     ]
  60   }
  61 }
  62
  63 mojom("mojo_bindings") {
  64   sources = [
  65     "background_sync.mojom",
  66     "mojo_geoposition.mojom",
  67     "permission_status.mojom",
  68     "service_worker_event_status.mojom",
  69   ]
  70 }