chromeos/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/allocator.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 import("//third_party/protobuf/proto_library.gni")
   9
  10 assert(is_chromeos, "Non-ChromeOS builds must not depend on //chromeos")
  11
  12 gypi_values = exec_script("//build/gypi_to_gn.py",
  13                           [ rebase_path("chromeos.gyp") ],
  14                           "scope",
  15                           [ "chromeos.gyp" ])
  16
  17 component("chromeos") {
  18   configs += [ "//net/third_party/nss/ssl:ssl_config" ]
  19   public_deps = [
  20     "//dbus",
  21   ]
  22   deps = [
  23     "//base",
  24     "//base:i18n",
  25     "//base:prefs",
  26     "//base/third_party/dynamic_annotations",
  27     "//chromeos/ime:gencode",
  28     "//components/device_event_log",
  29     "//components/policy/proto",
  30     "//components/onc",
  31     "//crypto",
  32     "//crypto:platform",
  33     "//google_apis",
  34     "//net/third_party/nss/ssl:libssl",
  35     "//third_party/icu",
  36     "//third_party/libxml",
  37     "//third_party/protobuf:protobuf_lite",
  38     "//url",
  39     ":cryptohome_proto",
  40     ":power_manager_proto",
  41   ]
  42   sources = gypi_values.chromeos_sources
  43   defines = [ "CHROMEOS_IMPLEMENTATION" ]
  44 }
  45
  46 static_library("test_support") {
  47   testonly = true
  48   configs += [ "//build/config/linux:dbus" ]
  49   deps = [
  50     "//testing/gmock",
  51     ":chromeos",
  52     ":cryptohome_proto",
  53     ":power_manager_proto",
  54     ":test_support_without_gmock",
  55   ]
  56   sources = [
  57     "attestation/mock_attestation_flow.cc",
  58     "attestation/mock_attestation_flow.h",
  59     "chromeos_test_utils.cc",
  60     "chromeos_test_utils.h",
  61     "cryptohome/mock_async_method_caller.cc",
  62     "cryptohome/mock_async_method_caller.h",
  63     "cryptohome/mock_homedir_methods.cc",
  64     "cryptohome/mock_homedir_methods.h",
  65     "dbus/mock_cryptohome_client.cc",
  66     "dbus/mock_cryptohome_client.h",
  67     "dbus/mock_lorgnette_manager_client.cc",
  68     "dbus/mock_lorgnette_manager_client.h",
  69     "dbus/mock_session_manager_client.cc",
  70     "dbus/mock_session_manager_client.h",
  71     "dbus/mock_shill_manager_client.cc",
  72     "dbus/mock_shill_manager_client.h",
  73     "dbus/mock_shill_profile_client.cc",
  74     "dbus/mock_shill_profile_client.h",
  75     "dbus/mock_shill_service_client.cc",
  76     "dbus/mock_shill_service_client.h",
  77     "dbus/services/service_provider_test_helper.cc",
  78     "dbus/services/service_provider_test_helper.h",
  79     "disks/mock_disk_mount_manager.cc",
  80     "disks/mock_disk_mount_manager.h",
  81     "login/auth/fake_extended_authenticator.cc",
  82     "login/auth/fake_extended_authenticator.h",
  83     "login/auth/mock_auth_attempt_state_resolver.cc",
  84     "login/auth/mock_auth_attempt_state_resolver.h",
  85     "login/auth/mock_auth_status_consumer.cc",
  86     "login/auth/mock_auth_status_consumer.h",
  87     "login/auth/mock_url_fetchers.cc",
  88     "login/auth/mock_url_fetchers.h",
  89     "network/fake_network_device_handler.cc",
  90     "network/fake_network_device_handler.h",
  91     "network/mock_managed_network_configuration_handler.cc",
  92     "network/mock_managed_network_configuration_handler.h",
  93     "network/onc/onc_test_utils.cc",
  94     "network/onc/onc_test_utils.h",
  95     "system/fake_statistics_provider.cc",
  96     "system/fake_statistics_provider.h",
  97   ]
  98 }
  99
 100 static_library("test_support_without_gmock") {
 101   testonly = true
 102   configs += [ "//build/config/linux:dbus" ]
 103   deps = [
 104     "//crypto",
 105     ":chromeos",
 106     ":cryptohome_proto",
 107     ":power_manager_proto",
 108   ]
 109   sources = [
 110     "dbus/fake_cros_disks_client.cc",
 111     "dbus/fake_cros_disks_client.h",
 112     "dbus/fake_power_manager_client.cc",
 113     "dbus/fake_power_manager_client.h",
 114     "dbus/fake_session_manager_client.cc",
 115     "dbus/fake_session_manager_client.h",
 116     "dbus/fake_shill_manager_client.cc",
 117     "dbus/fake_shill_manager_client.h",
 118     "dbus/fake_update_engine_client.cc",
 119     "dbus/fake_update_engine_client.h",
 120   ]
 121 }
 122
 123 test("chromeos_unittests") {
 124   configs += [
 125     "//build/config/linux:dbus",
 126     "//net/third_party/nss/ssl:ssl_config",
 127   ]
 128   deps = [
 129     "//base:prefs_test_support",
 130     "//base/test:run_all_unittests",
 131     "//base/test:test_support",
 132     "//components/onc",
 133     "//crypto",
 134     "//crypto:test_support",
 135     "//dbus:test_support",
 136     "//google_apis",
 137     "//net",
 138     "//net:test_support",
 139     "//testing/gmock",
 140     "//testing/gtest",
 141     "//url",
 142     ":cryptohome_proto",
 143     ":power_manager_proto",
 144     ":test_support",
 145   ]
 146   sources = gypi_values.chromeos_test_sources
 147   if (use_allocator != "none") {
 148     deps += [ "//base/allocator" ]
 149   }
 150 }
 151
 152 proto_library("power_manager_proto") {
 153   sources = [
 154     "//third_party/cros_system_api/dbus/power_manager/input_event.proto",
 155     "//third_party/cros_system_api/dbus/power_manager/peripheral_battery_status.proto",
 156     "//third_party/cros_system_api/dbus/power_manager/policy.proto",
 157     "//third_party/cros_system_api/dbus/power_manager/power_supply_properties.proto",
 158     "//third_party/cros_system_api/dbus/power_manager/suspend.proto",
 159   ]
 160
 161   proto_out_dir = "chromeos/dbus/power_manager"
 162 }
 163
 164 proto_library("cryptohome_proto") {
 165   sources = [
 166     "//third_party/cros_system_api/dbus/cryptohome/key.proto",
 167     "//third_party/cros_system_api/dbus/cryptohome/rpc.proto",
 168   ]
 169
 170   proto_out_dir = "chromeos/dbus/cryptohome"
 171 }
 172
 173 proto_library("cryptohome_signkey_proto") {
 174   sources = [
 175     "//third_party/cros_system_api/dbus/cryptohome/signed_secret.proto",
 176   ]
 177
 178   proto_out_dir = "chromeos/cryptohome"
 179 }